Excel Formel

[Egon12]

Hallo Edgar,

ändere für den Fall, dass man mal das Startdatum ändern will die Lamba dahingehend (passend für deine letzte Anpassung):

Aufruf:

Code:

=Streupflicht(2025;40;A5:A16;A10;DATUM(2024;12;31))

Formel:

Code:

=LAMBDA(StartJahrJanuar;AnzahlJahre;AlleParteien;ErstePartei;StartDatum;
    LET(xA; SEQUENZ(AnzahlJahre; 1; StartJahrJanuar);
        xB; SEQUENZ(3; 1; StartDatum; 1);
        xC; REDUCE(
                0; xA;
                LAMBDA(I; J;
                    VSTAPELN(
                        I;
                        SEQUENZ(
                            DATUM(J; 4; 30) - DATUM(J; 1; 1) + 1;
                            1;
                            DATUM(J; 1; 1);
                            1
                        )
                    )
                )
            );
        xD; INDEX(
                xC;
                SEQUENZ(ZEILEN(xC) - 1; 1; 2);
                1
            );
        xF; REDUCE(
                0; xA;
                LAMBDA(I; J;
                    VSTAPELN(
                        I;
                        SEQUENZ(
                            DATUM(J; 12; 31) - DATUM(J; 10; 1) + 1;
                            1;
                            DATUM(J; 10; 1);
                            1
                        )
                    )
                )
            );
        xG; INDEX(
                xF;
                SEQUENZ(ZEILEN(xF) - 1; 1; 2);
                1
            );
        xH; SORTIEREN(
                VSTAPELN(xB; xD; xG)
            );
        xI; AlleParteien;
        xJ; ZEILEN(xI);
        xK; ZEILEN(xH);
        xL; VERGLEICH(ErstePartei; xI; 0);
        xM; SEQUENZ(xK);
        xN; REST(
                (xL - 1) * 2 + xM - 1;
                xJ * 2
            ) + 1;
        HSTAPELN(
            xH;
            INDEX(
                xI;
                AUFRUNDEN(xN / 2; 0)
            )
        )
    )
)

Da kann man dies im Aufruf steuern. 
Mit O2024 bekam ich es nicht besser hin. Anton kann da für O365 bestimmt noch eine besseres zu diesem Thema zeigen.

Gruß Uwe

[Axel22]

Hallo Edgar,
jetzt passt es bis auf die Spalte C Streupflicht im Januar 2025 aber das ist egal
weil 2025 eh Geschichte ist. Ich brauchte das Jahr 2025 zur Nachkontrolle.
Alle anderen Jahre und Eintragungen stimmen.

Eine frage habe ich aber noch. Wenn ich in eine Zelle mit Formel klicke ist der
Text in der Bearbeitungsleiste ausgegraut und kann nicht bearbeitet werden. 
Sind das oder die Blätter geschützt?
Gruß Axel22

[BoskoBiati]

Hallo,

nennt sich Spillen, nur die Zelle, in der die Formel steht (im Kalender die Zeile 5) kann bearbeitet werden, der Rest der Zellen füllt sich automatisch!

[Axel22]

Hallo Edgar,
danke für die Info und auch ein Dankeschön an alle die bei der Lösung mit geholfen haben.
Es ist eine tolle Leistung und ein tolles Ergebnis von euch 
Gruß Axel22

[Axel22]

Hallo liebes Team vom Clever-Excel-Forum,
vielen dank für eure Lösungen für einen Dynamischen Reinigungsplan mit Drehfeld (Große Hausordnung Streupflicht)
Der Plan funktioniert besten und ich hätte es so nie hinbekommen.
Gruß Axel22