Hallo zusammen,
ich habe stündliche Werte von einer PV Anlage und möchte diese auf 10-minuten Werte runter interpolieren.
Hat hier jemand eine Idee wie ich das am besten in Excel machen kann?
Vielen Dank für die Hilfe.
Ab B1 Stundenwerte.
E1: =REST(ZEILE(B6)/6;1)*(
INDEX(B:B;ZEILE(B6)/6+1)-
INDEX(B:B;ZEILE(B6)/6))+
INDEX(B:B;ZEILE(B6)/6) oder
E1: =TREND(INDEX(B:B;
ZEILE(B6)/6+{0;1});KÜRZEN(
ZEILE(B6)/6)+{0;1};
ZEILE(B6)/6) runterkopieren
Mit der Trend-Funktion:
Code:
=TREND({10;20};{0;1};{0.0,1667.0,3333.0,5.0,6667.0,8333.1};1)
Bei Excelversionen, die keine Spill-Funktionalität haben, muss die Funktion wie folgt eingetragen werden:
Bereich A1:G1 wählen, Formel in Bearbeitungsleiste eintragen, Strg+Shift+Enter
@EarlFred: =TREND({10;20};{0;1};{0.1.2.3.4.5.6}/6;1) wäre etwas kürzer (wenn ich nicht noch nach den Werten und dem Sinn suchen müsste)
da haste recht! Wobei man dann 0 und 6 auch noch weglassen könnte, denn die existierenden Vorgabewerte müssen ja nicht noch einmal berechnet werden.
Die Konstantenarrays hatte ich tatsächlich eher als Platzhalter für Zellbezüge vorgesehen und entsprechend wenig Hirnschmalz investiert.
Ich ging blindlings davon aus, dass bereits Daten und eine Zeitschiene existieren, in die sich die Formel irgendwie auf unbekannte Weise einfügen muss.
Ich nehme an, dass, wenn ich schon auf 10 Minuten verbreitern soll, ich eine gestreckte Wertereihe (ohne Gewinnung von Information) erhalten möchte.
Thema "Kürzer ist schöner":
Code:
=A1+ZEILE(1:6)*(B1-A1)/6
Wenn kein Spill, dann Bereich A2:A7 markieren, sonst wie zuvor benannt.
Aber der TE will doch aus 365*24 Werten 365*24*6 machen ... nicht nur ein einzelnes Stundenintervall.
=REST(ZEILE(B6:B52565)/6;1)*(
INDEX(B:B;ZEILE(B6:B52565)/6+1)-
INDEX(B:B;ZEILE(B6:B52565)/6))+
INDEX(B:B;ZEILE(B6:B52565)/6) als Spill (TREND nicht spillbar) bzw. Formelarray
=LET(x;ZEILE(B6:B52565)/6;y;INDEX(B:B;x);REST(x;1)*(INDEX(B:B;x+1)-y)+y) nach xl2019
Wow danke für die Antworten.
Wie kann ich die Formel auf meine Zellen hier anwenden?
Anstatt B6 D14 als Start?
(20.02.2023, 11:41)carocarotte schrieb: [ -> ]Wie kann ich die Formel auf meine Zellen hier anwenden?
Anstelle Bildchen bitte eine Mappe.
Wie soll denn das Ergebnis aussehen? Deine Zeitschiene hat ja überhaupt keinen Platz für eine Ausgabe der 10-Minuten-Werte! Auch das trägst du bitte in die Mappe ein, damit wir erstmal wissen, was du eigentlich willst.