Hallo c...,
in welchem System wird denn stündlich die Leistung registriert?
Wenn die Zahlen mittlere Leistung in der Stunde sind (also eigentlich kWh), darfst du sie nicht interpolieren.
Aus 20 kwh ließe sich ja leicht 3,333 kw(h/6) machen.
In der Tabelle steht übrigens kw.
Hallöchen,
anbei die Datei.
Leider schaffe ich es auch nicht die Zeitangabe von stündlichen Werten auf 10 minuten werte nicht.
15 Minuten habe ich durch eine Vorlage glücklicherweise.
Wie kann ich dann die kW Erträge einmal auf 15 Minuten und einmal auf 10 Minuten Interpolieren?
Vielen Dank für all die Hilfe, ich bin leider nicht so fit in Excel
Hallöchen,
Zitat:Leider schaffe ich es auch nicht die Zeitangabe von stündlichen Werten auf 10 minuten werte nicht.
Gib 00:00:00 und darunter 00:10:00 ein und dann kannst Du das runter ziehen oder, wenn die Nachbarspalte schon ausgefüllt ist, beide Zellen markieren und die rechte untere Ecke mit dem schwarzen Kreuz per Doppelklick darauf nutzen.
Super, danke, das hat geklappt. wie bekomme ich dann zusätzlich noch hin, dass das Datum automatisch wechselt? Also bei 00:00 Uhr dann der nächste Tage beginnt?
Hi,
wenn du das erreichen willst, ist es das einfachste Datum und Uhrzeit in eine einzige Zelle zu schreiben, darunter dann 10 Minuten später und dann beide Zellen markieren und ziehen.
I6: 2023-01-22 00:00
I7: 2023-01-22 00:10
ziehen...
Datum und Uhrzeit bilden zusammen eine Zeitangabe, sollten also auch nicht über mehrere Zellen verstreut werden. In deinem "Bildchen" war es also eigentlich richtig.
Das "Ziehen" ist zwar eine einfache Lösung, allerdings schleichen sich mehr und mehr Rechenfehler ein (Thema Gleitkomma), die man bei Uhrzeiten zwar nicht unbedingt sieht, weil es sich erst weit hinten in den Nachkommastellen auswirkt, allerdings schlagen Verweisfunktionen mit solchen Werten oft fehl.
Vorschlag zur Mappe:
Für eine neue Spalte C ein. Dort hinterlegst du die Formel
Code:
=DATUM(2023;1;22)+(ZEILE(A1)-1)/24
Deine "verdichtete" Zeitschiene baust du dir ähnlich auf:
Code:
=DATUM(2023;1;22)+(ZEILE(A1)-1)/24/6
In die Nachbarspalte kommt folgende Funktion:
Code:
=TREND(
INDEX(
$D$6:$D$365;
VERGLEICH(ABRUNDEN(N6*24;0)/24;$C$6:$C$365;0))
:INDEX(
$D$6:$D$365;
VERGLEICH(AUFRUNDEN(N6*24;0)/24;$C$6:$C$365;0));
INDEX(
$C$6:$C$365;
VERGLEICH(ABRUNDEN(N6*24;0)/24;$C$6:$C$365;0))
:INDEX(
$C$6:$C$365;
VERGLEICH(AUFRUNDEN(N6*24;0)/24;$C$6:$C$365;0));
N6;
1)
Leider klappt die Trend Funktion nicht.
Das mit dem Datum hat wunderbar geklappt. (siehe Anhang).
- keine Eingabe als Matrixfunktion notwendig
- du nimmst deinen Vergleichswert aus Spalte L - die ist leer. Entsprechend kann keine Übereinstimmung gefunden werden. Ändere auf Spalte H!
Code:
=TREND(
INDEX(
$C$6:$C$365;
VERGLEICH(ABRUNDEN(H6*24;0)/24;$B$6:$B$365;0))
:INDEX(
$C$6:$C$365;
VERGLEICH(AUFRUNDEN(H6*24;0)/24;$B$6:$B$365;0));
INDEX(
$B$6:$B$365;
VERGLEICH(ABRUNDEN(H6*24;0)/24;$B$6:$B$365;0))
:INDEX(
$B$6:$B$365;
VERGLEICH(AUFRUNDEN(H6*24;0)/24;$B$6:$B$365;0));
H6;
1)
Dass du die Formel stark vereinfachen könntest, wenn gewisse Randbedingungen garantiert sind, ist aus den bisherigen Vorschlägen sicherlich ersichtlich.