Clever-Excel-Forum

Guten Morgen geschätzte Community

Ich habe eine Herausforderung in Excel (Office 365 ProPlus). Konkret: 

Ich habe eine Tabelle mit rund 6000 Zeilen (Sales Reporting). Nun möchte ich in einer zweiten Tabelle Werte ausgeben, die gewissen Bedingungen entsprechen, damit ich nicht immer Filtern muss. Am besten visualisiere ich das mal: 

Ausgangstabelle (stark vereinfacht)
[
Bild bitte so als Datei hochladen: Klick mich!
]

Zieltabelle: 
[
Bild bitte so als Datei hochladen: Klick mich!
]

In der Zieltabelle sollen jeweils Kunde, Sendung und Betrag aller Offerten (Spalte "Status) von Peter (Spalte "Sales") angezeigt werden. 

Hat jemand eine kreative Idee?

Liebe Grüsse
Michi

Moin Michi,

lad mal bitte eine Beispieldatei (.xlsx- keine Bildchen!!) hoch. https://www.clever-excel-forum.de/Thread...ng-stellen

Von deiner Beschreibung abgeleitet, könnte eventuell INDEX/AGGREGAT() helfen.

Hallo Michi,

Bitte beachte die Uploadmöglichkeiten in unserem Forum.
Ansonsten, schaue Dir mal den Autofilter_per_Formel an, oder eventuell hilft auch Pivot ...

Sorry - hier die Beispieldatei

Hi,

wie bereits vermutet:

Arbeitsblatt mit dem Namen 'Zieltabelle'
	A	B	C
1	Sales	Peter
2
3	Kunde	Sendung	Betrag
4	A	Test 1	8
5	D	Test 4	12
6	A	Test 9	136
7
8
9
10

Zelle	Formel
A4	=WENNFEHLER(INDEX(Ausgangstabelle!A:A;AGGREGAT(15;6;ZEILE(Ausgangstabelle!$B$1:$B$20)/(Ausgangstabelle!$B$1:$B$20=Zieltabelle!$B$1);ZEILE(A1)));"")
B4	=WENNFEHLER(INDEX(Ausgangstabelle!C:C;AGGREGAT(15;6;ZEILE(Ausgangstabelle!$B$1:$B$20)/(Ausgangstabelle!$B$1:$B$20=Zieltabelle!$B$1);ZEILE(B1)));"")
C4	=WENNFEHLER(INDEX(Ausgangstabelle!D:D;AGGREGAT(15;6;ZEILE(Ausgangstabelle!$B$1:$B$20)/(Ausgangstabelle!$B$1:$B$20=Zieltabelle!$B$1);ZEILE(C1)));"")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
B1	Liste		=$A$28:$A$30

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

---

Hi,
 
mit ist erst jetzt aufgefallen, dass du Microsoft 365 benutzt. Dann geht es noch wesentlich einfacher:

Arbeitsblatt mit dem Namen 'Zieltabelle'
	A	B	C
1	Sales	Peter
2
3	Kunde	Sendung	Betrag
4	A	Test 1	8
5	D	Test 4	12
6	A	Test 9	136

Zelle	Formel
A4	=FILTER(Ausgangstabelle!$A$1:$A$20;Ausgangstabelle!$B$1:$B$20=$B$1; "")
B4	=FILTER(Ausgangstabelle!$C$1:$C$20;Ausgangstabelle!$B$1:$B$20=$B$1; "")
C4	=FILTER(Ausgangstabelle!$D$1:$D$20;Ausgangstabelle!$B$1:$B$20=$B$1; "")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
B1	Liste		=$A$28:$A$30

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

 
Der Vorteil: du musst jeweils nur eine einzige Formel eingeben; der Rest wird von Excel selbst erledigt.

Grandios - in Qualität und Zeit. Vielen herzlichen Dank für die Unterstützung.  :35: