Zeile in ein anderes Tabellenblatt kopieren

[slowboarder]

Hi
wenn du mal den Autofilter in der Spalte "Arbeitsgang" aufklappst, fällt auf dass du viele der Begriffe mehrfach mit kleinen Varianten wie z.B. Hochkomma davor drin hast.
das solltest du natürlich bereinigen.

   

[HKindler]

Hi,

das, was Daniel bemängelt, scheint tatsächlich die Ursache zu sein.

Aber da hätte ich mal eine Frage an dich, Gh0sT_89: Wie um alles in der Welt kommt man darauf vor die meisten Einträge ein '-Zeichen zu machen?

Um künftig unterschiedliche Einträge in deiner Tabelle zu verhindern, kannst du mit der Datenüberprüfung arbeiten.

Obwohl, wenn ich mir das so anschauen hast du es vermutlich von irgendwoher in die Tabelle reinkopiert. Da gibt es mit PQ eine deutlich elegantere Methode. Dort kann man dann auch gleich irgendwelche Dinge direkt bereinigen.

[Gh0sT_89]

Ja das ist dadurch geschuldet das ich jeden Tag eine Liste erhalte einmal in PDF und in excel. 
Daraus kopiere ich die Daten und füge sie in dies Vorlage ein. 
Ja das mit den Strichen ist bekannt aber weiß nicht wie ich die am effizient & schnell lösen kann. 
Sowie auch die 2 Varianten mit dem prüfen aber jaa unsere AV 🙈.
Die Vorlage benutzen mehrere Personen ich Versuch aber grad da ein bisschen Struktur rein zu bekommen zwecks Übersichtlichkeit. 
Wenn mir jemand bei der Umsetzung helfen könnte wäre ich euch sehr verbunden. ☺️

Liebe Grüße 
Gh0sT_89

[Egon12]

Hallo Gh0sT_89 ,

Vorweg: Du kannst, dass ich so kurz angebunden mich heute verhalten habe nichts dafür. Das hat andere Gründe.

In deinem Listobjekt "Übersicht" kann es einfach so wie vorgeschlagen nicht funktionieren.
Um ein sauberes Ergebnis zu erhalten braucht es ISTZAHL(FINDEN()) in FILTER(). ZÄHLENWENN() ist für derartige Inhalte untauglich.

So wie ich es schon angemerkt hatte braucht es hier, wenn es zu mehreren Begriffen in Zeile 1 kommt LAMBDA() und in dem Fall reicht NACHZEILE().

im Blatt "Endabnahme2" habe ich mal ein paar Begriffe in Zeile 1 eingetragen.
Die Formel für A2 ist:

Code:

=LET(xA; Übersicht; xB; FILTER(1:1; 1:1<>"");xC; ISTZAHL(SUCHEN(xB; INDEX(xA;;10)));xD; NACHZEILE(xC; LAMBDA(r; ODER(r))); FILTER(xA; xD))

INDEX(xA;;10) enthält die Werte aus Spalte 10 deines Listobjektes. Falls du mal die Tabelle im Aufbau ändern solltest musst du ggf. dies anpassen.

  Vorlage bearbeitet_v3.xlsm (Größe: 56,76 KB / Downloads: 5)

Gruß Uwe

[Gh0sT_89]

Vielen lieben Dank, das ganze funktioniert jetzt tatsächlich so wie ich mir das vorgestellt habe.
Mit PQ hab jetzt die Spalte 10 ohne die ## ' ## bereinigt sodass keine ähnliche oder doppelten auftauchen.
Bei einem Blatt hab ich aber tatsächlich das Problem noch zb. Prüfen:
Das dann mehrere kommen zb auch Werte prüfen obwohl ich eigentlich nur "prüfen" möchte.
Wie kann ich das am besten noch umsetzen mit der Formel  

Dennoch 1000 Dank für die Lösung bis jetzt 

Mfg 
Gh0sT_89

[HKindler]

Hi,

wie sieht deine Formel und deine Tabelle denn jetzt genau aus?

Suchen/Finden findet "prüfen" halt egal wo in der Zelle dies steht. Somit auch in "Werte prüfen". Um dies jetzt sicher auszuschließen, muss man halt sämtliche Kombinationen kennen, die vorkommen können.

[Gh0sT_89]

Ja hab mir jetzt in diesem Fall die Formel von Daniel ran gezogen wo genau dies ausgibt mit "prüfen"
Hab diese mal im Anhang angehängt. Da ich dies noch mit 2 Makros verknüpft hab 
- 1x PQ um die Spalte 10 "Arbeitsgang" zu bereinigen (Arbeitsmappe ist aber ausgeblendet)
- Datei mit Datum im Pfad speichern.

Also für mich funktioniert die Datei eigentlich wie gedacht 
Vielen Dank erstmal dafür, vllt hat für den einen Fall noch eine Lösung aber ansonsten bin ich mehr als zufrieden ;)

Mfg 
Gh0sT_89

[Egon12]

Hallo,

ich habe jetzt mal noch eine weitere Überprüfung eingebaut und FINDEN statt SUCHEN benutzt. Die sollte schon reichen. Falls nicht kann man auch noch zusätzlich den Wert in FINDEN() auf  <3 prüfen lassen. Aber erst mal nicht mehr als nötig.

Formel in A3:

Code:

=LET(xA; Übersicht;xB; FILTER(1:1; 1:1<>"");xC; INDEX(xA;;10);xD; LÄNGE(xB);xE; ISTZAHL(FINDEN(xB; xC)) * (LÄNGE(xC) <= xD + 2);xF; NACHZEILE(xE; LAMBDA(r; ODER(r)));FILTER(xA; xF))

Gruß Uwe

[HKindler]

Hi Gh0sT_89,

deine Replace-Orgie in der PQ kannst du auch deutlich reduzieren:
= Table.ReplaceValue(#"vorheriger Schritt", "'", "", Replacer.ReplaceText, {"Auftr", "AG-Nr", "Material-Nr"})
Dies entfernt alle '-Zeichen in den drei Spalten "Auftr", "AG-Nr" und "Material-Nr". Das kannst du dir sogar per Mausklick erstellen: Gewünschte Spalten markieren (mit Shift-Klick bzw. Strg-Klick) und dann Transformieren --> Werte ersetzen.
Wenn du alle '-Zeichen in allen Spalten entfernen willst, so geht das mit
= Table.ReplaceValue(#"vorheriger Schritt", "'", "", Replacer.ReplaceText, Table.ColumnNames(#"vorheriger Schritt"))
Das musst du leider per Hand eingeben. Wenn du das per Maus machst, dann erhältst du eine Befehlszeile wie oben mit einer Liste mit allen Spaltennamen - sehr umständlich und unflexibel, aber dennoch brauchbar.

Du kannst an der Stelle auch noch ganz andere Sachen machen, z.B. aus deinem "Start geplant" ein echtes Datum.

Mit den aufbereiteten Daten ohne die '-Zeichen kannst du auch wieder Daniels Formel verwenden:
=FILTER(Übersicht;ZÄHLENWENN(1:1;Übersicht[Arbeitsgang]))

Uwes Formel kommt auch mit den nicht per PQ aufbereiteten Daten klar. Vor allem mit seiner letzten Korrektur sollte das nun funktionieren.

Was du verwendest, ist Geschmacksache. Ich würde die Daten per PQ aufbereiten und dann Daniels Formel verwenden. Ist für mich einfach leichter zu verstehen und dadurch besser nachvollziehbar. Außerdem kannst du für ein gefälligeres Aussehen und bessere Funktionalität der 'Übersicht' sorgen.

Übrigens: Generell solltest du verbundene Zellen wie in Zeile 1 von Blatt ZFP vermeiden. Die machen oft Schwierigkeiten. Zwar geht es hier gut, aber dennoch prinzipiell keine gute Idee. Wenn du alle Bedingungen sauber sehen willst, dann lass doch einfach die Zellen, die du bisher verbunden hast, leer.

[Gh0sT_89]

Ja versteh dich, kann der Formel auch nicht ganz folgen aber sie funktioniert o.O 

Ich werde wenn ich nochmal ein bisschen Luft hab dies mit PQ bereinigen und dann die andere Alternative mal probieren.

Aber stand jetzt funktioniert es schonmal so wie ich es gerne hätte.
Schön wäre wenn die Zeile noch farblich markiert ist dies auch in den Blätter mit übernommen wird.
Aber ob dies geht, weiß ich nicht. Evtl könnt ihr dies beantworten.

Mfg
Gh0sT_89