Präsenzen gerade und ungerade Wochen eintragen

[ws-53]

Am einfachsten aus meiner Sicht wäre, das jeweilige Datum durch 7 zu dividieren und das Ergebnis auf- oder abzurunden. Darüber lässt sich dann ganz einfach die Belegung gerade/ungerade zuordnen.

[HKindler]

das ist ja nicht das Problem. Das Problem ist, dass es möglich ist, dass beim Jahreswechsel 2 aufeinanderfolgende KW beide ungerade sein können.

Und genau darauf wollte ich hinweisen! In einem Jahr das nur 52KW hat, ist es in Europa kein Problem, in den USA schon eher (es sei denn der 1.1. fällt auf einen Sonntag). In einem Jahr mit 53KW hat man in Europa das Problem immer, in den USA eher nicht (es sei denn der 1.1. fällt auf einen Sonntag). Übrigens gibt es in den USA sogar eine KW54. Allerdings nur, wenn der 1.1. auf einen Samstag fällt und es sich um ein Schaltjahr handelt. Die Woche 54 ist dann - genauso wie die KW1 desselben Jahres - auch nur einen Tag lang. Das nächste Mal ist dies im Jahr 2028 der Fall. Und danach wieder in 2056.

[RPP63]

Moin!
Wir raufen uns die Haare für ein Problem, welches "eigentlich" nicht existiert …
Ich arbeite für ein Unternehmen, welches auch 14-tägige Touren hat.
Wir unterscheiden ebenfalls zwischen gerader und ungerader KW.
Wenn es dann alle paar Jahre mal dazu kommt, dass eine ungerade auf eine ungerade Woche folgt, melden wir halt Insolvenz an, weil es keinem Logistiker zugemutet werden kann, mal kurz das Hirn einzuschalten.

Sorry für meinen Zynismus!

Gruß Ralf

[EA1950]

Hallo,

ich habe dir im Arbeitsblatt "Original" 2 Formeln eingefügt:

in Zelle H3 mit Resultatbereich H3:AL5:
=LET(moa;DATWERT(1&$B$1&$A$1); moe;MONATSENDE(moa;0); dt;ERWEITERN(SEQUENZ(1;TAG(moe);moa);;31;"");
gu;WENNFEHLER(WENN(ISTGERADE(ISOKALENDERWOCHE(dt));"G";"U");"");
VSTAPELN(gu;dt;dt))
Sie gibt die 3 Datumszeilen aus.

weiters in Zelle H6 mit (maximalem) Resultatbereich H6:AL29:
=LET(NmPräs; Original!$A$6:$G$29; dtgu; Original!$H$3#; kw; tbTeileKW; gh; tbStdCode; MATRIXERSTELLEN(ANZAHL2(ABSCHNBEREICH(SPALTENWAHL(NmPräs; 1); 2)); ANZAHL2(ABSCHNBEREICH(ZEILENWAHL(dtgu; 1); ; 2)); LAMBDA(i;j; LET(zl; ZEILENWAHL(NmPräs; i); gu; INDEX(dtgu; 1; j); dt; INDEX(dtgu; 2; j); pwz; INDEX(zl; ; 2 + WOCHENTAG(dt; 11)); pz; WENNS(RECHTS(pwz; 2) = "uW"; "U"; RECHTS(pwz; 2) = "gW"; "G"; WAHR; XVERWEIS(INDEX(zl; ; 1) & "|" & INDEX(zl; ; 2); INDEX(kw; ; 1) & "|" & INDEX(kw; ; 2); INDEX(kw; ; 3); 0; 0)); wt; WENNFEHLER(REGEXEXTRAHIEREN(pwz; "^(\d|\.|;|GT|HT|\+)*"; ; 0); ""); ww; WENN(ODER(pz = gu; pz = "W"); WENN((ZÄHLENWENN(Feiertage; dt) = 0) * (ZÄHLENWENN(Betriebsferien; dt) = 0); wt; ""); ""); wa; REDUCE(WECHSELN(ww; "."; ","); SEQUENZ(ZEILEN(gh)); LAMBDA(akk;i; WECHSELN(akk; INDEX(gh; i; 1); INDEX(gh; i; 2)))); WENNFEHLER(SUMME(--TEXTTEILEN(wa; "+")); "")))))
Diese Formel ermittelt die tagtäglichen Stunden für die einzelnen Personen (A6:B29), wie sie durch die Präsenzspalten (C6:G29) vorgegeben wurden.
Fett geschrieben sind die Zellbereiche, die sie zur Dateneingabe benötigt.

Dazu setzt sie auch für die Kürzel "GT" bzw. "HT" die entsprechenden Stunden ein und führt auch eventuelle Additionen für Zusatzstunden aus. Die Werte dazu entnimmt sie der intelligenten Tabelle "tbStdCode" im Arbeitsblatt "Zuordnung". Die grundsätzlichen Zuordnungen der Personen zur geraden/ungeraden Woche habe ich in die Tabelle "tbTeileKW" verschoben ebenfalls in diesem Arbeitsblatt.

[EA1950]

Hallo,

ich habe leider festgestellt, dass ich in der Formel einen Fehler habe (TEXTTEILEN-Funktion). Diese habe ich jetzt ersetzt, sodass die Formel jetzt funktionieren sollte.

[RPP63]

Moin!
Mal abseits meines obigen Zynismus die Regeln für unsere Isokalenderwoche:
• Der letzte Montag des Jahres kann folgende KW sein: 52, 53 oder 1
• Der erste Montag des Folgejahrs hat entweder KW 1 oder 2
• Eine gerade KW folgt niemals einer geraden KW!
• Eine ungerade KW folgt einer ungeraden KW nur dann, wenn der letzte Montag des Jahres KW 53 ist.

Diese Konstellation gibt es alle fünf bis sechs Jahre.
Lediglich ein Denkansatz:

	A	B	C	D	E	F	G	H	I
1	letzter_MO_Jahr	KW	erster_MO_Jahr	KW		letzter_MO_Jahr	KW	erster_MO_Jahr	KW
2	Mo 28.12.20	53	Mo 04.01.21	1		Mo 28.12.20	53	Mo 04.01.21	1
3	Mo 27.12.21	52	Mo 03.01.22	1		Mo 28.12.26	53	Mo 04.01.27	1
4	Mo 26.12.22	52	Mo 02.01.23	1		Mo 27.12.32	53	Mo 03.01.33	1
5	Mo 25.12.23	52	Mo 01.01.24	1		Mo 28.12.37	53	Mo 04.01.38	1
6	Mo 30.12.24	1	Mo 06.01.25	2		Mo 28.12.43	53	Mo 04.01.44	1
7	Mo 29.12.25	1	Mo 05.01.26	2		Mo 28.12.48	53	Mo 04.01.49	1
8	Mo 28.12.26	53	Mo 04.01.27	1		Mo 28.12.54	53	Mo 04.01.55	1
9	Mo 27.12.27	52	Mo 03.01.28	1		Mo 27.12.60	53	Mo 03.01.61	1
10	Mo 25.12.28	52	Mo 01.01.29	1		Mo 28.12.65	53	Mo 04.01.66	1
11	Mo 31.12.29	1	Mo 07.01.30	2		Mo 28.12.71	53	Mo 04.01.72	1
12	Mo 30.12.30	1	Mo 06.01.31	2		Mo 28.12.76	53	Mo 04.01.77	1
13	Mo 29.12.31	1	Mo 05.01.32	2		Mo 28.12.82	53	Mo 04.01.83	1
14	Mo 27.12.32	53	Mo 03.01.33	1		Mo 27.12.88	53	Mo 03.01.89	1
15	Mo 26.12.33	52	Mo 02.01.34	1		Mo 28.12.93	53	Mo 04.01.94	1
16	Mo 25.12.34	52	Mo 01.01.35	1		Mo 28.12.99	53	Mo 04.01.00	1
17	Mo 31.12.35	1	Mo 07.01.36	2		Mo 28.12.05	53	Mo 04.01.06	1
18	Mo 29.12.36	1	Mo 05.01.37	2		Mo 28.12.11	53	Mo 04.01.12	1
19	Mo 28.12.37	53	Mo 04.01.38	1		Mo 28.12.16	53	Mo 04.01.17	1
20	Mo 27.12.38	52	Mo 03.01.39	1
21	Mo 26.12.39	52	Mo 02.01.40	1

Zelle	Formel
A2	=LET(j;EDATUM("31.12.2020";SEQUENZ(100;;0;12));j-WOCHENTAG(j;2)+1)
B2	=ISOKALENDERWOCHE(A2#)
C2	=A2#+7
D2	=ISOKALENDERWOCHE(C2#)
F2	=FILTER(A2:D101;B2#=53)

Gruß Ralf

---

Als Extrakt aus obiger Überlegung:
Die Liste der "Problemjahre" in den nächsten 100 Jahren erhält man mit
=LET(
    j; EDATUM("31.12." & JAHR(HEUTE()); SEQUENZ(100; ; 0; 12));
    leMo; j - WOCHENTAG(j; 2) + 1;
    JAHR(FILTER(leMo; ISOKALENDERWOCHE(leMo) = 53))
)

[Egon12]

Hallo,

hier noch eine spillende Variante für die Timeline des Monats in H3:

Code:

=LET(xA;DATWERT(1&B1&A1);xB;SEQUENZ(1;TAG(MONATSENDE(xA;0));xA;1);xC;WENN(ISTGERADE(ISOKALENDERWOCHE(xB));"G";"U");VSTAPELN(xC;xB;xB))

WENNFEHLER() wird so nicht mehr benötigt, da xC aus der Dimension xB generiert wird.

Gruß Uwe

[Mamamia]

Guten Abend,

Uff... ich glaube ich lasse das und sollen die das händisch eintragen 
Eure Vorschläge und Mühen sind ja schön und gut, dachte aber das würde einfacher gehen ( hab ja auch keine lösung parat..))

Das mit den Zuteilungen funktioniert jedoch nur bedingt.

Möglich wäre nämlich auch dass Kind A jeweils am Mo wöchentlich kommt, Di nur in den geraden Wochen und Mittwochs jeweils in den ungeraden WOchen.

Dann funktioniert es ja mit der Zuteilung nicht. 

Naja, suche weiter nach einer Lösung. vielleicht finde ich ja noch etwas raus.

Liebe Grüsse Mamamia

[knobbi38]

Naja, suche weiter nach einer Lösung. vielleicht finde ich ja noch etwas raus.

Wieso, die Lösung steht doch schon in #11 

Code:

=istgerade(quotient(<das datum>;7))

[Egon12]

Hallo Mamamia,
 
ich denke, dass es sich vielleicht doch machen lässt. Nur eben nicht so wie du es mit deiner Formel angedacht hattest. 
 
Ich hatte in meiner hochgeladenen Datei eine Hilfstabelle angelegt. Diese kann man statt pauschal via Woche U/G/W festzulegen dann mit Spalten für Wochentage erweitern und für jeden Wochentag die Bedingung festlegen.
 
Allerdings wäre die Bedingung zyklische Wiederholung. Dazu müsstest du dich doch mal vollständig für den Monat die Werte U/G/W in die Hilfstabelle im Blatt „Zuordnung“ festlegen in die Blatt „Original“ das Ausgabeergebnis eintragen.
Dann kann man erkennen, ob sich da was automatisierbares ableiten lässt.
Wenn ja, wird sich da auch eine Formellösung finden lassen.

  Präsenzlisten eintragen gerade und ungerade Wochen.xlsm (Größe: 44,93 KB / Downloads: 2)

 
Gruß Uwe