Hallo zusammen,
ich komme mit einer Formel nicht wirklich weiter:
=WENN(SVERWEIS(Datenblatt!A3;Nord!$A$2:$A$2000;1;0);"Nord";WENN(SVERWEIS(Datenblatt!A3;Mitte!$A$2:$A$2000;1;0);"Mitte";WENN(SVERWEIS(Datenblatt!A3;Süd!$A$2:$A$2000;1;0);"Süd";WENN(SVERWEIS(Datenblatt!A3;HV!$A$2:$A$2000;1;0);"HV";"nicht zugeordnet"))))
Basisdaten:
1 Basisexceltabelle die alle Personalnummern (Spalte A) beinhaltet (Name des Tabellenblattes: Datenblatt)
4 Exceltabellen in denen Personalnummern (Spalte A) sowie der jeweilige Dienstort (Spalte B) nebeneinander stehen. Mögliche Dienstorte sind "Nord", "Mitte", "Süd" und "HV".
(Namen der Tabellebnlätter: "Nord", "Mitte", "Süd" und "HV"
In meiner Basistabelle soll nun jeder Personalnummer der jeweilige Standort zugewiesen werden.
Ein Ergebnis (Nord) erscheint allerdings leider nur, wenn die Personalnummer in der ersten Tabelle, nämlich in der Tabelle "Nord" vorhanden ist.
Für eine Lösung wäre ich sehr dankbar.
Lieben Gruß vorab.
Seb
Hola,
zeig doch bitte eine Beispieldatei.
Gruß,
steve1da
Hallo,
so mal aus dem Steigreif:
=WENN(istfehler(SVERWEIS(Datenblatt!A3;Nord!$A$2:$A$2000;1;0));"";"Nord")&WENN((istfehler(SVERWEIS(Datenblatt!A3;Mitte!$A$2:$A$2000;1;0));"";"Mitte")&WENN(istfehler(SVERWEIS(Datenblatt!A3;Süd!$A$2:$A$2000;1;0));"";"Süd")&WENN(SVERWEIS(istfehler(Datenblatt!A3;HV!$A$2:$A$2000;1;0));"";"HV")
Hello,
Beispieldatei findest du im Anhang.
Gruß
Seb
Hallo Seb,
hier eimal einige Bemerkungen:
1) zu Edgars Lösung
In Edgars Lösung ist ein kleiner Tippfehler, in der 4. WENN-Funktion sind ISTFEHLER und SVERWEIS vertauscht.
2) zu deiner Formel
In deiner Formel liefern die Sverweise entweder eine Personalnummer oder einen Fehler.
Im ersten Parameter einer Wenn-Funktion erwartet Excel einen Wahrheitswert. Auch wenn die automatische Umwandlung sehr flexibel ist (jede Personalnummer ungleich 0 wird als WAHR interpretiert) kann und soll Excel einen Fehler nicht in einen Wahrheitswert umwandeln.
3) zur Fehlersuche in komplexen Formeln
Weist du, dass man in der Bearbeitungszeile Teile einer Formel markieren kann und diese dann mit F9 ausgewertet werden? Hiermit kann man bei Fehlern in komplexen Formeln die Fehlerursache schnell erkennen.
4) zu der Datei
Auch wenn viele diese Frage schon nicht mehr stellen oder hören können:
Gibt es einen vernünftigen Grund, warum du die Mitarbeiter in vier Tabellenblätter verwaltest?
Die Anzahl ist meines Erachtens kein vernünftiger Grund, dann könnte man die Daten auch in unterschiedliche Dateien in unterschiedliche Verzeichnisse in verschiedenen Netzwerken schreiben.
Die Verwaltung gleichartiger Daten in einem Tabellenblatt, am Besten in einer "intelligenten Tabelle" ist sehr viel einfacher.
Hallo,
in dieser Formel
Zitat:=WENN(istfehler(SVERWEIS(Datenblatt!A3;Nord!$A$2:$A$2000;1;0));"";"Nord")&WENN((istfehler(SVERWEIS(Datenblatt!A3;Mitte!$A$2:$A$2000;1;0));"";"Mitte")&WENN(istfehler(SVERWEIS(Datenblatt!A3;Süd!$A$2:$A$2000;1;0));"";"Süd")&WENN(SVERWEIS(istfehler(Datenblatt!A3;HV!$A$2:$A$2000;1;0));"";"HV")
ist eine Klammer zuviel und die Position von SVERWEIS() mit ISTFEHLER() vertauscht.
=WENN(ISTFEHLER(SVERWEIS(Datenblatt!A3;Nord!$A$2:$A$2000;1;0));"";"Nord")&WENN
(ISTFEHLER(SVERWEIS(Datenblatt!A3;Mitte!$A$2:$A$2000;1;0));"";"Mitte")&WENN(ISTFEHLER(SVERWEIS(Datenblatt!A3;Süd!$A$2:$A$2000;1;0));"";"Süd")&WENN(
ISTFEHLER(SVERWEIS(Datenblatt!A3;HV!$A$2:$A$2000;1;0));"";"HV")
Gruß
sturmrm
Hallo, ich würde das so lösen wollen..:
Code:
=WAHL((ZÄHLENWENN(Nord!A:A;A3)*1)+(ZÄHLENWENN(Mitte!A:A;A3)*2)+(ZÄHLENWENN(Süd!A:A;A3)*3)+(ZÄHLENWENN(HV!A:A;A3)*4);"Nord";"Mitte";"Süd";"HV")
bzw.:
Code:
=WENNFEHLER(WAHL((ZÄHLENWENN(Nord!A:A;A3)*1)+(ZÄHLENWENN(Mitte!A:A;A3)*2)+(ZÄHLENWENN(Süd!A:A;A3)*3)+(ZÄHLENWENN(HV!A:A;A3)*4);"Nord";"Mitte";"Süd";"HV");"keine oder mehrfach vergebene Pers.Nr.")
Hallo Jörg,
genial! Da hätte ich aber auch noch was:
Code:
=WAHL(min(6;1+(ZÄHLENWENN(Nord!A:A;A3)*1)+(ZÄHLENWENN(Mitte!A:A;A3)*2)+(ZÄHLENWENN(Süd!A:A;A3)*3)+(ZÄHLENWENN(HV!A:A;A3)*4));"nicht zugeordnet";"Nord";"Mitte";"Süd";"HV";"Mehrfach!")