Einen schönen guten Tag Euch allen.
Mitlerweile sehe ich den Wald vor Bäumen nicht mehr!
Ich habe folgenden Code:
Code:
=WENN(UND($J7<>"";UND($E7<HEUTE();UND($H7<>"";$I7<>"")));HYPERLINK("mailto:"&$J7&"?subject="&$E7&"&body="&WENN(UND($H7<>"";$I7<>"");WENN($H7="Herr";"Sehr geehrter Herr "&$I7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&$E7&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Sehr geehrte Frau "&$I7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&$E7&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a"));"Email senden");"")
$J7 = Mailadresse
$E7 = Datum
$H7 = Herr/Frau
$I7 = Name
Die ganze Formel funktioniert auch super!
Jetzt zu meinem Problem:
Ich möchte die Formel so erweitern, dass wenn eine Emailadresse eingetragen ist und $H7 und $I7 leer sind der Mailbody Sehr geehrten Damen und Herren lautet.
$J7 und $E7
Ich hoffe auf Eure Hilfe
Danke
Erstmal danke!
Jetzt die Formel:
Code:
=WENN(UND($J7<>"";$E7<HEUTE());HYPERLINK("mailto:"&$J7&"?subject="&$E7&"&body="&"Sehr geehrte"&WENN(UND(J7<>"";H7="";I7="");" Damen und Herren,";WENN(H7="Herr";"r Herr"&" "&I7;" Frau"&" "&I7)&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&$B7&""" seit "&TEXT($E7;"TT.MM.JJJJ")&" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a");"Email senden"))
Problem:
1. ist weder Anrede , Name und Mailadresse nicht eingetragen, wird ein Datumslink mit dem Wert 0 erstellt.
2. fehlt Anrede und Name, wird nur die Anrede "Sehr geehrten Damen und Herren," ohne weiteren Text im Body angezeigt.
3. ist eine Mailadresse und Name eingetragen, aber es fehlt die Anrede, wird automatisch "Frau" gesetzt.
Hallöchen,
1)
wenn schon mal ein Hyperlink in einer Zelle stand, kann das passieren.
Hier mal eine leicht verBesserte Formel
=WENN(UND($J7<>"";$E7
0);HYPERLINK("mailto:"&$J7&"?subject="&$E7&"&body="&"Sehr geehrte"&WENN(H7="Herr";"r Herr";" "&H7)&WENN(H7&I7="";"Damen und Herren, ";" "&I7&", ")&"%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden");"nix senden")
--> Anrede zusammensetzen leicht anders
--> ich prüfe zusätzlich, ob in E7 etwas größer 0 steht - kein Eintrag wäre ansonsten kleiner heute()
--> ich gebe zusätzlich "nix senden" aus.
2)
passiert bei mir nicht. Allerdings müsste man das Datum noch in einen Text wandeln - ansonsten erscheint die laufende zahl des Datums als Betreff 
3)
bei mir würde nix erscheinen, also im Prinzip "Sehr geehrte Meier,"
Hi,
hier mal eine kürzere Version der Formel:
Code:
=WENN(ODER($J7="";$E7>=HEUTE());"";HYPERLINK("mailto:"&$J7&"?subject="&TEXT($E7;"TT.MM.JJJJ")&"&body="&"Sehr geehrte"&WENN((H7="")*(I7="");" Damen und Herren";WENN(H7="Herr ";"r Herr";" Frau "))&$I7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden"))
Als Betreff und als Arbeit das Datum (E7)?
Datum muß auf jeden Fall als Text eingetragen werden!
Erstmal vielen dank!
Mein jetziger code:
Code:
=WENN(UND($J7<>"";$E7<HEUTE());HYPERLINK("mailto:"&$J7&"?subject="&$B7&"&body="&"Sehr geehrte"&WENN(H7="Herr";"r Herr";" "&H7)&WENN(H7&I7="";"Damen und Herren, ";" "&I7&", ")&"%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&$B7&""" seit """ &TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden");"")
Fehlerberichte:
aktuell
wenn Anrede = Herr und Name leer = Sehr geehrter Herr, (falsch) = soll = Sehr geehrte Damen und Herren
wenn Anrede = Frau und Name leer = Sehr geehrte Frau, (falsch) = soll = Sehr geehrten Damen und Herren
wenn Anrede = Frau und Name <> leer = Sehr geehrte Frau XX, (richtig)
wenn Anrede = Herr und Name <> leer = Sehr geehrte Herr XX, (richtig)
wenn Anrede = leer und Name leer = Sehr geehrten Damen und Herren (richtig)
Soll Hauptprüfung:
J7 (Emailadresse) muss immer <>"" um Emaillink anzuzeigen
WENN(UND(H7="";I7="");"Sehr geehrten Damen und Herren (Immer wenn Anrede und Name leer dann Sehr geehrten Damen und Herren)
H7 = Herr/Frau
I7 = Name
Hi,
hast Du überhaupt eine der Formeln ausprobiert, die wir Dir vorgestellt haben?
[
attachment=50924]
Da ist genauso dass problem!
14.02.2024
Herr
a@a.de
Email senden
mailto:a@a.de&14.02.2024Sehr geehrter Herr, mir ist aufgefallen, dass die Wartung/Prüfung "14.02.2024" überfällig ist.Ich bitte Sie, diese umgehend nachzuholen!
Name ist leer!
Da muss sehr geehrten Damen und Herren raus kommen!
Wenn Anrede oder Name leer immer sehr geehrten Damen und Herren !
Hallo Andreas,
vielleicht so ?
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| E | F | G | H | I | J | K | L |
| 6 | Datum | | | Herr/Frau | Name | Mailadresse | Anrede | Link |
| 7 | 20.08.2024 | | | Herr | Müller | Horst@wer | Sehr geehrter Herr Müller | |
| 8 | 12.02.2024 | | | Herr | Müller | | Sehr geehrter Herr Müller | |
| 9 | 12.02.2024 | | | Herr | Müller | Horst@wer | Sehr geehrter Herr Müller | Email senden |
| 10 | 12.02.2024 | | | Herr | | Walter@sen | Sehr geehrte Damen und Herren | Email senden |
| 11 | 12.02.2024 | | | Frau | Müller | Fer@wer | Sehr geehrte Frau Müller | Email senden |
| 12 | 12.02.2024 | | | Frau | | Fer@wer | Sehr geehrte Damen und Herren | Email senden |
| 13 | 12.02.2024 | | | | | Fer@wer | Sehr geehrte Damen und Herren | Email senden |
| 14 | 12.02.2024 | | | | Müller | Fer@wer | Sehr geehrte(r) Herr/Frau Müller | Email senden |
| 15 | 12.02.2024 | | | | | Fer@wer | Sehr geehrte Damen und Herren | Email senden |
| Zelle | Formel |
| K7 | ="Sehr geehrte"&WENN(I7="";" Damen und Herren";WENN(H7="Herr";"r Herr "&I7;WENN(H7="Frau";" Frau "&I7;"(r) Herr/Frau "&I7))) |
| L7 | =WENN(ODER($E7>=HEUTE();J7="");"";HYPERLINK("mailto:"&$J7&"?subject="&TEXT($E7;"TT.MM.JJJJ")&"&body="&K7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden")) |
| Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021 |
| Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg |
Ich würde die Anrede in einer separaten Spalte ermitteln. Das läßt sich dann besser prüfen/überwachen und vereinfacht die mailto-Formel.
Gruß
Fred