Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

WENN UND UND
#1
Einen schönen guten Tag Euch allen.

Mitlerweile sehe ich den Wald vor Bäumen nicht mehr!

Ich habe folgenden Code:
Code:
=WENN(UND($J7<>"";UND($E7<HEUTE();UND($H7<>"";$I7<>"")));HYPERLINK("mailto:"&$J7&"?subject="&$E7&"&body="&WENN(UND($H7<>"";$I7<>"");WENN($H7="Herr";"Sehr geehrter Herr "&$I7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&$E7&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Sehr geehrte Frau "&$I7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&$E7&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a"));"Email senden");"")

$J7 = Mailadresse
$E7 = Datum
$H7 = Herr/Frau
$I7 = Name

Die ganze Formel funktioniert auch super!

Jetzt zu meinem Problem:

Ich möchte die Formel so erweitern, dass wenn eine Emailadresse eingetragen ist und $H7 und $I7 leer sind der Mailbody Sehr geehrten Damen und Herren lautet.


$J7 und $E7
Ich hoffe auf Eure Hilfe

Danke
Antworten Top
#2
Hola,
so?
Code:
=WENN(UND($J7<>"";$E7<HEUTE());HYPERLINK("mailto:"&$J7&"?subject="&$E7&"&body="&"Sehr geehrte"&WENN(UND(J7<>"";H7="";I7="");" Damen und Herren";WENN(H7="herr";"r Herr"&" "&I7;" Frau"&" "&I7)&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a");"Email senden"))
Gruß,
steve1da
Antworten Top
#3
Erstmal danke!

Jetzt die Formel:
Code:
=WENN(UND($J7<>"";$E7<HEUTE());HYPERLINK("mailto:"&$J7&"?subject="&$E7&"&body="&"Sehr geehrte"&WENN(UND(J7<>"";H7="";I7="");" Damen und Herren,";WENN(H7="Herr";"r Herr"&" "&I7;" Frau"&" "&I7)&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&$B7&""" seit "&TEXT($E7;"TT.MM.JJJJ")&" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a");"Email senden"))

Problem:

1. ist weder Anrede , Name und Mailadresse nicht eingetragen, wird ein Datumslink mit dem Wert 0 erstellt.
2. fehlt Anrede und Name, wird nur die Anrede "Sehr geehrten Damen und Herren," ohne weiteren Text im Body angezeigt.
3. ist eine Mailadresse und Name eingetragen, aber es fehlt die Anrede, wird automatisch "Frau" gesetzt.
Antworten Top
#4
Hallöchen,

1)
wenn schon mal ein Hyperlink in einer Zelle stand, kann das passieren.

Hier mal eine leicht verBesserte Formel
=WENN(UND($J7<>"";$E70);HYPERLINK("mailto:"&$J7&"?subject="&$E7&"&body="&"Sehr geehrte"&WENN(H7="Herr";"r Herr";" "&H7)&WENN(H7&I7="";"Damen und Herren, ";" "&I7&", ")&"%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden");"nix senden")

--> Anrede zusammensetzen leicht anders
--> ich prüfe zusätzlich, ob in E7 etwas größer 0 steht - kein Eintrag wäre ansonsten kleiner heute()
--> ich gebe zusätzlich "nix senden" aus.

2)
passiert bei mir nicht. Allerdings müsste man das Datum noch in einen Text wandeln - ansonsten erscheint die laufende zahl des Datums als Betreff Sad

3)
bei mir würde nix erscheinen, also im Prinzip "Sehr geehrte Meier,"
.      \\\|///      Hoffe, geholfen zu haben.
       ( ô ô )      Grüße, André aus G in T  
  ooO-(_)-Ooo    (Excel 97-2019+365)
Antworten Top
#5
Hi,

hier mal eine kürzere Version der Formel:

Code:
=WENN(ODER($J7="";$E7>=HEUTE());"";HYPERLINK("mailto:"&$J7&"?subject="&TEXT($E7;"TT.MM.JJJJ")&"&body="&"Sehr geehrte"&WENN((H7="")*(I7="");" Damen und Herren";WENN(H7="Herr ";"r Herr";" Frau "))&$I7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden"))

Als Betreff und als Arbeit das Datum (E7)?
Datum muß auf jeden Fall als Text eingetragen werden!
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#6
Erstmal vielen dank!

Mein jetziger code:
Code:
=WENN(UND($J7<>"";$E7<HEUTE());HYPERLINK("mailto:"&$J7&"?subject="&$B7&"&body="&"Sehr geehrte"&WENN(H7="Herr";"r Herr";" "&H7)&WENN(H7&I7="";"Damen und Herren, ";" "&I7&", ")&"%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung  """&$B7&""" seit """ &TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden");"")

Fehlerberichte:

aktuell
wenn Anrede = Herr und Name leer = Sehr geehrter Herr, (falsch) = soll = Sehr geehrte Damen und Herren
wenn Anrede = Frau und Name leer = Sehr geehrte Frau, (falsch) = soll = Sehr geehrten Damen und Herren
wenn Anrede = Frau und Name <> leer = Sehr geehrte Frau XX,   (richtig)
wenn Anrede = Herr und Name <> leer = Sehr geehrte Herr XX,   (richtig)
wenn Anrede = leer und Name leer = Sehr geehrten Damen und Herren   (richtig)

Soll Hauptprüfung:
J7 (Emailadresse) muss immer <>"" um Emaillink anzuzeigen
WENN(UND(H7="";I7="");"Sehr geehrten Damen und Herren (Immer wenn Anrede und Name leer dann Sehr geehrten Damen und Herren)

H7 = Herr/Frau
I7 = Name
Antworten Top
#7
Hi,

hast Du überhaupt eine der Formeln ausprobiert, die wir Dir vorgestellt haben?


.xlsx   Mail_to.xlsx (Größe: 11,25 KB / Downloads: 3)
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#8
Da ist genauso dass problem!

  14.02.2024


Herr

a@a.de
Email senden
mailto:a@a.de&14.02.2024Sehr geehrter Herr, mir ist aufgefallen, dass die Wartung/Prüfung "14.02.2024" überfällig ist.Ich bitte Sie, diese umgehend nachzuholen!

Name ist leer!

Da muss sehr geehrten Damen und Herren raus kommen!

Wenn Anrede oder Name leer immer sehr geehrten Damen und Herren !
Antworten Top
#9
Hi,


dann so:

Code:
=WENN(ODER($J7="";$E7>=HEUTE());"";HYPERLINK("mailto:"&$J7&"?subject="&TEXT($E7;"TT.MM.JJJJ")&"&body="&"Sehr geehrte"&WENN((H7="")+(I7="");" Damen und Herren";WENN(H7="Herr";"r Herr";" Frau "))&$I7&",%0d%0a%0d%0a, mir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden"))
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#10
Hallo Andreas,

vielleicht so ?

Arbeitsblatt mit dem Namen 'Tabelle1'
EFGHIJKL
6DatumHerr/FrauNameMailadresseAnredeLink
720.08.2024HerrMüllerHorst@werSehr geehrter Herr Müller
812.02.2024HerrMüllerSehr geehrter Herr Müller
912.02.2024HerrMüllerHorst@werSehr geehrter Herr MüllerEmail senden
1012.02.2024HerrWalter@senSehr geehrte Damen und HerrenEmail senden
1112.02.2024FrauMüllerFer@werSehr geehrte Frau MüllerEmail senden
1212.02.2024FrauFer@werSehr geehrte Damen und HerrenEmail senden
1312.02.2024Fer@werSehr geehrte Damen und HerrenEmail senden
1412.02.2024MüllerFer@werSehr geehrte(r) Herr/Frau MüllerEmail senden
1512.02.2024Fer@werSehr geehrte Damen und HerrenEmail senden

ZelleFormel
K7="Sehr geehrte"&WENN(I7="";" Damen und Herren";WENN(H7="Herr";"r Herr "&I7;WENN(H7="Frau";" Frau "&I7;"(r) Herr/Frau "&I7)))
L7=WENN(ODER($E7>=HEUTE();J7="");"";HYPERLINK("mailto:"&$J7&"?subject="&TEXT($E7;"TT.MM.JJJJ")&"&body="&K7&",%0d%0a%0d%0amir ist aufgefallen, dass die Wartung/Prüfung """&TEXT($E7;"TT.MM.JJJJ")&""" überfällig ist.%0d%0aIch bitte Sie, diese umgehend nachzuholen!%0d%0a%0d%0a";"Email senden"))
Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021
Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Ich würde die Anrede in einer separaten Spalte ermitteln. Das läßt sich dann besser prüfen/überwachen und vereinfacht die mailto-Formel.

Gruß
Fred


Angehängte Dateien
.xlsx   e-mail senden_fs.xlsx (Größe: 10,83 KB / Downloads: 0)
< es lebe die Hilfsspalte >
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste