Hallo zusammen.
Ich habe folgende Tabelle. siehe Anhang
Ich möchte das die Zahlen die in Spalte "E" stehen in Spalter "B" & "C" geschrieben werden aber so das diese immer auf der Reihe der JES stehen. Abhängig davon ob es sich um OC bzw. M** handelt.
Wie kann ich das am besten umsetzen, habe schon alles mögliche versucht komme aber leider nicht weiter.
DANKE
Hi,
in Deinem Beispiel funktioniert:
B23:
=WENN(LINKS(D24)="M";E24;"")
C23:
=WENN(UND(B23="";LINKS(D23)="J");E24;WENN(LINKS(D23)="J";E25;""))
Beide Formeln runterkopieren.
Hi Boris.
Danke hat super geklappt.
Aber was mache ich wenn ich 2 mal M** nach der JES Zeile habe.
Wie kann ich wie in dem Beispiel die 5+1 in die Zeile mit dem JES schreiben
DANKE
Hi,
bevor ich jetzt antworte, zeig mal bitte alle möglichen Szenarien. Lad dazu bitte eine Beispieldatei hoch, in der man das auch direkt testen kann.
Hi.
Ja klar kein Problem.
Hier die Beispiel Datei
Hi,
etwas komplexer:
B23:
Code:
=WENN(LINKS(D23)<>"J";"";SUMMEWENN(D24:INDEX(D24:D$156;VERGLEICH("J*";D24:D$156;));"M*";E24:INDEX(E24:E$156;VERGLEICH("J*";D24:D$156;))))
C23:
Code:
=WENN(LINKS(D23)<>"J";"";SUMMEWENN(D24:INDEX(D24:D$156;VERGLEICH("J*";D24:D$156;));"O*";E24:INDEX(E24:E$156;VERGLEICH("J*";D24:D$156;))))
Beide Formeln runterkopieren.
Um die Nuller noch auszublenden: Spalten B und C formatieren mit benutzerdefiniertem Zellformat:
0;-0;;
Hallo Boris.
DANKE hat super geklappt
Hallo Boris.
Wie per PM besprochen hier die Datei.
DANKE
Hallo Boris.
Hier die andere Datei.
Danke für deine HILFE.
Hi,
in Zeile 1:
Code:
=WENN(LINKS(A1)<>"J";"";WENNFEHLER(INDEX(A2:INDEX(A2:A$182;VERGLEICH("J*";A2:A$182;));VERGLEICH("M*";A2:INDEX(A2:A$182;VERGLEICH("J*";A2:A$182;));0));""))
und runterkopieren. Mit Deiner Excel-Version solltest Du auch bereits die LET-Funktion zur Verfügung haben - mit dieser sähe die Alternativformel so aus:
Code:
=WENN(LINKS(A1)<>"J";"";LET(x;VERGLEICH("J*";A2:A$182;);y;A2:INDEX(A2:A$182;x);WENNFEHLER(INDEX(y;VERGLEICH("M*";y;0));"")))
und runterkopieren.