Benötige eure Hilfe
Es soll wenn ein Feiertag ist ein F drinstehn anstatt ein anderes Kürzel
=IF(AND(OR(AND(J5>=$F$5;J5<=$F$6);AND(J5>=$F$7;J5<=$F$8);AND(J5>=$F$9;J5<=$F$10);AND(J5>=$F$11;J5<=$F$11);AND(J5>=$F$12;J5<=$F$13);AND(J5>=$F$14;J5<=$F$15);AND(J5>=$F$16;J5<=$F$16);AND(J5>=$F$17;J5<=$F$18);AND(J5>=$F$20;J5<=$F$21));if(ISERROR(VLOOKUP(J5;$B$5:$B$17;2));$A$3);ISNUMBER(J5));$E$3;"")
Datei ist beigefügt
Hola,
auch dir einen wunderschönen guten Morgen....
Pack eine Prüfung auf das Datum vor deine Formel:
Code:
=WENN(ZÄHLENWENN($B$5:$B$20;J5);"F";wenn(und(.....
Gruß,
steve1da
Es kommt eine fehlermeldung es wird nicht gewechselt das es ein F oder ein SF ist.
Holz
bei mir kommt keine Fehlermeldung und es wird bei einem Feiertag F angezeigt.
Da du aber nicht in der Lage bist wenigstens die Tageszeit zu nennen bin ich hier raus.
Gruß,
steve1da
Der 1.1 ist ein Feiertag dort müsste ein F stehen anstatt SF das datum SF ist vorgegeben und soll mit Feiertage "F" ersetzt werden wenn es ein Feiertag ist.
Hallo,
hier: WENN(ISTFEHLER(SVERWEIS(J5;$B$5:$B$17;2));$A$3);ISTZAHL(J5));$E$3;"") gibt es schon mal einen gewaltigen Fehler. Wenn die Matrix (blau) des SVerweis über die Zellen B5 bis B17 läuft, kann der Spaltenindex (rot) nicht die Zahl 2 einnehmen.
Weiter würde ich dringend raten, die verbundenen Zellen heraus zu nehmen, die verursachen nur Probleme.
Hallo,
deine Formel in L5 für den 1.1.2021 lautet wie folgt:
=WENN(UND(
ODER(UND(J5>=$F$5;J5<=$F$6);UND(J5>=$F$7;J5<=$F$8);UND(J5>=$F$9;J5<=$F$10);UND(J5>=$F$11;J5<=$F$11);UND(J5>=$F$12;J5<=$F$13);UND(J5>=$F$14;J5<=$F$15);UND(J5>=$F$16;J5<=$F$16);UND(J5>=$F$17;J5<=$F$18);UND(J5>=$F$20;J5<=$F$21));
WENN(ISTFEHLER(SVERWEIS(J5;$B$5:$B$17;2));$A$3);
ISTZAHL(J5)
);$E$3;"")
Dabei sollen folgende ODER-verknüpfte UND-Ausdrücke WAHR liefern, wenn es sich bei J5 um ein Schulferien-Datum handelt, sonst FALSCH:
ODER(UND(J5>=$F$5;J5<=$F$6);UND(J5>=$F$7;J5<=$F$8);UND(J5>=$F$9;J5<=$F$10);UND(J5>=$F$11;J5<=$F$11);UND(J5>=$F$12;J5<=$F$13);UND(J5>=$F$14;J5<=$F$15);UND(J5>=$F$16;J5<=$F$16);UND(J5>=$F$17;J5<=$F$18);UND(J5>=$F$20;J5<=$F$21));
Ich habe ihn kurz IstSchulferien getauft.
Der zweite Teilausdruck liefert STETS den Wert "F", denn er enthält offenbar mehrere Fehler:
WENN(ISTFEHLER(SVERWEIS(J5;$B$5:$B$17;2));$A$3);
Offenbar sollte er WAHR liefern, wenn es sich um einen Feiertag (Zellbereich B5:B17) handelt, sonst FALSCH:
WENNNV(SVERWEIS(J5;$B$5:$B$17;1;0);0)>0
Ich habe ihn kurz IstFeiertag getauft.
Der dritte Teilausdruck müsste eigentlich stets WAHR liefern:
ISTZAHL(J5)
denn es ist kaum anzunehmen, dass er auf etwas anderes als ein Datum (=Zahl) anzuwenden ist.
Ich habe ihn kurz IstDatum getauft
Setzt man deine Formel mit den Kurzbezeichnungen wieder zusammen, so ergibt sich folgende Struktur:
=WENN(UND(IstSchulferien; IstFeiertag; IstDatum); $E$3; "")
wobei sich bei dir für Zelle J5 (=1.1.2021) folgende Zwischenresultate ergeben:
=WENN(UND(WAHR;"F";WAHR);"SF";"")
was wiederum als Endresultat "SF" liefern muss, was natürlich unbefriedigend ist.
Da einige Feiertage gleichzeitig in den Schulferien enthalten sind, so nehme ich an, möchtest du zuerst die Feiertage angezeigt bekommen -
ferner falls es kein Feiertag ist, ob es ein Schulferientag ist - anderenfalls soll eine leere Anzeige erfolgen.
Somit müsste die Formelstruktur sein:
=WENN(IstFeiertag; "F"; WENN(IstSchulferien; "SF"; ""))
und somit, wenn man die berichtigten Teilausdrücke heranzieht:
=WENN(WENNNV(SVERWEIS(J5;$B$5:$B$17;1;0);0)>0;[b]$A$3;[/b]
WENN(ODER(UND(J5>=$F$5;J5<=$F$6);UND(J5>=$F$7;J5<=$F$8);UND(J5>=$F$9;J5<=$F$10);UND(J5>=$F$11;J5<=$F$11);UND(J5>=$F$12;J5<=$F$13);UND(J5>=$F$14;J5<=$F$15);UND(J5>=$F$16;J5<=$F$16);UND(J5>=$F$17;J5<=$F$18);UND(J5>=$F$20;J5<=$F$21)); $E$3; ""))
Da du offenbar auch ein Fan von möglichst umständlichen Formeln bist, hast du die Von-Bis-Schulferien-Intervalle untereinander angelegt statt nebeneinander.
Hättest du das Von-Datum zB. in Spalte E und das bis Bis-Datum in Spalte F angelegt (jeweils ab Zeile 5), könnte man die Formel vereinfachen zu:
=WENN(WENNNV(SVERWEIS(J5;$B$5:$B$17;1;0);0)>0;[b]$A$3;[/b]WENN(SUMME(($E$5:$E$11<=J5)*(J5<=$F$5:$F$11));$E$3;""))
Korrektur: in Formeln enthaltene bzw. [b] gehören entfernt !![/b]