Clever-Excel-Forum

Hallo liebe Excel-Freunde,

ich stehe vor folgender Aufgabe:

Ich habe eine Tabelle mit meinen Kunden. Manche Kunden kaufen im Jahr nur ein Mal, manche gerne mehrmals. Dahinter die Beträge. Das heisst bei mir steht zum Beispiel

Kunde/Umsatz/Datum

Peter/12,00 €/04.05.2020
Martina/23,00 €/05.05.2020
Thorsten/129,00 €/05.05.2020
Peter/43,99 €/ 06.05.2020
Tobias/23,99 €/06.05.2020
Amelie/12,00 €/06.05.2020
Martina/23,99 €/07.05.2020
Elena/200,00 €/07.05.2020
Peter/12,49 €/07.05.2020

usw.

Nun habe ich eine zweite Liste erstellt, in der die Namen stehen, ohne Duplikate. Also somit eine Kundenliste, die aus der Umsatzliste generiert wurde.

Nun zu meinem Problem:

Hinter jedem Kunde soll sein Durschnittlicher Umsatz stehen. Gibt es eine Funktion die den Mittelwert aus allen Umsätzen eines Kunden berechnet?

Falls ich mich unklar ausgedrückt habe, versuche ich gerne es besser zu beschreiben.

Vielen lieben Dank!

Angelo

=MITTELWERTWENN(A:A;J1;B:B)

oder


=SUMMEWENN(A:A;J1;B:B)    /    ZÄHLENWENN(A:A;J1)

LG UweD

Moin!
Paradebeispiel für ein Pivot-Table, ganz ohne Formeln.
Kunde in Zeilen
Umsatz in Werte
Werte zusammenfassen nach Mittelwert
Fettich

	A	B	C	D	E	F
1	Kunde	Umsatz	Datum		Kunde	Mittelwert von Umsatz
2	Peter	12,00 €	04.05.2020		Amelie	12,00 €
3	Martina	23,00 €	05.05.2020		Elena	200,00 €
4	Thorsten	129,00 €	05.05.2020		Martina	23,50 €
5	Peter	43,99 €	06.05.2020		Peter	22,83 €
6	Tobias	23,99 €	06.05.2020		Thorsten	129,00 €
7	Amelie	12,00 €	06.05.2020		Tobias	23,99 €
8	Martina	23,99 €	07.05.2020		Gesamtergebnis	53,38 €
9	Elena	200,00 €	07.05.2020
10	Peter	12,49 €	07.05.2020

Gruß Ralf

Oder (in 365/xlWeb), wenn a) ohne Überschriften und b) Daten in A1:C9:, als ein "1-Formel-Pivot-Ersatz" (Iteration nicht nötig):

=WAHL({1.2};
EINDEUTIG($A1:INDEX($A:$A;ANZAHL2($A:$A)));MITTELWERTWENN($A1:$A999;
EINDEUTIG($A1:INDEX($A:$A;ANZAHL2($A:$A)));$B1:$B999))

oder auch

=LET(q;EINDEUTIG(A1:INDEX(A:A;ANZAHL2(A:A)));WAHL({1.2};q;MITTELWERTWENN(A1:A999;q;B1:B999)))

(letzteres nur 365 beta, Insider oder whatsoever, aber nicht GDocs/XLWeb)

Hi,

Zitat:=LET(q;EINDEUTIG(A1:INDEX(A:A;ANZAHL2(A:A)));WAHL({1.2};q;MITTELWERTWENN(A1:A999;q;B1:B999)))

(letzteres nur 365 beta, Insider oder whatsoever, aber nicht GDocs/XLWeb)

mittlerweile auch im normalen mtl. Kanal:  [attachment=34500]

Das ist gut. Dann verbreitet es sich etwas schneller. :)