Clever-Excel-Forum

Hey alle zusammen,

im Moment bin ich so ein bisschen am verzweifeln weil ich an einer Übung hacke. Und zwar sollen wir ohne VBA folgende Funktion basteln:

Gebt in Zelle A3 ein beliebiges Wort ein. In Zelle B3 soll dann dieses Wort ohne alle kleinen Vokale (a,e,i,o,u) ausgegeben werden (Beispiel: Aus "AutorAdIo" wird so dann "AtrAdI")

Was ich schon hinbekommen habe ist: =(ERSETZEN(A3;SUCHEN("a";A3;2);1;""))
Wie bekomme ich das jetzt aber hin das ich nach allen Vokalen gleichzeitig suche und wie achte ich auf Groß/Kleinschreibung ohne in VBA zu programmieren?
Anbei die Funktionen die wir verwenden sollen.
[attachment=33293]
Vielen lieben Dank in vorraus

Hallo
suchen unterscheidet nicht zwischen groß- und Kleinschreibung, dafür gibt es die Funktion finden
Schau dir auch mal wechseln an!

Gruß Holger

Weil die Funktion WECHSELN nicht in der Liste war:
=WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1;"a";"");"e";"");"i";"");"o";"");"u";"")
Gehe aber mal mit F2 in den Formeleditor und markiere den Teil WECHSELN(A1;"a";"") und drücke F9 usw., damit Du alles nachvollziehst und verstehst.

=TEXTVERKETTEN(;;WENN(ISTZAHL(FINDEN(
TEIL(A1;SEQUENZ(99);1);"aeiou"));"";
TEIL(A1;SEQUENZ(99);1)))

ist leider nicht erlaubt, wird vermutlich aber das kürzeste sein. Oder die Fahrradkette:

=TEXTKETTE(WENN(ISTZAHL(FINDEN(
TEIL(A1;SEQUENZ(99);1);"aeiou"));"";
TEIL(A1;SEQUENZ(99);1)))

oder ganz neu:

=LET(x;TEIL(A10;SEQUENZ(99);1);
TEXTKETTE(WENN(ISTZAHL(FINDEN(x;"aeiou"));"";x)))

(30.07.2020, 17:23)LCohen schrieb: [ -> ]=TEXTVERKETTEN(;;WENN(ISTZAHL(FINDEN(
TEIL(A1;SEQUENZ(99);1);"aeiou"));"";
TEIL(A1;SEQUENZ(99);1)))

ist leider nicht erlaubt, wird vermutlich aber das kürzeste sein. Oder die Fahrradkette:

=TEXTKETTE(WENN(ISTZAHL(FINDEN(
TEIL(A1;SEQUENZ(99);1);"aeiou"));"";
TEIL(A1;SEQUENZ(99);1)))

oder ganz neu:

=LET(x;TEIL(A10;SEQUENZ(99);1);
TEXTKETTE(WENN(ISTZAHL(FINDEN(x;"aeiou"));"";x)))

Langweilig Smile

Am kürzesten ist es mit der neuen Excel 366 Funktion Vokale_wech:

Code:
=Vokale_wech(A1)

PS:

Code:
Function Vokale_wech(ByVal s As String) As String

'New Excel 366 function :-)

Dim c: For Each c In Array("a", "e", "i", "o", "u"): s = Replace(s, c, ""): Next c: Vokale_wech = s

End Function

=GESCHACHTELTWECHSELN() ist ein Antrag an MS, genauso wie =SPLITTEN()

Bei Deinem ersten WECHSELN können noch 10 Gänse weg.

Lufkin

echo

Sulprobil

LCohen

Sulprobil

LCohen