Liebe Gemeinde,
ich möchte zunächst vorausschicken, dass ich ein absoluter Excel-Noob bin. Eventuelle Hilfestellungen sollten daher diesem Niveau angepasst sein. :32:
Mein Problem: Ich möchte eine beliebige (große) Zahl durch Punkte, die in einem annähernden Rechteck/Quadrat angeordnet sind, visualisieren.
Die Zahl wird also aufgeteilt in: Zahl = AnzahlSpalten x AnzahlZeilen + Rest.
Beispiel: 18 = 4 x 4 +2
A B C D
1 • • • •
2 • • • •
3 • • • •
4 • • • •
5 • •
Wie kann ich - bei gegebenen Werten von AnzahlSpalten, AnzahlZeilen und Rest - die Punkte automatisch in ein Excel-Blatt anordnen lassen?
Besten Dank schon mal für jede Hilfe!
Gruß
Düx
Code:
=WENN((SPALTE(A1)+ZEILE(A1)*4-4)<=$G$1;"X";"")
Hallo
In G1 steht dein Wert
Die oben stehende Formel fügt ein "X" ein
Die Formel in die oberste linke Zelle kopieren, dann weiter kopiern bis in die 4. Spalte
die 4 Spalten markieren und runter kopieren so weit wie du sie benötigst
Gruß Holger
Diese Lösung ist zu dicht am Beispiel ausgerichtet (4 Spalten) und auch nur bei kleinen Zahlen praktikabel. Bei zum Beispiel 32812 = 181 x 181 + 51 wird das eher unhandlich. Ich suche eher eine allgemein gültige Lösung, die bei der Vorgabe der drei Werten AnzahlSpalten, AnzahlZeilen und Rest das Feld automatisch erstellt.
Dennoch erstmal besten Dank!
Moin
Ich habe nur eine Lösung für die Abo-Version (alternativ auch Excel Online).
Code:
=WENN(SEQUENZ(AnzahlZeilen+1;$AnzahlSpalten)<=Gesamt;"•";"")
Du kannst Zeilen, Spalten einfügen so viel wie du möchtest.
Auch den Wert eines X kann man natürlich auch anpassen.
Davon war zuerst aber nicht die Rede
Siehe Anhang
Gruß Holger
@shift-del
Zitat:=WENN(SEQUENZ(AnzahlZeilen+1;$AnzahlSpalten)<=Gesamt;"•";"")
Ich glaube, das ist genau das, was ich gesucht habe, denn soweit ich die Funktion SEQUENZ verstanden habe, wird mit einer einzigen Formal das komplette Feld erzeugt. Nur leider steht mir diese Funktion mit meinem Office 2016 nicht zur Verfügung. Sehr schade! Und ich wüsste auch nicht, dass ich diese Funktion in meiner Office-Version nachrüsten könnte.
@echo
Zitat:Auch den Wert eines X kann man natürlich auch anpassen. Davon war zuerst aber nicht die Rede.
Ich verstehe, was du meinst, aber ich weiß nicht, wie du darauf gekommen bist, dass ich das wollen würde. Da hast du irgendwas missverstanden. Egal. Ich denke, dass ich mit deiner überarbeiteten Version auskommen kann. Für meine Zwecke reicht das. Besten Dank!
Hallo,
richtig --->
in deiner angegebenen Version gibt's
kein SEQUENZ()...
Ich würde das sicher so lösen wollen -
allerdings auch mit SEQUENZ()..:
Ich beginne nicht in der Spalte A, weil die Formel SEQUENZ()
das Array (
automatisch)
bildet - nach den Vorgaben aus B1 bis B4...
Vorteil hier bei SEQUENZ() - es ist
nur eine Formel (für das Array) nötig.. ...
man braucht kein Formelvorrat!!!
| Arbeitsblatt mit dem Namen 'Tabelle2' |
| A | B | C | D | E | F | G |
| 1 | Vorgabe | 22 | | • | • | • | • |
| 2 | Zeile(n) | 4 | | • | • | • | • |
| 3 | Spalte(n) | 4 | | • | • | • | • |
| 4 | Zus.Zeile(n) | 2 | | • | • | • | • |
| 5 | Anz. • | 22 | | • | • | • | • |
| 6 | | | | • | • | | |
| Zelle | Formel |
| D1 | =WENN(SEQUENZ(B2+B4;B3)<=B1;"•";"") |
| B2 | =GANZZAHL(B1^0,5) |
| B3 | =B2 |
| B4 | =(B1>(B2^2))*1+(B1-(B2^2)>B2) |
| B5 | =ZÄHLENWENN(D1#;"•") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Ich möchte noch korrigieren, dass für ein zweidimensionales Feld auch nur Gesamt, AnzZ oder Gesamt, AnzS nötig sind und einzugeben sein dürfen!
Der vierte Parameter RestInZeile hingegen ist ungenügend, da damit nicht eindeutig definiert wird, ob bei 22 Gesamt und 2 Rest nun 5x4 oder 4x5 oder 2x10 als Komplett-Feld-Anteil vergeben werden sollen.
...das mit dem Waffeldiagramm war wohl doch nicht so ganz das Richtige/passende.
Im Anhang eine Beispieldatei mit einer Formellösung mit variabler Spaltenzahl.
Formel in Zelle B6 (nach rechts und nach unten kopieren)
=WENN(UND(SPALTEN($B6:B$6)<=$R$2;SPALTEN($B6:B$6)+$R$2*(ZEILEN($B6:B$6)-1)<=$P$2);$U$2;"")
in Zelle P2 steht der Wert, der "in Punktform" dargestellt werden soll
in Zelle R2 steht die gewünschte Spaltenanzhahl (Breite)
in Zelle U2 steht das Zeiche, das eingetragen werden soll (Punkt,etc...)
Gruß
Fred