Clever-Excel-Forum

Hallo Zusammen,

ich hoffe wirklich ihr könnt mir helfen 

Mein Problem: ich habe eine Tabelle in der ich mehrere Abfragen einbauen möchte - Alter, Geschlecht & Punktewert. Herausgegeben werden soll dann anhand einer Liste ein Gesamtwert.

Beispiel:

gegeben ist männlich (genaue Übereinstimmung), 20 Jahre (genaue Übereinstimmung), Punktwert von 0,78 (ungenaue, aufsteigende Übereinstimmung) - die Tabelle gibt den Punktwert in Spannen (z.B. 0,75-1,45) an.

Ausgegeben werden soll dann beim nächstpassenden Treffer (abhängig vom Punktewert) ein Gesamtwert.

Der Svergleich mit Wahl um alter und Geschlecht herauszufinden ist kein Problem, ich kriege aber die dritte Abfrage mit ungefährem Wert (Punktewert) nicht heraus.

Über ein Feedback und Anregungen von euch würde ich mich sehr freuen

Moin

VERWEIS() und vielleicht auch SUMMEWENNS().

Hallo,

hier zwei mögliche Formeln zur Ermittlung des entsprechenden Wertes aus Spalte E:
=SUMMENPRODUKT(($A$3:$A$72=$I$3)*($B$3:$B$72=$I$2)*($I$4>=$C$3:$C$72)*($I$4<=$D$3:$D$72);$E$3:$E$72)
=INDEX($E$1:$E$72;AGGREGAT(15;6;ZEILE($A$1:$A$72)/(($A$1:$A$72=$I$3)*($B$1:$B$72=$I$2)*($I$4>=$C$1:$C$72)*($I$4<=$D$1:$D$72));ZEILE(A1)))

Damit diese Formeln bei einem Punktwert oberhalb des höchsten von-Wertes korrekt funktionieren muss  beim bis-Wert auch ein Wert drinstehen (in deiner Liste aktuell leer)
Siehe angehängte Beispieldatei

Oder du arbeitest mit einer Hilfsspalte, in der du prüfst, in welchen Wertebereich der gesuchte Punktwert fällt (siehe Beispieldatei) und beziehst diese dann in deine bisherige Abfrage mit ein


Zu deinen Punktwert-Bereichen (Spalten C und D) habe ich allerdings noch zwei Anmerkungen / Fragen:

1. In Spalte C und D (Punktwert von, bis) kommt teilweise der Wert 0,00 mehrfach vor.
Welcher Wert aus Spalte E (Stanine-Wert) soll denn dann bei einem Punktwert von 0,00 zurückgegeben werden ?
(Die Summenprodukt-Formel gibt in diesem Fall einen falschen Wert zurück !)

2. Die Bereiche mit den Punktwerten haben Lücken !
Ist das so gewollt ?
Welcher Wert aus Spalte E (Stanine-Wert) soll denn bei einem Punktwert, der zwischen den Bereichen liegt, zurückgegeben werden ?
Zum Beispiel:
Männlich, 4-6 Jahre, Punktwert 0,6
(Die Summenproduktformel ergibt in diesem Fall 0, die AGGREGAT-Formel eine Fehler)

Gegebenenfalls musst du hier deine Liste nochmal etwas überarbeiten…

Gruß
Fred

Moin!
Abseits der von Fred festgestellten Mängel in der Liste mal der Vorschlag mit SUMMEWENNS() umgesetzt:
=SUMMEWENNS(E3:E72;A3:A72;I3;B3:B72;I2;C3:C72;"<="&I4;D3:D72;">="&I4)

Gruß Ralf

Hi Olofolo,

wenn es dir nicht so Aufwendig ist und du nicht so oft damit arbeitest, würdeich dir die Filterfunktion im zusammenhang mit der Teilergebnis Funktion empfehlen.

Habe dir im Anhang ein Bsp. beigefügt.

Hoffe dir geholfen zu haben.

---