Hallo zusammen,
ich möchte gern fragen ob es einen Weg gibt, wie man eine Pivottabelle welche man basierend der Daten in Tabelle 1 (sorry für das nicht umbennen) in ein Pivot konvertiert, , ob es dann eine autmatisierte Möglichkeit gibt, dass es dann eine Tabellenauswertung wie in Tabelle "Ziel" gibt? Ich möchte am liebsten, dass wenn ich die Daten in der Tabelle "Tabelle1" aktualisiere, sich das Pivot aktualisiert und somit auch die entsprechenden kleinen Untertabellen im Reiter "Ziel".
Ist das überhaupt technisch möglich?
Danke und Gruss
Hoppolero
PS: Ich will es dann mit Namen definierren und als Dropdown weiterverwenden.
PSS: Ich dachte in der SuFu könnte ich es unter "Pivot Tabelle Gruppieren" finden, aber klappt leider nicht :(
Hallo Hoppolero,
Deiner Pivotauswertung bedarf es nicht. Es geht einfacher ohne.
Wenn Du untenstehende Formel B1 weit genug nach rechts und A2 nach rechts und unten kopierst, erhältst Du sehr schnell die gewünschte Aufstellung.
Arbeitsblatt mit dem Namen 'Ziel' |
| A | B | C |
1 | Abteilung 1 | Abteilung 2 | Abteilung 3 |
2 | Name 1 | Name 11 | Name 20 |
3 | Name 2 | Name 12 | Name 21 |
4 | Name 3 | Name 13 | Name 22 |
5 | Name 4 | Name 14 | Name 23 |
6 | Name 5 | Name 15 | Name 24 |
7 | Name 6 | Name 16 | Name 25 |
8 | Name 7 | Name 17 | Name 26 |
9 | Name 8 | Name 18 | Name 27 |
10 | Name 9 | Name 19 | Name 28 |
11 | Name 10 | | Name 29 |
12 | | | Name 30 |
13 | | | |
Zelle | Formel |
A2 | =WENN((A1="")+(ZEILE(A1)>ZÄHLENWENN(Tabelle1!$B:$B;A$1));"";INDEX(Tabelle1!$A:$A;VERGLEICH(A$1;Tabelle1!$B:$B;0)-2+ZEILE())) |
A1 | =Tabelle1!B2 |
B1 | =WENNFEHLER(INDEX(Tabelle1!$B:$B;AGGREGAT(15;6;ZEILE(A2:A99)/(Tabelle1!$B2:$B99>0)/(ZÄHLENWENN($A1:A1;Tabelle1!$B2:$B99)=0);SPALTE(A1)));"") |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Danke für eure Lösungen. Am Ende hat mir in der Tat die Variante von Neopa perfekt geholfen. Ich bin begeistert. Ich muss gestehen, ich hätte es wohl nicht so hinbekommen, da mir momentan einfach das Wissen fehlt für diese Formeln aber ich bin froh, dass ihr mir so geholfen habt.
Leider habe ich meine Mühe wie die Funktion eigentlich genau wirkt, aber damit werde ich mich zu gegebener Zeit auseinandersetzen.
Jetzt versuche ich weiter mein "Projekt" zu lösen. :)
Danke für eure Hilfe.
PS: Power Query ging leider nicht, da ich auf dem Arbeits-PC nur bedingte Rechte für Installationen habe. Aber auch dir vielen Dank @shift-del
Was kann es für einen Grund geben, dass nicht alle Abteilungen korrekt als Überschrift wiedergegeben werden in der Zieltabelle. Es werden Abteilungen aus der Tabelle welche in der Reihenfolge davor und danach stehen, ausgegeben, aber nicht die zwischendrin....
Merkwürdig...
Hallo zusammen,
ich habe mal die Datei angepasst, musste aus Datenschutzgründen aber die Namen unkenntlich machen[img]
Dateiupload bitte im Forum! So geht es: Klick mich!].
2 Probleme fallen mir direkt auf:
- MaterialPlaningOrdering fehlt in der Tabelle "Konvertiert"
- Warehousing laufen die Namen doppelt auf in "Konvertiert"
Ich befürchte es könnte noch mehr Fehler geben, finde aber gerade keine.
Ich möchte am Ende in der Tabelle "Dropdown" in Abhängigkeit von der Abteilung dann den Mitarbeiter Namen auswählen.
Ich hoffe ich denke bei der ganzen Nummer nicht zu kompliziert!
Gruss
Matze
PS: Danke für eure Hilfe!
Hallo Matze,
... die Formel
in B1 muss richtig wie folgt lauten:
Code:
=WENNFEHLER(INDEX('Namen Filter'!$B:$B;AGGREGAT(15;6;ZEILE(A2:A500)/('Namen Filter'!$B2:$B500>0)/(ZÄHLENWENN($A1:A1;'Namen Filter'!$B2:$B496)=0);1));"")
und diese nach rechts kopieren. Also darin als letzten Argument der AGGREGAT()-Formel eine 1 anstelle SPALTE(A1)
[Nachtrag:]
Dein Tabellenblatt "Namen_Filter" kannst Du einsparen, wenn Du im Tabellenblatt "Konvertiert"
in A1:
in B1:
Code:
=WENNFEHLER(INDEX('Liste von HR'!$D:$D;AGGREGAT(15;6;ZEILE(A2:A500)/('Liste von HR'!$D2:$D500>0)/(ZÄHLENWENN($A1:A1;'Liste von HR'!$D2:$D500)=0);1));"")
und in A2:
Code:
=WENN((A1="")+(ZEILE(A1)>ZÄHLENWENN('Liste von HR'!$D:$D;A$1));"";INDEX('Liste von HR'!$B$1:$B$500&", "&'Liste von HR'!$C$1:$C$500;VERGLEICH(A$1;'Liste von HR'!$D:$D;0)-2+ZEILE()))
einsetzt und B1 nach rechts und A2 zusätzlich weit genug nach unten kopierst.