Clever-Excel-Forum

Hallo zusammen,
meine Suche in den topics war nicht erfolgreich, deswegen die Frage.
In einer Tabelle habe ich die Patienten die in meinem Dienst im Jahr 2018 behandelt wurden. Jeder Patient kann 3 verschiedene Therapien bekommen und jeder Patient kann in jeder Sparte (Therapietyp) entweder "neu" oder "alt" sein. Ich sollte am Ende des Jahres imstande sein, die neuen Patienten und die alten (also keine doppel) separat.

Patient            TherapieA TherapieB TherapieC
mustermann         n            
Klaus                   a               n
Max                                      a             a
Erika                   n                n


"n" muss nur einmal gezählt werden im Fall von mehreren "n" auf einer Zeile.
wenn ein Patient in einer Sparte alt ist dann muss "n" nicht gezählt werden
wenn ein Patient in 2 bzw drei Sparten "alt" ist dann muss das nur 1 mal gezählt werden.

Leider ist die alte Führungskraft nicht mehr da und die Tabelle ist so konzipiert worden und demenstprechend auch ausgefüllt worden (800 Einträge ca)

Ich hoffe es ist nicht so kompliziert.

Hallo,

für mich nicht gerade verständlich. Lade bitte eine Beispieldatei (keine ScrShots!) mit händisch eingetragenen Wunschergebnissen hoch. So geht's: https://www.clever-excel-forum.de/thread-326.html

Anbei einen Auszug aus der Tabelle, die bis jetzt manuell ausgewertet worden ist ( :22: )

Hi,

ich hoffe, ich habe dich jetzt richtig verstanden, denn meine Bitte nach einem händisch eingetragenen Wunschergebnis hast du geflissentlich überlesen.

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C	D	E	F	G	H	I
3	NACHNAME VORNAME	GEB. AM	Spalte1	TherA	TherB	TherC	Neu	Alt
4	abc	26.05.11			a		0	1
5	dkj	27.10.14		a	a		0	1
6	ghio	06.06.16			a		0	1
7	vakj	13.09.06			a	n	0	0
8	jnvoasdfg	17.11.11			n		1	0
9	njasdof	06.12.11		n	n		1	0
10	djfa	12.09.14			a		0	1

Zelle	Formel
H4	=WENN(ZÄHLENWENN($E4:$G4;"a")>0;0;WENN(ZÄHLENWENN($E4:$G4;"n")>0;1;0))
I4	=WENN(ZÄHLENWENN($E4:$G4;"n")>0;0;WENN(ZÄHLENWENN($E4:$G4;"a")>0;1;0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Herzlichen Dank Günter,
das Ergebnis geht jetzt Zeile für Zeile und ich könnte am ende der Tabelle die Summe machen, ich bin schon zufrieden.
Ich dachte es gäbe eine Formel die in einer Zelle die ganzen neuen Patienten zählt und die alten.
Aber wie gesagt bin ich mit deinen Vorschlag schon sehr zufrieden.

LG Marco

Hi,

falls die die beiden Spalten stören, kannst du sie ausblenden und du schreibst einfach daneben die Summe.

Günter entschuldige,
ich habe gesehen, es fehlt eine Bedingung: sollte eine spalte ein "a" und eine eandere Spalte ein "n" enthalten dann ist der Patient nicht als neu sondern als Alt gezählt werden, wie kann man die 3 Bedingungen zusammen berücksichtigen?
Gelb markiert der Fall.

Hallo, meinst du so..?

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	H	I
2	N	A
3	0	1
4	0	1
5	1	0
6	0	1
7	0	1
8	0	1
9	0	1
10	0	1

Zelle	Formel
H3	=(((ZÄHLENWENN(D3:F3;H$2)>0)-(ZÄHLENWENN(D3:F3;I$2)>0))>0)*1
I3	=(ZÄHLENWENN(E3:G3;I$2)>0)*1

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Hallo,

so?

	A	B	C	D	E	F
2				TherA	TherB	TherC
3	asdf	26.01.11
4	dasf	17.12.07			n	a
5	asdf	15.07.04			n
6	asdd	15.05.13			a
7	a	15.05.13			a
8	sdfgffgadsf	20.02.12			a
9	gasdfg	28.12.03			n	a
10	afg	30.05.17			a	a
11
12	Anzahl Altpatienten:			6
13	Anzahl Neupatienten:			1
14	Anzahl Ohne Eintrag:			1

Zelle	Formel
D12	{=SUMME((MMULT((D3:F10="a")*1;{1;1;1})>0)*1)}
D13	{=SUMME((MMULT((D3:F10="n")-(D3:F10="a")*3;{1;1;1})>0)*1)}
D14	{=SUMME((MMULT((D3:F10="")*1;{1;1;1})=3)*1)}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Hallo Jörg,

du bist doch ein Freund für kürzere Formeln ... hast du nicht 2 Klammern zu viel gesetzt? "()"

	D	E	F	G	H	I
3		a			0	1

Zelle	Formel
H3	=((ZÄHLENWENN(D3:F3;H$2)>0)-(ZÄHLENWENN(D3:F3;I$2)>0)>0)*1
I3	=(ZÄHLENWENN(E3:G3;I$2)>0)*1

Gruß
Marcus