Hi
In meinem Bsp. ist A1 = Anfangsdatum und A2 = Enddatum.
In B1 und/oder B2 schreibst du die Monate die du Zählen möchtest, aber als Zahl. (für Januar = 1 ;Februar = 2 usw.)
C1 = Ergebnis
Gruß Elex
Das enddatum müsste aber B2 sein. dann wäre es perfekt . in Spalte c und d die zwei suchmonate und in E da ergebnis.
Hi
Ich denke mal du hast die Anpassung selbst versucht und bist an dem Teil ZEILE(A1:A1001) gescheitert. Diesen Teil einfach so lassen und alle anderen Bezüge an deine Wunschzellen anpassen.
Sieht dann so aus.
____|______A_____|______B_____|_C_|_D_|__E_|
1| 01.01.2017| | 1| 2| 14|
2| | 31.12.2023| | | |
E1 =SUMMENPRODUKT(ZÄHLENWENN(C1:D1;(MONAT((EDATUM(A1;ZEILE(A1:A1001)-1))/(EDATUM(A1;ZEILE(A1:A1001)-1)<=MONATSENDE(B2;0))))))
Gruß Elex
Hallo, für PhilippB.kommt das sicher nicht in Frage, aber ich könnte mir hier eine Power Query Lösung vorstellen. Danke für die Übung..:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E |
1 | von .. Bis | | Monate | | Ergebnis |
2 | 01.01.2017-31.08.2019 | | März | | 8 |
3 | | | April | | |
4 | | | Oktober | | |
5 | | | | | |
6 | | | | | |
7 | | | | | |
8 | | | | | |
9 | 01.01.2017 | | 3 | | 8 |
10 | 31.08.2019 | | 4 | | |
11 | | | 10 | | |
Zelle | Formel |
E9 | =SUMMENPRODUKT(ZÄHLENWENN(C9:C11;(MONAT((EDATUM(A9;ZEILE(A1:A1001)-1))/(EDATUM(A9;ZEILE(A1:A1001)-1)<=MONATSENDE(A10;0)))))) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Guten Morgen und riesen Danke.
Es funktioniert und ich schaue mir das später im Detail an.
Starkes Forum.
VG aus dem Norden
Hallo Elex,
im Anhang ist nochmal eine Test-Datei. In Zeile 2 funktioniert die Formel nicht richtig. Elex, magst du dir das nochmal anschauen?
VG,
Philipp
Hi
wenn du die Formel nach unten kopieren möchtest musst du ein paar Dollar investieren. :19:
Also so.
E1 =SUMMENPRODUKT(ZÄHLENWENN(C1:D1;(MONAT((EDATUM(A1;ZEILE($A$1:$A$1001)-1))/(EDATUM(A1;ZEILE($A$1:$A$1001)-1)<=MONATSENDE(B1;0))))))
Gruß Elex
Ich habe es nochmal ausprobiert. Mir war die mathematische Lösung wichtig, da ZEILE() bei so etwas nur ein Notbehelf sein sollte.
C1: =(JAHR(B1)-JAHR(A1)-1)*2+
(DATUM(JAHR(A1);1;2)>A1)+(DATUM(JAHR(A1);2;2)>A1)+
(DATUM(JAHR(B1);3;)<=B1)+(DATUM(JAHR(B1);2;)<=B1)
oder
C1: =(JAHR(B1)-JAHR(A1)-1)*2+
((1&-JAHR(A1))-A1>=0)+((2&-JAHR(A1))-A1>=0)+
((3&-JAHR(B1))-2<B1)+((2&-JAHR(B1))-2<B1)
mit B1-A1>=0 (Minuswerte stimmen nicht)
Hallo, was ist aber bei mehreren Monaten - nicht aufeinander folgende? Da ist Elex' Formel vorn. Oder eben meine Power Query Variante, die dem TE aber nicht hilft, weil erst ab XL2010 verfügbar..:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F |
1 | von .. Bis | | Monate | | Ergebnis | |
2 | 01.01.2018-31.03.2019 | | Januar | | 5 | |
3 | | | Februar | | | |
4 | | | April | | | |
5 | | | | | | |
6 | | | | | | |
7 | | | | | | |
8 | | | | | | |
9 | 01.01.2018 | | | | 1 | 5 |
10 | 31.03.2019 | | | | 2 | 4 |
11 | | | | | 4 | |
Zelle | Format | Wert |
A9 | TT.MM.JJJJ | 01.01.2018 |
A10 | TT.MM.JJJJ | 31.03.2019 |
Zelle | Formel |
F9 | =SUMMENPRODUKT(ZÄHLENWENN(E9:E20;(MONAT((EDATUM(A9;ZEILE(A1:A1001)-1))/(EDATUM(A9;ZEILE(A1:A1001)-1)<=MONATSENDE(A10;0)))))) |
F10 | =(JAHR(A10)-JAHR(A9)-1)*2+((1&-JAHR(A9))-A9>=0)+((2&-JAHR(A9))-A9>=0)+((3&-JAHR(A10))-2<A10)+((2&-JAHR(A10))-2<A10) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
- Ich bemühe zuerst mal WF, der immer sagt: Ich antworte nur auf die Frage.
- Jetzt lasse ich das wieder sein, und gehe auf Deinen berechtigten Einwand ein: Je komplexer die Regel, desto besser tatsächlich das Breitband-Antibiotikum ZEILE().
- Jetzt prügle ich noch weiter auf mich ein: Meine Formel war ja sogar noch etwas begünstigt dadurch, dass es sich nicht nur um Monate nebeneinander, sondern auch noch deren ersten beide handelt.