feiertageabfrage

[schluckspecht]

hallo zusammen,
wie bekomme ich Excel dazu,das die Feiertage in der Zusatzspalte für den
jeweiligen Monat abzufragen.
Soll heißen,in A9 soll nach der Abfrage entweder der 1.Feiertag für Monat X eingetragen werden.
Ansonsten der 1. So. im Monat X.Momentan hab ich nur die So.Auflistung in A9-A16.

danke für die Hilfe

[Ego]

Hallo s...,

zB so:

für A9:
=MIN(DATUM(H1;G1;0)+8-WOCHENTAG(DATUM(H1;G1;0));AGGREGAT(15;6;feiertage/(feiertage>DATUM(H1;G1;0));1))

ab A10:
=WENN(A9="";"";WENN(MIN(A9+8-WOCHENTAG(A9);AGGREGAT(15;6;feiertage/(feiertage>A9);1))>DATUM($H$1;$G$1+1;0);"";MIN(A9+8-WOCHENTAG(A9);AGGREGAT(15;6;feiertage/(feiertage>A9);1))))



Achtung! Dabei must du die Feiertagstabelle um einen Tag des Folgejahres erweitern.

[shift-del]

Moin

Mit ein paar Hilfszellen.

[schluckspecht]

@ego & shift-del
Jungs,ihr seit klasse. Danke nochmals.
Ego,warum muss der Jahreswechsel mit in der Spalte?

[Ego]

Hallo s...,

Das ist nur für Ende Dezember notwendig. Nach dem letzten Feiertag im Jahr würde die Aggregat-Funktion mit den aktuellen Parametern und damit auch die Min-Funktion einen Fehler ausweisen.
Ich halte einen zusätzlichen Eintrag in der Feiertagsliste, der wie jeder Monatswechsel über die innere Wenn-Funktion abgefangen wird, für einfacher als das Abfangen des Fehlerwertes in der Formel.

ps. Man könnte zB auch um beide Aggregat-Funktionen ein "WENNFEHLER( ... ; 9^9)" einbauen.

[newcomer]

und noch eine Lösung ohne Hilfsspalten:

A9 nach unten ausfüllen

=WENN(ARBEITSTAG.INTL(DATUM($H$1;$G$1;1);ZEILEN(A$9:A9);"1111110";feiertage)>MONATSENDE(DATUM($H$1;$G$1;1);0);"";ARBEITSTAG.INTL(DATUM($H$1;$G$1;1);ZEILEN(A$9:A9);"1111110";feiertage))


:21: 

Viele Grüße



Christian