Zwei Spalten mit Daten miteinander vergleichen

[Kaessi]

Hallo liebe Excel-Profis,

ähnliche Fragestellungen habe ich zwar schon gefunden, allerdings nie ganz passend zu meinem Problem.
Ich schildere euch mal mein geplantes Vorhaben:

Ich habe eine Tabelle in der beispielsweise die Zusammensetzung von zwei verschiedenen Proben verglichen wird.
Als Beispiel:

                  Probe 1         Probe 2
Möhren      0,00469         2,4369
Äpfel                     0         1,5649
Gurken       0,46591                 0
Sesam                  0                  0
Zwiebeln     1,65963        0,0043
Ananas                 0         0,9865

Dann möchte ich ausrechnen, welche Inhaltsstoffe in beiden, welche in nur einer und welche in der anderen Probe vorliegen. Also würde rauskommen:
Inhaltsstoffe in beiden: 2
Inhaltsstoffe nur in Probe 1: 3
Inhaltsstoffe nur in Probe 2: 4

Im weiteren Projekt könnte es dann sein, dass ich irgendwann mehr als zwei Proben miteinander vergleichen möchte, das wird dann wahrscheinlich deutlich komplizierter oder?

In der Hoffnung, dass ihr mir weiterhelfen könnt :)
Vielen Dank schonmal,
Kaessi

[steve1da]

Hol,

schau dir mal Zählenwenn() und Zählenwenns() an.

Gruß,
steve1da

[BoskoBiati]

Hi,

ich glaube Deiner Musterlösung nicht:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F
1		Probe 1	Probe 2
2	Möhren	0,00469	2,4369	Inhaltsstoffe nur in 1:	1	1
3	Äpfel	0	1,5649	Inhaltsstoffe nur in 2:	2	2
4	Gurken	0,46591	0	Inhaltsstoffe in beiden:	2	2
5	Sesam	0	0	Inhaltsstoffe in keiner:	1	1
6	Zwiebeln	1,65963	0,0043
7	Ananas	0	0,9865

Zelle	Formel
E2	=SUMMENPRODUKT(($C$2:$C$7=0)*($B$2:$B$7>0))
F2	=ZÄHLENWENNS($C$2:$C$7;0;$B$2:$B$7;">0")
E3	=SUMMENPRODUKT(($B$2:$B$7=0)*($C$2:$C$7>0))
F3	=ZÄHLENWENNS($C$2:$C$7;">0";$B$2:$B$7;0)
E4	=SUMMENPRODUKT(($B$2:$B$7>0)*($C$2:$C$7>0))
F4	=ZÄHLENWENNS($C$2:$C$7;">0";$B$2:$B$7;">0")
E5	=SUMMENPRODUKT(($B$2:$B$7=0)*($C$2:$C$7=0))
F5	=ZÄHLENWENNS($C$2:$C$7;"0";$B$2:$B$7;0)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Im weiteren Projekt könnte es dann sein, dass ich irgendwann mehr als zwei Proben miteinander vergleichen möchte, das wird dann wahrscheinlich deutlich komplizierter oder

länger, nicht komplizierter.