Wenn dann sonst Rechnungen

[Babysun]

Hallo Zusammen

Seit Stunden zermartere ich mir das Hirn wie ich eine Auflistung in Excel 2016 sauber hinkriege. 
Ich bin kurz davor, meinen PC zum Fenster raus zu werfen, jedoch kann er für mich Nichtwissen nix dafür. 
Vielleicht kann mir hier jemand weiterhelfen. 

Folgendes:

Um meine Finanzen und meine Spontankäufe etwas besser in den Griff zubekommen möchte ich mir ein Haushaltsbuch
nach meinen Wünschen zusammen stellen. 

Ich habe mal ein File zusammen gestellt wie es etwa aussehen könnte. (Siehe Anhang)

Mein Ziel ist es, dass wenn 

F5=Konto 1 ist, den Betrag aus E5 (hier 100)nimmt und diesen Betrag dann vom aktuellen Betrag G, (in diesem Fall G3=5000) abzieht.
Wenn jedoch F5=Konto 2 ist, sollte es E5 von H3 (hier 2000) subtrahieren.   

Ist das überhaupt so möglich?

Danke für eure Hilfe.

Liebe Grüsse
Sandra

[WillWissen]

Hi Sandra,

hast du es so gemeint?

Tabelle5

	A	B	C	D
1	Ausgabe	von Kto	Konto1	Konto2
2		Bestand	5000	2000
3	100	Konto 1	4900	1900
4	200	Konto 2	4900	1900
5	50	Konto 1	4850	1850

Formeln der Tabelle

Zelle Formel C3 =WENN($B3=1;C2-$A3;C2) D3 =WENN($B3=1;D2-$A3;D2)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Spalte B (ab B3) ist benutzerdefiniert formatiert:

Code:

"Konto "0

[Babysun]

Hallo Günter

Besten Dank für deine Antwort.

Ich werde das übers Wochenende austesten und werde ich wieder hier melden.

Aber es sieht schon mal sehr gut aus

Herzlichen Dank für deine Hilfe!

Liebe Grüsse
Sandra

[Babysun]

Hi Günter

Also deine Formel hab ich getestet und musste sie ein bisschen anpassen, da es einen kleinen Fehler drin hatte.

Die Formel funktioniert super. Danke.

Wie ist das, wenn ich nun die Einnahmen auch noch einbauen möchte?
Ich habe versucht die im gleichen Stil mit der Formel einzubauen, aber da wird mir dann mitgeteilt, dass die Formel zu lang ist.

Kann man nicht mehrere Wenn-Formeln einbauen?

Habe kurz was über den sverweis gelesen, würde das hier besser passen?

LG und einen schönen Sonntag
Sandra

[coemm]

Hallo Sandra,

meinst du so?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Einnahmen	Ausgaben		Konto1	Konto 2
2				5000	2000
3		100	Konto 1	4900	2000
4		200	Konto 2	4900	1800
5		50	Konto 1	4850	1800
6		500	Konto 1	4350	1800
7	1000		Konto 1	5350	1800
8	500		Konto 2	5350	2300

Zelle	Formel
D3	=WENN(UND($C3="Konto 1";$A3<>"");D2+$A3;WENN(UND($C3="Konto 1";$B3<>"");D2-$B3;D2))
E3	=WENN(UND($C3="Konto 2";$A3<>"");E2+$A3;WENN(UND($C3="Konto 2";$B3<>"");E2-$B3;E2))
D4	=WENN(UND($C4="Konto 1";$A4<>"");D3+$A4;WENN(UND($C4="Konto 1";$B4<>"");D3-$B4;D3))
E4	=WENN(UND($C4="Konto 2";$A4<>"");E3+$A4;WENN(UND($C4="Konto 2";$B4<>"");E3-$B4;E3))
D5	=WENN(UND($C5="Konto 1";$A5<>"");D4+$A5;WENN(UND($C5="Konto 1";$B5<>"");D4-$B5;D4))
E5	=WENN(UND($C5="Konto 2";$A5<>"");E4+$A5;WENN(UND($C5="Konto 2";$B5<>"");E4-$B5;E4))
D6	=WENN(UND($C6="Konto 1";$A6<>"");D5+$A6;WENN(UND($C6="Konto 1";$B6<>"");D5-$B6;D5))
E6	=WENN(UND($C6="Konto 2";$A6<>"");E5+$A6;WENN(UND($C6="Konto 2";$B6<>"");E5-$B6;E5))
D7	=WENN(UND($C7="Konto 1";$A7<>"");D6+$A7;WENN(UND($C7="Konto 1";$B7<>"");D6-$B7;D6))
E7	=WENN(UND($C7="Konto 2";$A7<>"");E6+$A7;WENN(UND($C7="Konto 2";$B7<>"");E6-$B7;E6))
D8	=WENN(UND($C8="Konto 1";$A8<>"");D7+$A8;WENN(UND($C8="Konto 1";$B8<>"");D7-$B8;D7))
E8	=WENN(UND($C8="Konto 2";$A8<>"");E7+$A8;WENN(UND($C8="Konto 2";$B8<>"");E7-$B8;E7))

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

PS: Lade bitte keine Bilder hoch, denn dann muss man deine Datei erst nachbauen. Besser ist eine Beispieldatei hoch zu laden. Dann kann man darin direkt arbeiten.
Wie man eine Datei hoch lädt, kannst du hier nachlesen.

[Gast 123]

Hallo

ich habe mir die Sache auch mal angesehen und eine eigene Lösung entwickelt.  s. Beispieldatei
Ich benutze allerdings keine Formeln, sondern ein Vba Makro zum auflisten der Konten.  Bitte mal anschauen.

Für die Interessenten die keine xlsm Dateien laden gibt es eine xlsx mit Makros in der Tabelle, die man in ein normales Modul kopieen muss.

mfg  Gast 123

[Gast 123]

Datein versehentlich nicht geladen - hier sind sie:

[Jockel]

Hallo Sandra,

meinst du so?

...

Hallo Conny, Sandra hat aber andere Ergebnisse heraus... Warum auch immer... Siehe ihr Bild Zeile 7, Konto 2 stimmt mE gar nicht... Aber ich bin ganz in deiner Nähe... Wenn, ja wenn du nicht auch schlampern würdest... Nomenklatur der Konten bzw. ihrer Vergleichbarkeit wegen... ... deine Formel (nach Bereinigung der "Fehler") ginge auch so..:

PHP-Code:

=WENN(UND($C3=D$1;$A3<>"");D2+$A3;WENN(UND($C3=D$1;$B3<>"");D2-$B3;D2)) 


Sandra wird sich sicher noch äußern zu gegebener Zeit...

Ich frage mich, ob es nicht möglich ist, in einer Zeile Ein- und Ausgaben haben zu dürfen. Ich würde so tun..:

Arbeitsblatt mit dem Namen 'Blatt1'
	A	B	C	D	E
1	Einnahmen	Ausgaben		Konto1	Konto2
2				5.000,00	2.000,00
3		100,00	Konto1	4.900,00	2.000,00
4		200,00	Konto2	4.900,00	1.800,00
5		50,00	Konto1	4.850,00	1.800,00
6		500,00	Konto1	4.350,00	1.800,00
7	1.000,00		Konto1	5.350,00	1.800,00
8	500,00		Konto2	5.350,00	2.300,00

Zelle	Formel
D3	=D2+SUMMEWENN($C3;D$1;$A3)-SUMMEWENN($C3;D$1;$B3)

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[Rabe]

Hi,

aus meiner Sicht sind zwei Spalten unnötig. Ich würde die Kontobewegungen alle in einer Spalte führen.

Es gibt doch normalerweise viel mehr Ausgaben als Einnahmen. Ist dann eine extra Spalte für die paar Einnahmen überhaupt nötig?
Ich würde es so machen:
Blatt1

	A	B	D	E	F	G
1	Haushaltsbudget
2	Datum	Bemerkungen	Konto-bewegung	bezahlt mit	Konto1	Konto2
3	01.09.2017	Eröffnung Monat			5000	2000
4	02.09.2017	Testausgabe 1	-100	Konto1	4900	2000
5	03.09.2017	Testausgabe 2	-200	Konto2	4900	1800
6	04.09.2017	Testausgabe 3	-50	Konto1	4850	1800
7	05.09.2017	Testausgabe 4	-500	Konto1	4350	1800
8	29.09.2017	Gehalt 1	1000	Konto1	5350	1800
9	30.09.2017	Gehalt 2	500	Konto2	5350	2300

verwendete Formeln
Zelle	Formel	Bereich	N/A
F4:G9	=F3+SUMMEWENN($E4;F$2;$D4)

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.08 einschl. 64 Bit

Dann noch formatiert als intelligente Tabelle (STRG-L) im Bereich A2 bis G9 dann muß keine Formel mehr manuell fortgeschrieben werden.