Tagesliste mit lückenhaften Daten füllen

[Robi]

Liebe Excel-Spezialisten,

ich habe folgendes Problem:
Eine Tagesliste, in welche die Anwesenheit einer oderer mehrerer Personen am betreffenden Tag eingetragen werden soll.
Die Tage im Beispiel (Spalte F) seien von 1-20 nummeriert.
Die Anwesenheit einer Person liegt als Liste mit Tagesintervallen vor. Im Beispiel ist Person1 (Spalten A und B) von Tag 3 bis Tag 5 anwesend. Dann am Tag 9 und schliesslich von Tag 15 bis Tag 18.
Gesucht ist eine Formel, welche an den Tagen, an denen Person1 anwesend ist, einen Eintrag (z.B. den Wert 1) in der gelben Spalte G macht.
(Das Analoge würde dann mit Person2... geschehen.)

Besten Dank,
Robi

[shift-del]

Hallo Robi

Code:

=SUMMENPRODUKT(ZÄHLENWENNS(F3;">="&$A$3:$A$8;F3;"<="&$B$3:$B$8))

[BoskoBiati]

Hallo,

da reicht doch das SUMMENPRODUKT:

Arbeitsblatt mit dem Namen 'Sheet1'
	A	B	C	D	E	F	G	H	I
1	Person1		Person2			Tag	Person1	Person2	Personen
2	von Tag	bis Tag	von Tag	bis Tag
3	3	5	1	3		1		1	1
4	9	9	5	6		2		1	1
5	15	18	8	8		3	1	1	2
6			12	13		4	1		1
7			15	15		5	1	1	2
8			18	20		6		1	1

Zelle	Formel
G3	=SUMMENPRODUKT(($A$3:$A$8<=F3)*($B$3:$B$8>=F3))
H3	=SUMMENPRODUKT(($C$3:$C$8<=F3)*($D$3:$D$8>=F3))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Rabe]

Hi,

ich würde die Datenliste umstellen und es mit intelligenten Tabellen so lösen, dann verlängern sich die Formeln automatisch und es ist nur eine Formel nötig:

Sheet1

	A	B	C	D	E	F	G	H	I
1	Person1		Person2
2	von Tag	bis Tag	von Tag	bis Tag		Tag	Person1	Person2	Personen
3	3	5	1	3		1	0	1	1
4	9	9	5	6		2	0	1	1
5	15	18	8	8		3	1	1	2
6			12	13		4	1	0	1
7			15	15		5	1	1	2
8			18	20		6	0	1	1
9						7	0	0	0
10	Person	von Tag	bis Tag			8	0	1	1
11	Person2	1	3			9	1	0	1
12	Person1	3	5			10	0	0	0
13	Person2	5	6			11	0	0	0
14	Person2	8	8			12	0	1	1
15	Person1	9	9			13	0	1	1
16	Person2	12	13			14	0	0	0
17	Person1	15	18			15	1	1	2
18	Person2	15	15			16	1	0	1
19	Person2	18	20			17	1	0	1
20						18	1	1	2
21						19	0	1	1
22						20	0	1	1

verbundene Zellen

A1:B1

C1: D1

verwendete Formeln
Zelle	Formel	Bereich	N/A
G3:H22	=SUMMENPRODUKT((Tabelle1[von Tag]<=$F3)*(Tabelle1[bis Tag]>=$F3)*(Tabelle1[Person]=G$2))
I3:I22	=SUMME(G3:H3)

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.08 einschl. 64 Bit

  Anwesenheitsübersicht.xlsb (Größe: 12,59 KB / Downloads: 1)

[shift-del]

da reicht doch das SUMMENPRODUKT:

Ja, das ging mir heute morgen auch durch den Kopf. Hatte aber nicht mehr die Zeit und die Lust es um zu schreiben.