Spezielle Matrixsuche und Ausgabe und auslassen von leeren Zellen in ein anderes Tab

[BoskoBiati]

Hi,

damit das Ganze auch so aussieht wie im Original:


  Beispiel Heizkörper.xlsx (Größe: 15,78 KB / Downloads: 9)

[BoskoBiati]

Hi,

die Formel in der letzten Datei beruht auf einem Gedankenfehler meinerseits. Hier eine funktionierende Formel, passend zu der Datei:

Code:

=WENNFEHLER(
LET(ya;FILTER(Wohnungen!E3:.J25;(Wohnungen!A3:.A25=A3)*(Wohnungen!B3:.B25=B3)*(Wohnungen!C3:.C25=C3));
   yb;Wohnungen!E2:J2;xa;"Raumnutzung;;;";
   za;TEXTVERKETTEN(";";;INDEX(yb;;1);INDEX(ya;;1);INDEX(yb;;2);INDEX(ya;;2));
   zb;TEXTVERKETTEN(";";;INDEX(yb;;3);INDEX(ya;;3);INDEX(yb;;4);INDEX(ya;;4));
   zc;";;;";
   zd;TEXTVERKETTEN(";";;INDEX(yb;;5);INDEX(ya;;5);INDEX(yb;;6);INDEX(ya;;6));
   ze;"Heizkörperverteilung;;;";
   zf;TEXTVERKETTEN("#";;xa;za;zb;zc;zd;zc;ze);
xb;FILTER(Wohnungen!D2:.J25;(Wohnungen!B2:.B25=B3)*(Wohnungen!C2:.C25=C3)*(Wohnungen!A2:.A25=A3));
xc;Übersicht!F4:K4;
xd;FILTER(Übersicht!F5:.K25;(Übersicht!C5:.C25=B3)*(Übersicht!D5:.D25=C3)*(Übersicht!E5:.E25=A3));
VSTAPELN(TEXTTEILEN(zf;";";"#");
HSTAPELN(MTRANS(xc);MTRANS(xd);WECHSELN(MATRIXERSTELLEN(6;2;LAMBDA(a;b;a*b=0))*1;0;""))));
"Kombi nicht vorhanden!")

[EA1950]

Hallo,

oder auch folgende LET-Formel (in der Zelle, in der das Wort "Raumnutzung" steht):

Code:

=LET(
    whgf; VSTAPELN(
        Wohnungen!$E$2:$J$2;
        FILTER(
            Wohnungen!$E$3:.$J$25;
            (Wohnungen!$A$3:.$A$25 = A3) * (Wohnungen!$B$3:.$B$25 = B3) * (Wohnungen!$C$3:.$C$25 = C3)
        )
    );
    whg; ZEILENUMBRUCH(ZUZEILE(whgf; 2; WAHR); 4; "");
    übs; VSTAPELN(
        Übersicht!$F$4:$K$4;
        FILTER(
            Übersicht!$F$5:.$K$27;
            (Übersicht!$C$5:.$C$27 = B3) * (Übersicht!$D$5:.$D$27 = C3) * (Übersicht!$E$5:.$E$27 = A3)
        )
    );
    WENNFEHLER(
        VSTAPELN(
            ERWEITERN("Raumnutzung"; ; 4; "");
            ÜBERNEHMEN(whg; 2);
            {"". "". "". ""};
            ÜBERNEHMEN(whg; -1);
            TEXTTEILEN(";;;|Heizkörperauflistung;;;"; ";"; "|");
            HSTAPELN(MTRANS(übs); ERWEITERN(""; SPALTEN(übs); 2; ""))
        );
        "Raumschlüssel nicht vorhanden!"
    )
)