Sequenz spillen

[slowboarder]

danke.
aber die Idee hat ja Andre auch schon gehabt.

[BoskoBiati]

Hallo zusammen,

vielen Dank für die vielen Beiträge und die tollen Formeln. Ich habe mich für die Formel von Daniel entschieden, die ist am kürzesten und bringt die gleichen Ergebnisse wie alle anderen. Alle Formeln sind aber in meiner Sammlung gelandet.
Allerdings ist die Formel von Uwe etwas schwieriger anzupassen, da sie abhängig von der Lage der Datumswerte im Blatt ist. Wenn die Werte z.B. in C8:I9 liegen, muß xLs angepasst werden, damit es keinen Fehler gibt.

Im Anhang noch eine Datei, in der alle Formeln nochmal zusammengestellt sind, auch abgewandelt für Tabellen, bei denen die Zeiträume horizontal angeordnet sind. In Tabelle2 die Formeln von Uwe mit veränderte Lage der Datumswerte.


  Sequenz spillen.xlsx (Größe: 12,76 KB / Downloads: 6)

[Egon12]

Hallo Edgar,

mir hat die sperrige Anpassbarkeit keine Ruhe gelassen.

Nun verbessert so:

Code:

=LET(
  xZ; FILTER(1:2;1:1<>"");
  xLs;MAX(SPALTEN(xZ));
  xSp; SEQUENZ(xLs;1;1);
  xInit; 0;
  xVst; REDUCE(
    xInit;
    xSp;
    LAMBDA(pS;pL;
      LET(
        xS; INDEX(xZ;1;pL);
        xE; INDEX(xZ;2;pL);
        xBer; WENN(UND(ISTZAHL(xS); ISTZAHL(xE); xE >= xS); SEQUENZ(xE - xS + 1; ; xS; 1); SEQUENZ(0;1) );
        SORTIEREN(VSTAPELN(pS; xBer);;1)
      )
    )
  );
  FILTER(xVst; ISTZAHL(xVst)*(xVst<>0))
)

Somit muss man nun nicht mehr mit Spalte A beginnen.
ggf. könnte diese Anpassung noch nötig sein:  xZ; FILTER(1:2;(1:1<>"")*(2:2<>""));

Gruß Uwe

[BoskoBiati]

Hi Uwe,

soweit ganz gut, einziges (kleines) Problem ist nur, dass die Formel nicht in in der gleichen Zeile wie die Datumswerte stehen darf.

Das Ganze war im Zusammenhang mit diesem Thread:

https://www.clever-excel-forum.de/Thread...-Feiertage

Allerdings hat sich das erledigt, da die Formel für die bedF gedacht war und diese eine Liste, welche mit einer dieser Formeln erstellt wurde, nicht akzeptiert.

[Egon12]

Hallo Edgar,

Ich habe gerade nur das Tablett zu Hand. Ohne es momentan überprüfen zu können: Um die Ausgabe in Höhe der beiden Datenzeilen ausgeben zu lassen kann man statt Filter einen Range vorgeben. Damit geht aber das automatische Erkennen der letzten belegten Spalte des Datumsberreichs verloren.

Gruß Uwe

[slowboarder]

man sollte noch erwähnen, dass die Formeln, die auf "Gesamtsequenz erstellen und unerwünschte ausfiltern" nur dann anwendbar sind, wenn sich die einzelnen Blöcke nicht überschneiden, es also im Ergebnis keine mehrfach vorkommenden Werte gibt.
Außerdem muss für die gezeigte Formel die Ausgangliste aufsteigend sortiert sein. Dies könnte man aber auch innerhalb der Formel durch weitere Funktionen sicherstellen.

Gruß Daniel

[schauan]

@ Daniel,

das ist auf jeden Fall für eine Beschreibung der Lösung wichtig.
Im konkreten Fall geht es z.B. um die Ferien eines Bundeslandes oder die Urlaube eines einzelnen Mitarbeiters. Diese "Listen" werden unterschiedlich betrachtet und innerhalb einer "Liste" gibt es da zumindest keine Überschneidungen. Man muss halt für die flexiblen Lösungen nur schauen, dass man die Daten sortiert angibt. Wenn man beim Urlaub am Jahresende feststellt, dass noch ein paar Tage übrig sind, sollte man die nicht nur drunter schreiben, sondern anschließend auch sortieren

bei den "starren" Ansätzen, z.B. mein
=--TEXTTEILEN((TEXTVERKETTEN(";";;SEQUENZ(2;;A1;1);SEQUENZ(B2-B1+1;;B1;1);SEQUENZ(C2-C1+1;;C1;1)));;";")
ist das egal, weil jeder Datumsbereich getrennt bzw. einzeln betrachtet wird.

[slowboarder]

wie gesagt, das Sortieren kann man in der Formel erledigen:
=LET(a;A1:C2;b;SEQUENZ(MAX(a)-MIN(a)+1;;MIN(a));FILTER(b;WVERWEIS(b;SORTIEREN(a;1;1;1);2;1)>=b))

oder man verwendet eine Methode, die auch mit unsortierten Daten zurecht kommt:
=LET(a;A1:C2;b;SEQUENZ(MAX(a)-MIN(a)+1;;MIN(a));FILTER(b;ZÄHLENWENNS(INDEX(a;1;0);"<="&b;INDEX(a;2;0);">="&b)))

[Elex]

Hallo,

würde auch über die Textvariante rangehen. Sortierung und Überschneidung egal.

Code:

=WEGLASSEN(TEXTTEILEN(TEXTKETTE(NACHSPALTE(A1:C2;LAMBDA(a;TEXTKETTE("#"&SEQUENZ(MAX(a)-MIN(a)+1;;MIN(a))))));;"#")*1;1)

[Sigi.21]

Hallo Daniel (slowboarder),

das ist wirklich eine perfekte Formel. Ich staune immer wieder, was die Profis hier alles zaubern können.

Aber: Jetzt solltest du auch den letzten Schritt noch vollziehen, und das Ganze in eine Lambda()-Funktion mit Namen (im Namensmanager) verpacken.
Dann kann der Anwender/User den Datenbereich fast beliebig mit der Maus angeben, und muss den Range nicht mehr im Code ändern.


Gruß Sigi