Drehfelder kopieren

[Jappy]

Hallo liebe Forumsgemeinde,

ich hoffe ihr könnt mir helfen.
Ich habe eine Tabelle für die Getränkeabrechnung der einzelnen Teilnehmer erstellt.
Nur stellte ich fest, das es nicht möglich ist die Drehfelder zu kopieren.

Ich hätte gerne wie in Zeile 2 auch fortführend die Drehfelder zur Tochterzelle.

Ist es auch möglich einen "Bezahlt" Button für jede Zeile in Spalte AA einzufügen. Seine funktion soll alle Buchungen in der Zeile wieder auf Null setzen.

Danke euch

Anbei die schon soweit ich konnte erstellte Tabelle.

[Egon12]

Hallo Jappy,

kleine Fleißaufgabe: Mit gehaltener Strg. Taste klickst du die in Zeile 2 enthaltenen Drehfelder an. Mit gehaltener Shift Taste kopierst du dann so oft du es benötigst die Drehfelder. Dann lädst du die Datei dir hoch. die kleine Prozedur um die Zellverknüpfung für alle zu erzeugen bau ich dir dann ein.
Was die Summe anlangt. Da braucht es natürlich eine Preisliste, oder kostet jedes Teil beispielhaft 1€?

Gruß Uwe

[Jappy]

Hallo Uwe, danke für deine Unterstützung.

Ich habe jetzt alle Drehfelder kopiert. Aber dadurch haben alle jetzt noch ihren Bezug zu der Spalte in zeile 2.

Die Preise habe ich in der Summenformel in der Summenspalte hinterlegt. Wird alles addiert und entsprechend multipliziert.

Hier dann die überarbeitete Datei.

[Klaus-Dieter]

Hallo Jappy,

das kann doch nicht den Ernst sein! Habe, was den Aufbau von Listen betrifft, schon viel gesehen, aber das ist nur krank, wer soll den so etwas bedienen? Abgesehen davon: was ist wenn sich da einer (oder mehrere) falsche Klicks ausgelöst werden? Es gibt keine Kontrollmöglichkeit. Eine Kreuztabelle zum Erfassen von Daten ist auch nicht so optimal, was die spätere Auswertung betrifft.

[Jappy]

Hallo Klaus-Dieter,

danke für deine wertschätzende und gesunde Antwort.

Dann hilf mir doch wie es übersichtlicher & sicherer gestaltet werden kann.

Ist doch der Sinn solcher Foren oder?

[Klaus-Dieter]

Hallo Jappy,

bin schon dabei, meckern kann ich besser, als zaubern. 

[slowboarder]

willst du wirklich diese vielen Buttons haben?

wenn es Buttons sein sollen, dann vielleicht so mit VBA- Unterstützung:

1. schreibe diesen Code in ein allgemeines Modul

Code:

Sub UpAndDown()
Dim s As Shape
Dim cT As Range
Set s = ActiveSheet.Shapes(Application.Caller)
Set cT = s.TopLeftCell

If s.Top < (cT.Top + 5) Then
    cT.Offset(0, -1).Value = cT.Offset(0, -1).Value + 1
ElseIf s.Top > (cT.Top + cT.Height / 2 - 5) Then
    cT.Offset(0, -1).Value = WorksheetFunction.Max(0, cT.Offset(0, -1).Value - 1)
Else
End If
End Sub

2. erstelle zwei normale Buttons und weise ihnen dieses Makro zu
einen der Buttons platzierst du in der oberen Hälfte der Zelle, den anderen in der unteren Hälfte der Zelle, achte aber darauf dass die linke obere Ecke der Buttons noch innerhalb  rechten Nachbarzelle derjenigen Zelle liegt, die gesteuert werden soll.

diese Buttons kannst du dann per Copy-Paste in die restlichen Zellen übernehmen.

der Code prüft in welcher Zelle sich der Button, der ihn aufruft, befindet.
die linke Nachbarzelle wird dann bearbeitet.
befindet sich die linke obere Ecke des Buttons knapp unterhalb des oberen Rahmens der Zelle, dann wird hochgezählt
befindet sich die linke obere Ecke des Buttons unterhalb der Mitte der Zelle, dann wird reduziert (bis maximal 0)
somit kannst du für jeden Button denselben Code verwenden.


wenn die Kasse mit einer Maus arbeitet, würde ich ganz auf die Buttons verzichten und das ganze über Doppelklick zum hochzählen und rechter Mausklick zum runterzählen programmieren
dazu müsste dann dieser Code ins Modul des Tabellenblatts:

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row > 1 And Target.Column > 1 And Not Target.Formula Like "=*" Then
    Target = Target + 1
    Cancel = True
End If
End Sub

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row > 1 And Target.Column > 1 And Not Target.Formula Like "=*" Then
    If Target.Value <> "" And Target.Value <> 0 Then Target.Value = Target.Value - 1
    Cancel = True
End If
End Sub

Gruß Daniel

[HKindler]

Hi,

ich habe ähnliches bei uns auch schon getestet. Am Schluss sind wir dann zur guten alten Strichliste zurückgekehrt. Die funktioniert auch in dieser Situation am besten.

[Egon12]

Hallo,
 
mit einer kleinen Prozedur kann man ganz einfach in einem Rutsch die Drehfelder erzeugen. Entferne aus deiner Tabelle alle Drehfelder.
Markiere den Tabellenbereich nebst Überschriften und drücke Strg./T. 

Dann drücke Alt/F11 um das VBA Editor Fenster zu öffnen. Gehe in den VBA Editor und erzeuge ein allgemeines Modul.
Ins allgemeine Modul:

Code:

Option Explicit

Sub DrehfelderErzeugen()
    Dim Spn As Object, i&, j&, k&, adrZ$
    With Tabelle1.ListObjects(1).DataBodyRange
        For i = 1 To .Rows.Count
            For j = 3 To .Columns.Count Step 2
                Set Spn = Tabelle1.Spinners.Add(.Cells(i, j).Left, .Cells(i, j).Top, .Cells(i, j).Width, .Cells(i, j).RowHeight - 0.2)
                k = k + 1
                adrZ = .Cells(i, j).Offset(, -1).Address
                With Spn
                    .Name = "Drehfeld" & k
                    .LinkedCell = adrZ
                End With
            Next j
        Next i
    End With
End Sub

Starte diese Prozedur mit F5 und alles steht fertig und einsatzbereit in deiner Tabelle drin.

Falls dich die formatierte Tabelle stört kannst du diese am Ende in Bereich konvertieren. Dazu klickst du im Menü im Ribbonband auf Tabellenentwurf und da Button "in Bereich konvertieren". Damit ist die Tabelle fertig und einsatzbereit.
Die kannst du dann wieder als .xlsx speichern, da dazu kein VBA mehr erforderlich ist.

  Getränke JHV Verein.xlsm (Größe: 245,25 KB / Downloads: 1)
 
Gruß Uwe

[Klaus-Dieter]

Hallo Jappy,

anbei ein Vorschlag, wie man das lösen könnte, wenn man nicht wirklich mit der alten Strichliste arbeiten will.