Datenreihe automatsich fortsetzen

[marvio842]

Hallo, bei mir (Excel365) funktioniert das automatische fortlaufende ausfüllen nicht mehr. Wenn ich also 01.10.22 , 02.10.22, 03.10.22....dann mit der Maus rechts Klick, mit dem kleinen Schwarzen Plus nach unten Ziehe wiederholen sich nur die bereits angeklickten im selben Schema, aber ich will ja das Excel mit das Datum fortlaufen für den Rest des Monats ausfüllt.

Habe bereits in der Formatierung die Zellen Datum auf Kurz. Auch geprüft aus Deutschland eingestellt (arbeite & wohne in Spanien)
Danke vorab falls mir jemand bitte einen Tipp geben kann was ich falsch mache

[Gastlich]

Hallo,


mit ISTZAHL() kann geprüft werden, ob es tatsächlich ein Datum ist, oder Text.

Die Zahlen sind anscheinend linksbündig angeordnet, und damit Text.

[marvio842]

Vielen Dank für den Hinweis, werde ich gleich prüfen

[RPP63]

Moin!
Abseits dessen:
Den Januar (als Beispiel) erschlägt man in einem modernen Excel mit einer einzigen Formelzelle so:
=DATUM(2022;1;SEQUENZ(31))

Gruß Ralf

[RPP63]

Nur ergänzend zwei bzw. drei Formeln, die die Möglichkeiten von Excel 2021/365/Online verdeutlichen.
Sie berücksichtigen, ob ein Schaltjahr vorliegt.
Das auszuwertende Jahr steht in A1

• Gesamtjahr in einer Spalte:
=LET(j;A1;
 NJ_akt;DATUM(j;1;1);
 NJ_2;DATUM(j+1;1;1);
 SEQUENZ(NJ_2-NJ_akt;;NJ_akt))

• ohne LET():
=DATUM(A1;1;SEQUENZ(365+(MONAT(DATUM(A1;2;29)=2))))

• Gesamtjahr in 12 Monatsspalten:
=MATRIXERSTELLEN(31;12;LAMBDA(t;m;LET(j;DATUM(A1;m;t);WENN(MONAT(j)>m;"";j))))
(MATRIXERSTELLEN() nicht in Excel 2021)

Gruß Ralf

[LCohen]

Und hier noch das Gesamtjahr (in A1 stehend als 2022) in 12 Monatsspalten, aber 37 statt 31 Zeilen (damit gleiche Wochentage nebeneinander stehen, braucht man 6 Zeilen mehr):

B2#: =MATRIXERSTELLEN(37;12;LAMBDA(t;m;LET(j;DATUM(A1;m;t)-REST(DATUM(A1;m;1);7);WENN((MONAT(j)<>m);"";j))))

Oder gleich mit Jahr, Vorspalte und Kopfzeile (4 Bereiche), ohne separate Eingabe in A1:

A1#: =LET(a;2022;
VSTAPELN(
HSTAPELN(""&a;
TEXT(SEQUENZ(;12;30;30);"MMMM"));
HSTAPELN(TEXT(SEQUENZ(37;;0);"TTT");
TEXT(MATRIXERSTELLEN(37;12;LAMBDA(t;m;LET(j;DATUM(a;m;t)-REST(DATUM(a;m;1);7);WENN((MONAT(j)<>m);"";j))));"TT"))))

[RPP63]

Sehr schön! 

[LCohen]

Deins aber auch. Endlich kann ich aufgrund Deines MATRIXERSTELLEN office-hilfe.com/support/threads/kalender-mit-nur-einer-formel.22779/ auch dynamisch zeigen (muss ich dort noch hinpacken).

A1#: =LET(a;2022;VSTAPELN(HSTAPELN(""&a;TEXT(SEQUENZ(;25;30;30);"MMMM"));HSTAPELN(TEXT(SEQUENZ(37;;0);"TTT");TEXT(MATRIXERSTELLEN(37;25;LAMBDA(t;m;LET(j;DATUM(a;m;t)-REST(DATUM(a;m;1);7);WENN((MONAT(j)<>REST(m-1;12)+1);"";j))));"TT"))))

stellt 25 Monate nebeneinander. Warum? Über Spaltenausblenden kann ich z.B. Juli 2022 bis August 2023 (14 Monate) ausdrucken (Schuljahr inkl. Teilen beider Sommerferien). Oder ich nehme Dezember 2022 bis Januar 2024 (14 Monate), damit man die direkt benachbarten Monate des Jahres sieht, um dort schnell wichtige Erinnerungen hinzuschreiben.

Das Spaltenausblenden könnte man sich natürlich noch über =KALENDER(2022;7;14) (o.g. 1. Bsp.) statt =KALENDER(2022) sparen, wenn man entsprechend LETtet und shiftet.

[BoskoBiati]

Hi,

genial. Ich verstehe zwar nichts mehr, aber das sind mal tolle Möglichkeiten.
Leider ist das m.E. für den Alltagsanwender nicht mehr nachvollziehbar.

[LCohen]

Also ich finde es einfacher als PQ. Ansonsten ähneln sich dynamische Formeln und PQ. Und Dir, Bosko, traue ich zu, dass Du mit dynamischen Formeln auch noch mal richtig Spaß haben kannst.

Du hast recht, dass das verwirrend aussieht. Aber die Formeln werden auch von innen nach außen aufgelöst. Hinzu kommt, dass an Hilfszellen Statt nun vorherige Formelzuweisungen getreten sind. Man kann also die langen Formeln auch verkürzen und in eigene Zeilen packen - was ein guter Programmierer sicherlich auch tun würde. 

Daher kann ein riesiger inhaltlicher Komplex in eine einzige Formel.

clever-excel-forum.de/Thread-LAMBDA-Das-Helferlein-Q-uadrant-und-eine-Anwendung-UNPIVOT oder
clever-excel-forum.de/Thread-LAMBDA-In-NACHZEILE-verwendete-Funktion-dynamisieren

könnte vielleicht etwas helfen.