Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Das Update ist abgeschlossen, Ihr könnt unser Forum jetzt wieder wie gewohnt nutzen. Eventuelle Bugs und Auffälligkeiten postet Ihr bitte im entsprechenden Forum im Bereich Forumstechnik. x


[LAMBDA] Das Helferlein Q (uadrant) und eine Anwendung UNPIVOT
#1
Mit 

Q: =LAMBDA(x;[qq];[yy];[zz];LET(
q;WENN(WURDEAUSGELASSEN(qq);4;qq);
y;WENN(WURDEAUSGELASSEN(yy);1;yy);
z;WENN(WURDEAUSGELASSEN(zz);1;zz);
a;ZEILEN(x);
b;SPALTEN(x);
WAHL(q;
INDEX(x;1;1):INDEX(x;y;z);
INDEX(x;1;1+z):INDEX(x;y;b);
INDEX(x;1+y;1):INDEX(x;a;z);
INDEX(x;1+y;1+z):INDEX(x;a;b))))


kann man Matrizen vierteln. Dabei werden Kopfzeile (2), Vorspalte (3) (standardmäßig gilt dafür 1 Zellenhöhe/breite, jedoch beliebig von 0-n einstellbar) und die Werte (4) isoliert.

Als Beispiel nehmen wir dafür einen kurzen Entpivotierungscode:

UNPIVOT: =LAMBDA(a;LET(b;Q(a;2);c;Q(a;3);d;Q(a);i;SPALTEN(b);j;i*ZEILEN(d);
VSTAPELN({"Zei"."Spa"."Wert"};HSTAPELN(INDEX(c;SEQUENZ(j;;1;1/i));INDEX(b;REST(SEQUENZ(j)-1;i)+1);ZUSPALTE(d)))))


____ Jens Eric Sven
rot_ ___2 ___3 ___0
rosé ___5 ___3 ___4


wird mit =UNPIVOT(A1:D3) zu

Zei_ Spa_ Wert
rot_ Jens ___2
rot_ Eric ___3
rot_ Sven ___0
rosé Jens ___5
rosé Eric ___3
rosé Sven ___4
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste