Barcode in Excelliste verarbeiten

[Penki2004]

Hallo,
 
ich arbeite in einer Feuerwehr die selbst Einsatzkleidung ausgibt, wäscht und lagert. Jetzt hätte ich die Idee das jedes Kleidungsstück einen Barcode aufgepatch bekommt wenn es gekauft wird und in einer Excelliste aufgenommen wird. Wenn dann das Kleidungsstück aus dem Lager ausgegeben wird oder später gewaschen wird dann wird der Barcode gescannt und es öffnet sich in der Liste die gewünschte Tabelle in der Mappe damit man eintragen kann was gemacht wird. Also entweder Ausgabe des Kleidungsstücks, Wäsche oder Reparatur.
Ist das mit Excel möglich ? Wie kann ich das am einfachsten lösen ?
 
Wir haben Excel 2016, Barcodescanner kann besorgt werden welcher auch benötigt wird.

[Mase]

https://www.ms-office-forum.net/forum/sh...p?t=362482

[UweD]

Hallo


das Abscannen eines Barcodes ist nichts anderes als die Eingabe von Text / Ziffern.

Die meisten Scanner werden wie eine Tastatur angesehen.

auf Excel bezogen:

Wenn du also eine Zelle selectiert hast und den Code scannst, wird der gelesenen Wert in der Zelle eingetragen und Enter angehangen. (So sind die meisten Scanner eingestellt)


Was du jetzt damit in Excel machen möchtest ist also unabhängig davon, ob du scannst oder Handeingabe wählst.


Um im gewünschten Ablauf nun weiterzuhelfen, müsstest du genauer beschreiben, wie deine Mappe / Tabellen aufgebaut sein sollen usw.


LG UweD

[Penki2004]

Ah ok, dankeschön.

Vorgestellt haben wir uns die Excel Liste so das jedes Kleidungsstück eine eigene Tabelle bekommt in der Mappe und man mit dem Barcode in dem Kleidungsstück direkt auf die Tabelle des Kleidungsstücks kommt und dort dann eintragen kann ob es gewaschen wurde, repariert oder an welche Person das Kleidungsstück ausgegeben wurde. Wenn möglich vielleicht auch mit einem Extra Barcode an der Waschmaschine das man auch gleich nur erst den Code des Kleidungsstückes scannt und dann den an der Waschmaschine und damit wird automatisch eingetragen das das gfescannte Kleidungsstück jetzt an dem Datum gewaschen wurde.

Kann man sowas mit Excel lösen ?

[Gast 123]

Hallo

zuerst müsst ihr euch bitte selbst mal Gedanken machen wie die Datei aussehen soll. Da gibt es unendliche Varianten.
Die Kollegen raten immer davon ab Daten auf viele Tabellen zu verteilen. Es sei denn sie sollen auch gedruckt werden.

Anbei mal eine Lösung Idee von mir über drei DropDown Zellen. Da kann man sogar auf einen Scanner verzichten.
Das Makro dazu ist noch nicht geschrieben, weil ich ja nicht weiss ob diese Idee bei euch ankommt???
Wenn nicht denkt euch bitte eigene Vorschlaege aus und stellt sie als Beispiel ins Forum. Sagt mehr als viele Worte.

mfg  Gast 123

[Penki2004]

Würden es schon gerne mit jedes Kleidungsstück eine Tabelle machen da es einmal im Jahr zur Inventur ausgedruckt werden muss. Hab jetzt mal auf die schnelle eine Mappe mit 3 Beispielen erstellt. Mit dem Scanner sollte beim einscannen dann gleich auf die richtige Tabelle gesprungen werden damit man dann Datum einträgt und was gerade gemacht wurde, also gewaschen, ausgegeben usw. Immer fortlaufend mit Datum . Das wichtigste ist das beim einscannen automatisch das richtige Kleidungsstück kommt, noch schöner wäre es wenn man wie schon erwähnt erst die Jacke einscannt und dann einen Barcode an der Waschmaschine und dann trägt es automatisch Datum und gewaschen ein aber das wird wahrscheinlich dann aufwendig oder ?

[UweD]

Hallo nochmal

Erstmal aus der Praxis ein paar Tipps.

 - Verwende den Code 128 für die Barcodes, der ist sehr kompakt und sehr gut scannbar
 - die Tabellenblätter sollten so heißen wie die Codes
   also z.B. EH1234 oder UEH1234
 - an der Waschmaschine kannst du dann Steuerbarcodes anbringen
    - GEWASCHEN
    - GENAEHT
    - ..
    - und auf jeden Fall Einen "B_Ende" (Befehl Ende)


Ebenfalls ein Blatt "Eingabe" anlegen
 - dort die Zelle A1 markieren
 - Zelle formatieren, Schutz,
 - bei "gesperrt" den Haken rausnehmen
 - alle Anderen Zellen bleiben gesperrt

 - Das ganze Blatt schützen,
 - dabei bei Option "GesperrteZellen auswählen" den Haken rausnehmen

>>> Jetzt kannst du nur noch diese Zelle auswählen


Zum Makro:

in den Codebereich von DieseArbeitsmappe

Code:

Option Explicit

Const strEnde = "B_Ende"


Private Sub Workbook_Open()
   Sheets("Eingabe").Activate
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
   If ActiveSheet.Name <> "Eingabe" Then
   
       Dim RNG As Range
       On Error GoTo Fehler
       Const APPNAME = "Worksheet_Change"
       
       Set RNG = Sh.Columns(2) 'Eingaben in Spalte B werden überwacht
       
       If Not Intersect(RNG, Target) Is Nothing Then
           If Target.Row > 3 Then
               If Target = strEnde Then
                   With Application
                       .EnableEvents = False
                       Target.ClearContents
                       .EnableEvents = True
                   End With
                       
                   'zurück
Sheets("Eingabe").Activate
                   
               End If
           End If
       End If
   End If
Fehler:
   Application.EnableEvents = True
   If Err.Number <> 0 Then MsgBox "Fehler in Sub """ & APPNAME & """" & vbCrLf _
       & "Fehlernummer: " & Err.Number & vbLf & Err.Description: Err.Clear
End Sub

in den Codebereich vom Blatt Eingabe:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
   
   Dim strCode As String, RNG As Range, LR As Long
   'On Error GoTo Fehler
   Const APPNAME = "Worksheet_Change"
   Set RNG = Range("A1")
   
   If Not Intersect(RNG, Target) Is Nothing Then
       If Target <> "" Then
       
           'prüfen ob Blatt schon existiert
           If IsError(Evaluate(Target & "!A1")) Then
               MsgBox "Barcode unbekannt"
               
           Else
               With Sheets(Target.Value)
                   .Activate
                   
                   'erste freie Zeile
                   LR = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
                   
                   'Datum eintragen
                   .Cells(LR, 1) = Format(Date, "DD.MM.YYYY")
                   
                   'Nachbarzelle auswählen
                   .Cells(LR, 2).Select
                   
               End With
           End If
                   
       End If
   End If
   
   
   Err.Clear
Fehler:
   If Err.Number <> 0 Then MsgBox "Fehler in Sub """ & APPNAME & """" & vbCrLf _
       & "Fehlernummer: " & Err.Number & vbLf & Err.Description: Err.Clear
End Sub

Ablauf:


- Wenn du die Datei öffnest bist du im Blatt Eingabe in A1
- hier jetzt scannen
  (oder zum Testen Handeingabe)   J1234
- nach Prüfung, ob das Blatt existiert wirst du in das blatt geleitet
- das Datum wird eingetragen und du stehst in der Nachbarzelle
- hier kannst du entweder die Steuercodes einscannen oder Bemerkungen eintragen

- Zum Abschluss den Code B_Ende scannen
- dadurch gelangst du wieder ins Eingabefeld auf Blatt Eingabe



Teste es mal.


LG UweD

[Gast 123]

Hallo

@Uwe   hallo Kollege, da warst du etwas schneller.  Wir haben beide fast die gleiche Idee.  Mein geht noch einen Tick weiter ...

Statt Eingabe habe ich ein "Übersicht" Blatt eingefügt, wo man sofort sieht wer welche Kleidung hat und den letzten Bearbeitungsstand. Als Eingabe habe ich die Zelle  F1  genommen, aber dafür in jedem Blatt. D.h., man muss nicht auf Übersicht zurück gehen um weiter einzuscannen. Ohne Scanner konnte ich es aber nicht praktisch testen. Alle Sheets haben noch einen Hyperlink zur Tabelle Übersicht.

mfg  Gast 123

[Penki2004]

Wow ihr seit der Wahnsinn ! Danke !

Soweit hab ich das verstanden und klappt auch super, nur muss ich zugeben das ich mit Makros noch nie was gemacht habe. Da müsst ihr mir vllt ein wenig helfen. Das mit dem Makro erstellen klappt wie ?

[Penki2004]

@UweD
Sind bei deiner erstellten Arbeitsmappe schon Steuercodes eingebaut ? Wenn ja wie kann ich diesen Steuercodes (z.B. gewaschen) einen Barcode zuweisen ? Auch dem Code B_Ende muss ich noch einen Barcode zuweisen oder ?

Wir bräuchten ca. 1500-2000 Blätter in der Arbeitsmappe weil wir ungefähr soviele Kleidungsstücke haben. Wie erstelle ich diese am einfachsten ? Kopieren kann ich ja immer nur 1x ein Blatt.

Hab bei der angehängten Arbeitsmappe das Blatt EH1234 so gestaltet wie dann alle Blätter aussehen sollten mit Name, Seriennummer, Größe usw. Dieses Blatt möchte ich wie oben beschrieben 2000 mal kopieren.