Bestimmung der Quartalswoche

[snb]

Bitte nicht 'quoten' !

[fredo]

Hallo,

es ist vielleicht in der Diskussion ein bisschen untergegangen, aber vielleicht hat ja doch noch jemand eine Idee zu meinem Beitrag #18.

Gruß,
Fredo

[lupo1]

Noch einmal: Es gibt keine zufriedenstellenden Antworten auf "Quartalswochen":

Entweder sind es keine ganzen Wochen am Übergang von Quartal zu Quartal und/oder sie fangen nicht (wie eine vernünftige Woche nach DIN) mit einem Montag an.

Quartale haben 90 (91 in Schaltjahren), 91, 92, 92 Tage. Nur die 91 ist dabei durch 7 teilbar. Das bedeutet: Nur das 2. Quartal besteht jedes Jahr aus genau 13 Wochen. Die aber fangen jedes Mal mit einem anderen Wochentag an!

Da Du selbst kein komplettes Beispiel mit Wunschergebnis für ein ganzes Jahr hinterlegst, wie es sein soll, willst Du von uns statt nur einer Lösung in Excel auch noch eine Lösung für das Soll. Dafür bist aber Du selbst zuständig!

Sollten dennoch weitere "Lösungen" angeboten werden, wäre es nett, sie ausnahmsweise aufgrund dieser Fragestellung auch zu begründen! Vielen Dank sagt dafür schon jetzt jeder dankbare Leser.

[fredo]

Hallo Lupo, für dich eine gesammte Darstellung:



1. Quartal 16/17:                  1. Quartalswoche: 1.11-6.11 (6 Tage DI-SO)
                                              2. Quartalswoche: 7.11-13.11 (7 Tage MO-SO)
                                             ....
                                              14. Quartalswoche: 30.01-31.01 (2 Tage MO-DI)   - 1 Quartal Ende.
 
 
2. Quartal 16/17:                  1. Quartalswoche: 1.02-5.02 (5 Tage MI-SO)
                                              2. Quartalswoche: 6.02-12.11 (7 Tage MO-SO)
                                             ....
                                              13. Quartalswoche: 24.04-30.04 (7 Tage MO-SO)   - 2 Quartal Ende. 
 
 
3. Quartal 16/17:                  1. Quartalswoche: 1.5-7.5 (7 Tage MO-SO)
                                              2. Quartalswoche: 8.5-14.5 (7 Tage MO-SO)
                                             ....
                                              14. Quartalswoche: 31.07-31.07 (1 Tage MO)   - 3 Quartal Ende. 
 
 
  4. Quartal 16/17:                  1. Quartalswoche: 1.8-6.8 (6 Tage DI-SO)
                                              2. Quartalswoche: 7.8-13.8 (7 Tage MO-SO)
                                             ....
                                              14. Quartalswoche: 30.10-31.10 (2 Tage MO-DI)   - 4 Quartal Ende.

[Rabe]

Hi fredo,

warum schreibst Du so riesengroß?

[fredo]

Hallo Rabe,

das hat das Copy Paste aus Word so ergeben.  Das hat keinerlei sekundären Grund.
Stört dich das und soll ich es nochmal ändern oder kannst du darüber hinwegsehen?

Gruß,
Fredo

[Rabe]

Hi,

ich wollte es nur wissen.

[lupo1]

Hier zwei Möglichkeiten gemäß Deiner #24, wobei ich bei der zweiten 1 von 4 Eingangsparametern A1 einspare:

=AUFRUNDEN((KÜRZEN((A1-2)/7)*7+9-DATUM(JAHR(A1);MONAT(A1)-REST(MONAT(A1)+1;3);1))/7;)
=AUFRUNDEN((KÜRZEN((A1-2)/7)*7+9-DATUM(JAHR(A1);KÜRZEN((MONAT(A1)+10)/3)*3-10;1))/7;)

[lupo1]

Hier noch eine denkbare Komplettdarstellung für den 31.10.2018:
=""
&TEXT(EDATUM(A1;-10);"-\NJJ")&TEXT(EDATUM(A1;2);"\OJJ")
&TEXT(MONAT(EDATUM(A1;2))&0;"-\QM")
&TEXT(AUFRUNDEN((KÜRZEN((A1-2)/7)*7+9-DATUM(JAHR(A1);KÜRZEN((MONAT(A1)+10)/3)*3-10;1))/7;);"-\Q\W00")
&TEXT(A1-DATUM(JAHR(A1);KÜRZEN((MONAT(A1)+10)/3)*3-10;);"-\Q\T00")
&TEXT(A1+1-(EDATUM(1&-JAHR(A1);-2+12*(MONAT(A1)>10)));"-\V\T000")
&TEXT(A1;"-TTT")
&TEXT(A1;"-JJMMTT")
&TEXT(KALENDERWOCHE(A1;21);"-\K\W00")
&TEXT(A1+1-(1&-JAHR(A1));"-\K\T000")

... ergibt separiert:
(Stringstarter, damit auch der folgende erste Teil N17O18 ohne Änderung verschoben werden kann)
-N17O18 (Jahr von Nov 2017 bis Okt 2018)
-Q4 (Quartal 4)
-QW14 (Quartalswoche 14)
-QT92 (Quartalstag 92)
-VT365 (lfd. Tag des verschobenen Jahres: 365)
-Mi (Wochentag)
-181031 (Datum international kurz)
-KW44 (Kalenderwoche)
-KT304 (Kalendertag)

... bzw. am Stück:
-N17O18-Q4-QW14-QT92-VT365-Mi-181031-KW44-KT304

Jedes Segment kannst Du aus der Formel rausnehmen oder an einen anderen Platz verschieben.

[fredo]

Hi Lupo,

erstmal ein fettes Danke!

Das hat gerade alle meine Vorstellungen übertroffen:)
Deine Extrapunkte sind super hilfreich und kann ich sogar selber für mich verwenden.
Ich werd jetzt erstmal Zeit investieren und die Formeln analysieren und hoffentlich was für mich mitnehmen können.

Dir noch eine schöne restliche Woche.

Gruß,
Fredo