Das Clever-Excel-Forum.de - Treffen
findet vom 15. - 17. September 2017 in Thüringen / Region Großer Inselsberg statt. Hotelbuchung ab sofort möglich.


Zählenwenn ohne Hilfsspalte
#1
Hallo Zusammen,

folgendes Beispiel konnte ich bisher nicht im Forum finden (bzw. auch bisher im ganzen Internet nicht wirklich), deshalb hier meine Frage.

Bezogen auf das Bild, versuche ich seit geraumer Zeit die Teilnehmer-Anzahl zu ermitteln ohne dafür eine Hilfsspalte (gelb) zu verwenden. Frage 1 ist eine Mehrfachantwort-Frage, dh der Teilnehmer kann keine bis alle 3 Fragen beantworten.
Bisher habe ich es so gelöst, indem ich in einer Hilfsspalte diese 3 Zellen in einer Zeile summiert habe und wenn es größer 0 war, konnte es als Teilnehmer gezählt werden.
Eine weitere Herausforderung ist, dass die Anzahl der Mehrfachantworten pro Frage variert (dh eine mögliche Frage 4 könnte zb 4 Antwortspalten aufweisen), aber immer nebeneinander sind.

?mage


Danke schon mal im voraus! Smile
to top
#2
Hallo,

irgendwie scheint das mit dem Bild nicht funktioniert zu haben.

Allerdings ist ein Bild i.d.R. auch keine so gute Idee - denn die wenigsten User haben Lust eine Tabelle aus einem Bild nachzubauen. Aus diesem Grund wäre eine Beispielsdatei hilfreicher.

Hier findest du eine Anleitung zum Hochladen von Dateien:

http://www.clever-excel-forum.de/Thread-...ng-stellen
Gruß
Peter
to top
#3
ah okay, danke. hier nun mit Anhang


Angehängte Dateien
.xlsx   Zählenwenn ohne Hilfsspalte.xlsx (Größe: 11,12 KB / Downloads: 13)
to top
#4
Hi,

ich denke nicht, dass dein Vorhaben so ohne weiteres umzusetzen ist. Was stört dich eigentlich an der Hilfsspalte? Die kannst du doch einfach ausblenden.
?mage

Misserfolg ist eine Chance, es beim
nächsten Mal besser zu machen.

(Henry Ford)
http://www.sprueche-zum-nachdenken.eu
to top
#5
Hallo,

das funktioniert nur dann einwandfrei, wenn Deine Datei sauber aufgebaut ist, was momentan wohl nicht der Fall ist, da keine Spalte frei ist für die Frage 1_4!!!!!

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCDEFG
1Teilnehmer_NrFrage1_1Frage1_2Frage1_3Frage2Frage3Hilfsspalte_Frage1
211 23 3
32 1   1
43   2 0
545    5
65321  6
7       
8      4
9     Anzahl der Teilnehmer die Frage 1 beantwortet haben:4

ZelleFormel
G8{=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN($B$1;ZEILE(1:5);;;3);">0")>0)*1)}
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß


Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
[-] Folgende(r) 1 Benutzer sagt Danke an BoskoBiati für diesen Beitrag:
Eydrien
to top
#6
Ah super! Genau diesen Ansatz habe ich gebraucht Smile

Ich glaube du hattest das mit Frage1_4 etwas missverstanden. Was ich gemeint hatte, war das es weitere Fragen gibt, zum Beispiel Frage4_1 bis Frage4_5.

@WillWissen
Als Hintergrund: In meiner eigentlich Datei ist jede Spalte als Bereich benannt, die man in einer anderen Mappe über zwei DropDowns auswählen kann. Zwei, weil ich hier dynamisch durch Auswahl eine Anfangsspalte und eine Endspalte zuordnen möchte.
to top
#7
Beim erweitern/anpassen meines eben geschilderten Ziels, muss ich irgendwo einen gewaltigen Denkfehler reingebaut haben.

=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX(1:1;1;VERGLEICH(A10;1:1;0));ZEILEN(INDIREKT(A10));;;INDIREKT(A10):INDIREKT(B10));">0")>0)*1)

zwischenzeitlich hatte es gepasst, bis ich irgendwas änderte 22...seht ihr vielleicht was falsch ist? Huh


Angehängte Dateien
.xlsx   Zählenwenn ohne Hilfsspalte.xlsx (Größe: 11,51 KB / Downloads: 2)
to top
#8
Hallo,

ich hab mal versucht Edgars Formel etwas allgemeiner zu fassen.

Teste mal:

Arbeitsblatt mit dem Namen 'Tabelle1'
 AB
10Frage1_14
11Frage2_13

NameBezug
Frage1_1=Tabelle1!$B$2:$B$6
Frage2_1=Tabelle1!$E$2:$E$6

ZelleFormel
B10=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(LINKS(A10;LÄNGE(A10)-2)&"*";$1:$1;0));ZEILE($1:$5);;;ZÄHLENWENN($1:$1;LINKS(A10;LÄNGE(A10)-2)&"*"));">0")>0)*1)
B11=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(LINKS(A11;LÄNGE(A11)-2)&"*";$1:$1;0));ZEILE($1:$5);;;ZÄHLENWENN($1:$1;LINKS(A11;LÄNGE(A11)-2)&"*"));">0")>0)*1)

ZelleGültigkeitstypOperatorWert1Wert2
A10Liste =$1:$1 
A11Liste =$1:$1 
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg


oder so, wenn Du nur Frage und Index nimmst:

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCD
10Frage1_14Frage14
11Frage2_13Frage23
12Frage3_35Frage35

NameBezug
Frage1_1=Tabelle1!$B$2:$B$6

ZelleFormel
B10=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(LINKS(A10;LÄNGE(A10)-2)&"*";$1:$1;0));ZEILE($1:$7);;;ZÄHLENWENN($1:$1;LINKS(A10;LÄNGE(A10)-2)&"*"));">0")>0)*1)
D10=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(C10&"*";$1:$1;0));ZEILE($1:$7);;;ZÄHLENWENN($1:$1;C10&"*"));">0")>0)*1)

ZelleGültigkeitstypOperatorWert1Wert2
A10Liste =$1:$1 
A11Liste =$1:$1 
A12Liste =$1:$1 
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

@Edgar
Edgar, ich hab die Formel nicht als Array Formel eingegeben und es scheint zu funktionieren,
oder mache ich einen Fehler.
Gruß Atilla

Excel 2007
to top
#9
Hallo atilla,

Du hast recht, es geht auch ohne Matrix. Hier mal mit variabler Zeilenanzahl:

Code:
=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(A1;ZEILE(A1:INDEX(A:A;ANZAHL($A$1:$A$9)));VERGLEICH(LINKS($A$10;7)&"*";1:1;0)-1;;ZÄHLENWENN($1:$1;LINKS($A$10;7)&"*"));">0")>0)*1)
Gruß


Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
to top
#10
Hallo Edgar,

Zitat:Hier mal mit variabler Zeilenanzahl:

da war ich auch gerade dran.

Ich hatte das: A1:INDEX(A:A;ANZAHL($A$1​:$A$9) ohne Umrandung mit Zeile getestet.
Funktioniert natürlich nicht. Nach dem Ausschlafen hätte ich es dann mit Zeile Umrandet. :-)

Insgesamt eine schöne Lösung von Dir, die ich sicher nicht behalten werde.
Gruß Atilla

Excel 2007
to top


Möglicherweise verwandte Themen...
Thema Verfasser Antworten Ansichten Letzter Beitrag
  Zählenwenn mit Text? WHOAMI 3 130 05.11.2016, 13:50
Letzter Beitrag: schauan
  Zählenwenn Groß- und Kleinschreibung MalteMobile 9 255 21.09.2016, 13:48
Letzter Beitrag: Jockel
  Verständnis ZÄHLENWENN MalteMobile 5 150 19.09.2016, 16:48
Letzter Beitrag: shift-del
  Doppelte Bedingung mit ZÄHLENWENN Sebasor 3 246 09.09.2016, 07:58
Letzter Beitrag: schauan
  ZÄHLENWENN mit Bedingung Monika 7 241 17.08.2016, 15:28
Letzter Beitrag: Monika
Wink zählenwenn andrea75w 3 202 11.08.2016, 17:09
Letzter Beitrag: neopa
  Zählenwenn mit Punkten AwesomeMeMe 4 204 09.08.2016, 15:59
Letzter Beitrag: neopa
  Zählenwenn mit Bedinungen Fred B 4 213 28.07.2016, 08:41
Letzter Beitrag: steve1da
  Zählenwenn mit Bedinung Fred B 6 294 14.07.2016, 12:32
Letzter Beitrag: Fred B
  Zählenwenn: Bereich variieren xDice 12 496 29.06.2016, 13:31
Letzter Beitrag: Jockel

Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste