Hallo Zusammen,
folgendes Beispiel konnte ich bisher nicht im Forum finden (bzw. auch bisher im ganzen Internet nicht wirklich), deshalb hier meine Frage.
Bezogen auf das Bild, versuche ich seit geraumer Zeit die Teilnehmer-Anzahl zu ermitteln ohne dafür eine Hilfsspalte (gelb) zu verwenden. Frage 1 ist eine Mehrfachantwort-Frage, dh der Teilnehmer kann keine bis alle 3 Fragen beantworten.
Bisher habe ich es so gelöst, indem ich in einer Hilfsspalte diese 3 Zellen in einer Zeile summiert habe und wenn es größer 0 war, konnte es als Teilnehmer gezählt werden.
Eine weitere Herausforderung ist, dass die Anzahl der Mehrfachantworten pro Frage variert (dh eine mögliche Frage 4 könnte zb 4 Antwortspalten aufweisen), aber immer nebeneinander sind.
[Bild: Unbenannta5e0e.png]
Danke schon mal im voraus! :)
Hallo,
irgendwie scheint das mit dem Bild nicht funktioniert zu haben.
Allerdings ist ein Bild i.d.R. auch keine so gute Idee - denn die wenigsten User haben Lust eine Tabelle aus einem Bild nachzubauen. Aus diesem Grund wäre eine Beispielsdatei hilfreicher.
Hier findest du eine Anleitung zum Hochladen von Dateien:
http://www.clever-excel-forum.de/Thread-...ng-stellen
ah okay, danke. hier nun mit Anhang
Hi,
ich denke nicht, dass dein Vorhaben so ohne weiteres umzusetzen ist. Was stört dich eigentlich an der Hilfsspalte? Die kannst du doch einfach ausblenden.
Hallo,
das funktioniert nur dann einwandfrei, wenn Deine Datei sauber aufgebaut ist, was momentan wohl nicht der Fall ist, da keine Spalte frei ist für die Frage 1_4!!!!!
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B | C | D | E | F | G |
| 1 | Teilnehmer_Nr | Frage1_1 | Frage1_2 | Frage1_3 | Frage2 | Frage3 | Hilfsspalte_Frage1 |
| 2 | 1 | 1 | | 2 | 3 | | 3 |
| 3 | 2 | | 1 | | | | 1 |
| 4 | 3 | | | | 2 | | 0 |
| 5 | 4 | 5 | | | | | 5 |
| 6 | 5 | 3 | 2 | 1 | | | 6 |
| 7 | | | | | | | |
| 8 | | | | | | | 4 |
| 9 | | | | | | Anzahl der Teilnehmer die Frage 1 beantwortet haben: | 4 |
| Zelle | Formel |
| G8 | {=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN($B$1;ZEILE(1:5);;;3);">0")>0)*1)} |
| Achtung, Matrixformel enthalten! |
| Die geschweiften Klammern{} werden nicht eingegeben. |
| Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Ah super! Genau diesen Ansatz habe ich gebraucht :)
Ich glaube du hattest das mit Frage1_4 etwas missverstanden. Was ich gemeint hatte, war das es weitere Fragen gibt, zum Beispiel Frage4_1 bis Frage4_5.
@WillWissen
Als Hintergrund: In meiner eigentlich Datei ist jede Spalte als Bereich benannt, die man in einer anderen Mappe über zwei DropDowns auswählen kann. Zwei, weil ich hier dynamisch durch Auswahl eine Anfangsspalte und eine Endspalte zuordnen möchte.
Beim erweitern/anpassen meines eben geschilderten Ziels, muss ich irgendwo einen gewaltigen Denkfehler reingebaut haben.
=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX(1:1;1;VERGLEICH(A10;1:1;0));ZEILEN(INDIREKT(A10));;;INDIREKT(A10):INDIREKT(B10));">0")>0)*1)
zwischenzeitlich hatte es gepasst, bis ich irgendwas änderte :22:...seht ihr vielleicht was falsch ist?
Hallo,
ich hab mal versucht Edgars Formel etwas allgemeiner zu fassen.
Teste mal:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B |
| 10 | Frage1_1 | 4 |
| 11 | Frage2_1 | 3 |
| Name | Bezug |
| Frage1_1 | =Tabelle1!$B$2:$B$6 |
| Frage2_1 | =Tabelle1!$E$2:$E$6 |
| Zelle | Formel |
| B10 | =SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(LINKS(A10;LÄNGE(A10)-2)&"*";$1:$1;0));ZEILE($1:$5);;;ZÄHLENWENN($1:$1;LINKS(A10;LÄNGE(A10)-2)&"*"));">0")>0)*1) |
| B11 | =SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(LINKS(A11;LÄNGE(A11)-2)&"*";$1:$1;0));ZEILE($1:$5);;;ZÄHLENWENN($1:$1;LINKS(A11;LÄNGE(A11)-2)&"*"));">0")>0)*1) |
| Zelle | Gültigkeitstyp | Operator | Wert1 | Wert2 |
| A10 | Liste | | =$1:$1 | |
| A11 | Liste | | =$1:$1 | |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
oder so, wenn Du nur Frage und Index nimmst:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B | C | D |
| 10 | Frage1_1 | 4 | Frage1 | 4 |
| 11 | Frage2_1 | 3 | Frage2 | 3 |
| 12 | Frage3_3 | 5 | Frage3 | 5 |
| Name | Bezug |
| Frage1_1 | =Tabelle1!$B$2:$B$6 |
| Zelle | Formel |
| B10 | =SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(LINKS(A10;LÄNGE(A10)-2)&"*";$1:$1;0));ZEILE($1:$7);;;ZÄHLENWENN($1:$1;LINKS(A10;LÄNGE(A10)-2)&"*"));">0")>0)*1) |
| D10 | =SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(INDEX($1:$1;;VERGLEICH(C10&"*";$1:$1;0));ZEILE($1:$7);;;ZÄHLENWENN($1:$1;C10&"*"));">0")>0)*1) |
| Zelle | Gültigkeitstyp | Operator | Wert1 | Wert2 |
| A10 | Liste | | =$1:$1 | |
| A11 | Liste | | =$1:$1 | |
| A12 | Liste | | =$1:$1 | |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
@Edgar
Edgar, ich hab die Formel nicht als Array Formel eingegeben und es scheint zu funktionieren,
oder mache ich einen Fehler.
Hallo atilla,
Du hast recht, es geht auch ohne Matrix. Hier mal mit variabler Zeilenanzahl:
Code:
=SUMMENPRODUKT((ZÄHLENWENN(BEREICH.VERSCHIEBEN(A1;ZEILE(A1:INDEX(A:A;ANZAHL($A$1:$A$9)));VERGLEICH(LINKS($A$10;7)&"*";1:1;0)-1;;ZÄHLENWENN($1:$1;LINKS($A$10;7)&"*"));">0")>0)*1)
Hallo Edgar,
Zitat:Hier mal mit variabler Zeilenanzahl:
da war ich auch gerade dran.
Ich hatte das: A1:INDEX(A:A;ANZAHL($A$1:$A$9) ohne Umrandung mit Zeile getestet.
Funktioniert natürlich nicht. Nach dem Ausschlafen hätte ich es dann mit Zeile Umrandet.
Insgesamt eine schöne Lösung von Dir, die ich sicher nicht behalten werde.