Zelle aus anderer Datei auslesen - Spalte fix, Zeile variabel

[schauan]

Hallöchen,

ich hatte ja schon auf die Problematik mit der 0 hingewiesen und den Beispielbeitrag. Abgeleitet daraus hier mal für den Namen in B18 ein langer Ansatz:

=WENN(ISTZAHL(N(SVERWEIS($B$2;'C:\Test\[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0)));SVERWEIS($B$2;'C:\Test\[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;5;0);SVERWEIS($B$2;'C:\Test\[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0))


und ein kurzer:
=WENNFEHLER(--(SVERWEIS($B$2;'C:\Test\[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0)&"");SVERWEIS($B$2;'C:\Test\[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;5;0))

Den Pfad C:\Test musst Du natürlich nach Deinen Gegebenheiten anpassen.

[spuely]

Hallo André,
vielen Dank schonmal.
Ich habe es mit deiner langen und der kurzen Variante versucht - natürlich auch die Angabe der Quelldatei angepasst. 
Leider klappt es nicht ganz - Ergebnis "0".

Kannst du mir die beiden Formeln bitte kurz erklären - vielleicht mache ich beim Anpassen einen Fehler.
Was bewirkt das N ziemlich am Anfang der langen Formel oder wofür steht z.B. das -- bei der kurzen?

Oder hast du diese Formeln in meiner hochgeladen Datei getestet, so dass du mir diese eventuell erneut hochladen kannst?

[schauan]

Hallöchen,

ich habe hier mal die 3 Varianten in Deiner Testdatei -  lang, kurz und Ww.
Bei letzterer habe ich den Bereich beim ersten SVERWEIS auf Zeile 200 erweitert wie im alternativen, Zeile 5 war zu wenig . Im Test steht in B2 ja 1003, das wird in Zeile 6 gefunden.
Bei mir bin ich mal eine Spalte weiter gegangen, in meinem Post hatte ich auf den Vornamen verwiesen und nicht, wie in B18 gefordert, den Nachnamen
N bzw. -- dienen dazu, dass die 0 auch wirklich als Zahl bewertet wird

Arbeitsblatt mit dem Namen 'LABOR'
	A	B	C	D
17	Proband	lang	kurz	Ww
18	Nachname	Müller	Müller	0

Zelle	Formel
B18	=WENN(ISTZAHL(N(SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0)));SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;6;0);SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0))
C18	=WENNFEHLER(--(SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0)&"");SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;6;0))
D18	=WENNFEHLER(SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0);SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;6;0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[spuely]

Vielen Dank für deine Bemühungen, aber es klappt einfach nicht - egal mit welcher Variante - sorry.  


Mit deiner Formel (ich habe den richtigen Dateiname eingetragen)...

=WENNFEHLER(--(SVERWEIS($B$2;[Anfragen_P-Care.xlsx]Formularantworten!$B$3:$BM$200;14;0)&"");SVERWEIS($B$2;[Anfragen_P-Care.xlsx]Formularantworten!$B$3:$BM$200;6;0))

...da zieht er den Namen des Auftraggebers aus (6) ignoriert aber ob in (14) beim Probanden was steht oder nicht - denn wenn bei (14) was steht, dann so ja dieser Eintrag verwendet werden und nur wenn leer dann Eintrag aus (6).


Nachdem ich deine Formel reinkopiert hatte, waren die Hochkommatas vor den eckigen Klammern verschwunden... normal/egal?

[schauan]

Hallöchen,

ich habe jetzt mal meine lange mit dem -- aus der kurzen kombiniert, klappt. In "14" steht Otto

Arbeitsblatt mit dem Namen 'LABOR'
	A	B	C
17	Proband	lang	kurz
18	Nachname	otto	Müller

Zelle	Formel
B18	=WENN(ISTZAHL(--(SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0)));SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;6;0);SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0))
C18	=WENNFEHLER(--(SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;14;0)&"");SVERWEIS($B$2;'[datei-2.xlsx]Formularantworten'!$B$3:$BM$200;6;0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[spuely]

Du bist mein Held des Tages... die lange Variante funktioniert!
Damit wird für mich bei der Abwicklung endlich einiges leichter!

Vielen Dank für eure Ausdauer... auch Danke an Günter!