Wenn/ und / Oder verschachtelt

[Monica_66]

Guten Tag, 

als Logik-Legasthenikerin komme ich mit diesen Excel Funktionen einfach nicht zurecht. Kaum denke ich, jetzt habe ich es kapiert, kommt die nächste Aufgabe, die mir klar macht, dass ich überhaupt nix verstanden habe. 
Ein tolles Beispiel ist die angehängte Datei. Hier geht es darum, dass alle Männer, die die Prüfung bestanden haben, einen Schraubenschlüssel bekommen. alle Frauen, die bestanden haben, bekommen Sekt. Alle anderen nix. 

ich hätte die Funktion so aufgebaut: =Wenn(Feld ="m"; Feld="bestanden);(und(Feld="w"; Feld="bestanden);"Schraubenschlüssel";"Sekt";"")

also, wenn männlich, bestanden und weiblich,bestanden dann Schraubenschlüssel, Sekt, nix

aber das funktioniert einfach nicht. 
wo habe ich meinen Denkfehler?
mit Zahlen im Feld ist es einfacher aber mit Text in der Zelle?
ich hab auch schon versucht mit wenn "m";"w";Feld >=10; dann "Schraubenschlüssel";"Sekt";"nix"

kann mir bitte bitte jemand helfen? ich soll das bis zur Zwischenprüfung verstanden haben 

liebe Grüße
Monica

[LCohen]

F2: =WENN(E2="bestanden";SVERWEIS(C2;{"m"."SchrSchl";"w"."Sekt"};2;);) benDefFmt Standard;;

[RPP63]

Und da ich annehme, dass LCohens richtige Formel als "nicht gelöst" bewertet wird, mal die old fashioned Lösung für einen Anfängerkurs:
=WENN(UND(C2="m";E2="bestanden");"Schraubenschlüssel";WENN(UND(C2="w";E2="bestanden");"Sekt";""))

Da ist nixxx mit ODER()

Und jetzt denke Dir andere Beispiele aus und löse selbständig!
Sonst wird das nämlich nichts mit der Prüfung.

[Monica_66]

der SVerweis, da wäre ich nie drauf gekommen

---

also ein bisschen nah dran war ich stellenweise 
ich muss das mit ganz viel Humor machen, sonst raste ich noch aus 
das ist dann eine Lösung wo ich ich wieder denke, na klaaaaaaaaaaaaar! ist doch logisch!!!!

auch dir vielen herzlichen Dank. 
das wird sicher nicht die letzte Frage sein. ich hab da noch andere Sachen bekommen ...

[RPP63]

und für den Dozenten dann noch eine Lösung in Spalte G, wo er selbst suchen muss, was ich da gemacht habe:

	A	B	C	D	E	F	G
1	Personal- Nummer	Name	Geschlecht	Punkte	Ergebnis	Prämie
2	500	Bendorf	m	12	bestanden	Schraubenschlüssel	Schraubenschlüssel
3	503	Sikorski	w	13	bestanden	Sekt	Sekt
4	504	Ruckl	m	8	nachprüfung
5	505	Reith	w	11	bestanden	Sekt	Sekt

Zelle	Format	Wert
G2	[=1]"Schraubenschlüssel";[=2]"Sekt";;	1

Zelle	Formel
E2	=WENN(D2>=10;"bestanden";WENN(D2<6;"durchgefallen";"nachprüfung"))
F2	=WENN(UND(C2="m";E2="bestanden");"Schraubenschlüssel";WENN(UND(C2="w";E2="bestanden");"Sekt";""))
G2	=((C2="m")*(E2="bestanden"))+2*((C2="w")*(E2="bestanden"))

[Monica_66]

Hammer ! 
warum können meine Synapsen das nicht auch? 

[RPP63]

Alles ne Sache der Übung!
Wobei die doppelte Prüfung auf "bestanden" Quatsch ist.
Und natürlich die Prüfung auf "bestanden" an sich, denn das ist ja Spalte D > 9, also kurz
=(D2>9)*((C2="m")+2*(C2="w"))

---

Und weil es Spaß macht, die wohl ultimative Kürzung:
=(D2>9)*FINDEN(C2;"mw")