Wenn Oder Suchen Formel

[Hamza420]

Liebe Experten,

ich habe eine Frage zu einer Wenn Oder Formel in Kombination zu Suchen. Ich suche nach in einer Zelle nach 3 Schlagwörtern (Oder). Wenn einer davon gefunden wird, dann soll es mir eine bestimmte Zahl 1 oder 2 ausgeben. Ich habe eine Beispielsdatei. 

Die Suchenfunktion geht aber nicht in Kombination mit der Suchen Oder????

Vielen Dank!

[steve1da]

Hola,

Die Suchenfunktion geht aber nicht in Kombination mit der Suchen Oder????

doch. Du musst nur um jedes Suchen() ein Istzahl() packen.
Das deine Zahlen als TEXT ausgegeben werden ist gewollt?

Gruß,
steve1da

[merkurus]

Hallo

In B2 z.B. mal folgende Formel eintragen. Probiers mal damit.

Code:

=WENN(ODER( NICHT(ISTFEHLER(SUCHEN("GE";A2))); NICHT(ISTFEHLER(SUCHEN("Duo";A2))); NICHT(ISTFEHLER(SUCHEN("Tri";A2))));"8";"5")

Gruß

[Fred11]

....oder mit ZÄHLENWENN mit *

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Name	Formel
2	Artikel 1 Du 2.4	5	5	5
3	Artikel 2 Tri - Var 2	8	8	8
4	Artikel 3 Duo	8	8	8
5	Artikel 3 Duo Trist	8	8	8
6	Artikel xyz	5	5	5

Zelle	Formel
B2	=WENN(ODER(ISTZAHL(SUCHEN("GE";A2));ISTZAHL(SUCHEN("Duo";A2));ISTZAHL(SUCHEN("Tri";A2)));8;5)
C2	=WENN(ZÄHLENWENN(A2;"*GE*")+ZÄHLENWENN(A2;"*Duo*")+ZÄHLENWENN(A2;"*Tri*");8;5)
D2	=WENN(SUMME(ZÄHLENWENN(A2;{"*GE*";"*Duo*";"*Tri*"}));8;5)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß
Fred