Inhalt Zelle kopieren wenn Nachbarzelle "X"

[Daniel Albert]

Hallo,

ich habe leider keine passende Lösung im Internet zu folgender Herausforderung gefunden:


A                      B
1 bauer             x
2 müller  
3 Herbst            x

Ich möchte in einen anderen Zellbereich untereinander nur die Werte aus der Spalte A agezeigt haben wo in der Spalte B ein "x" steht.

Ich kann zwar mit der Wenn- Funktion arbeiten bekomme es aber nicht hin, dass keine Leerzeilen entstehen.

Gibt es dafür eine Lösung ?

ruß daniel

[GMG-CC]

Moin Daniel,

die einfachste Lösung: Per Autofilter nur die entsprechenden Daten anzeigen lassen, markieren, kopieren und am Ziel einfügen.

[WillWissen]

Hi Daniel,

neben der Filterlösung von Günther hier mein Vorschlag mit einer Matrixformel.

Auf gleichem Arbeitsblatt:

Tabelle1

	A	B	C	D
1	blauer	x		blauer
2	Müller			Herbst
3	Herbst	x
4

Formeln der Tabelle

Zelle Formel D1 {=WENN(ZEILE(1:1)>ZÄHLENWENN(B:B;"x");"";INDEX(A:A;KKLEINSTE(WENN(B:B="x";ZEILE($1:$7));ZEILE(A1))))} D2 {=WENN(ZEILE(2:2)>ZÄHLENWENN(B:B;"x");"";INDEX(A:A;KKLEINSTE(WENN(B:B="x";ZEILE($1:$7));ZEILE(A2))))} D3 {=WENN(ZEILE(3:3)>ZÄHLENWENN(B:B;"x");"";INDEX(A:A;KKLEINSTE(WENN(B:B="x";ZEILE($1:$7));ZEILE(A3))))} D4 {=WENN(ZEILE(4:4)>ZÄHLENWENN(B:B;"x");"";INDEX(A:A;KKLEINSTE(WENN(B:B="x";ZEILE($1:$7));ZEILE(A4))))}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8


Oder auf zweitem Arbeitsblatt:


Tabelle2

	A
1	blauer
2	Herbst
3
4

Formeln der Tabelle

Zelle Formel A1 {=WENN(ZEILE(1:1)>ZÄHLENWENN(Tabelle1!B:B;"x");"";INDEX(Tabelle1!A:A;KKLEINSTE(WENN(Tabelle1!B:B="x";ZEILE($1:$7));ZEILE(Tabelle1!A1))))} A2 {=WENN(ZEILE(2:2)>ZÄHLENWENN(Tabelle1!B:B;"x");"";INDEX(Tabelle1!A:A;KKLEINSTE(WENN(Tabelle1!B:B="x";ZEILE($1:$7));ZEILE(Tabelle1!A2))))} A3 {=WENN(ZEILE(3:3)>ZÄHLENWENN(Tabelle1!B:B;"x");"";INDEX(Tabelle1!A:A;KKLEINSTE(WENN(Tabelle1!B:B="x";ZEILE($1:$7));ZEILE(Tabelle1!A3))))} A4 {=WENN(ZEILE(4:4)>ZÄHLENWENN(Tabelle1!B:B;"x");"";INDEX(Tabelle1!A:A;KKLEINSTE(WENN(Tabelle1!B:B="x";ZEILE($1:$7));ZEILE(Tabelle1!A4))))}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[RPP63]

Moin!
Ergänzend eine Lösung ohne Matrixformel, allerdings mit Hilfsspalte.
(könnte man zwar in einer Formel verwursten, wäre dann aber unübersichtlich)

	A	B	C	D	E
1	Name	Auswahl		Hilfsspalte	Name
2	Böhm			3	Jacobs
3	Jacobs	x		7	Richter
4	Paulus			10	Schott
5	Wichmann			11	Rau
6	Schmitz			14	Pfaff
7	Richter	x		18	Geyer
8	Hammer			20	Schröder
9	Reichert
10	Schott	x
11	Rau	x
12	Brückner
13	Stolz
14	Pfaff	x
15	Rohde
16	Frank
17	Haag
18	Geyer	x
19	Neubert
20	Schröder	x
21	Meister

Formeln der Tabelle

Zelle Formel D2 =VERGLEICH("x";B:B;0) E2 =WENN(D2="";"";INDEX(A:A;D2)) D3 =WENN(ZEILE()-1>ZÄHLENWENN(B:B;"x");"";D2+VERGLEICH("x";INDEX(INDEX(B:B;D2+1):B1000;);0)) E3 =WENN(D3="";"";INDEX(A:A;D3))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Den Input habe ich hier her:
http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=224

Die Formeln aus D3 und E2 können beliebig nach unten gezogen werden, also auch über den Wertebereich hinaus.

Gruß Ralf

[WillWissen]

Hallo zusammen,

dann hätte ich noch eine matrixfreie Alternative:

Tabelle2 (2)

	A	B	C	D
1	Name	Auswahl	HS
2	Böhm			Jacobs
3	Jacobs	x	3	Richter
4	Paulus			Schott
5	Wichmann			Rau
6	Schmitz			Pfaff
7	Richter	x	7	Geyer
8	Hammer			Schröder
9	Reichert
10	Schott	x	10
11	Rau	x	11
12	Brückner
13	Stolz
14	Pfaff	x	14
15	Rohde
16	Frank
17	Haag
18	Geyer	x	18
19	Neubert
20	Schröder	x	20
21	Meister

Formeln der Tabelle

Zelle Formel C2 =WENN(B2="x";ZEILE();"") D2 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A1)));"") C3 =WENN(B3="x";ZEILE();"") D3 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A2)));"") C4 =WENN(B4="x";ZEILE();"") D4 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A3)));"") C5 =WENN(B5="x";ZEILE();"") D5 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A4)));"") C6 =WENN(B6="x";ZEILE();"") D6 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A5)));"") C7 =WENN(B7="x";ZEILE();"") D7 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A6)));"") C8 =WENN(B8="x";ZEILE();"") D8 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A7)));"") C9 =WENN(B9="x";ZEILE();"") D9 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A8)));"") C10 =WENN(B10="x";ZEILE();"") D10 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A9)));"") C11 =WENN(B11="x";ZEILE();"") D11 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A10)));"") C12 =WENN(B12="x";ZEILE();"") D12 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A11)));"") C13 =WENN(B13="x";ZEILE();"") D13 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A12)));"") C14 =WENN(B14="x";ZEILE();"") D14 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A13)));"") C15 =WENN(B15="x";ZEILE();"") D15 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A14)));"") C16 =WENN(B16="x";ZEILE();"") D16 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A15)));"") C17 =WENN(B17="x";ZEILE();"") D17 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A16)));"") C18 =WENN(B18="x";ZEILE();"") D18 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A17)));"") C19 =WENN(B19="x";ZEILE();"") D19 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A18)));"") C20 =WENN(B20="x";ZEILE();"") D20 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A19)));"") C21 =WENN(B21="x";ZEILE();"") D21 =WENNFEHLER(INDEX(A:A;KKLEINSTE(C:C;ZEILE(A20)));"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[RPP63]

Hallo Günter!
Schöne einfache Lösung! 
Aber:
Du kannst doch nicht einfach meine Namen klauen ...   :21:

Ich habe mir einen Namensgenerator aus den 630 häufigsten Nach- und den jeweils 310 häufigsten weibl. und männl. Vornamen gebastelt.
Jeweils (aus Platzgründen) ausgelagert in .txt-Dateien, Aufruf per UDF aus meiner PERSONAL.XLSB (im Beispiel sind die UDF's, nicht jedoch die Namen, in der Mappe).
Führt dann zu so etwas:

	D	E	F	G
1	Nachname	Vorname w	Vorname m	Vorname ?
2	Rösch	Dorothea	Ibrahim	Peggy
3	Riedel	Gerlinde	Gerhard	Inga
4	Kühl	Bianca	Arne	Grete
5	Cordes	Johanna	Ingolf	Norbert
6	Horstmann	Pia	Ludger	Christoph
7	Kunz	Steffi	Gerhard	Marcel
8	Reimer	Therese	Edwin	Roger
9	Albers	Vera	Ewald	Marian
10	Fries	Maria	Hans-Peter	Dorothee
11	Blank	Edith	Christian	Christof

Formeln der Tabelle

Zelle Formel D2 =NachnameZufall() E2 =VornameZufall("w") F2 =VornameZufall("m") G2 =VornameZufall()

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Da es so etwas tatsächlich noch nicht im WWW zu finden gibt, überlege ich, das mal vernünftig aufzuarbeiten und hier zur Verfügung zu stellen.

Gruß Ralf

[WillWissen]

Hi Ralf,

Du kannst doch nicht einfach meine Namen klauen ...   [img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

ich hoffe, ich tue dir da nicht allzu sehr weh - aber ich bin bei so etwas völlig schmerzfrei. :89:

[...] überlege ich, das mal [...] hier zur Verfügung zu stellen.

Das wäre eine tolle Sache. Im Forum "Komplettlösungen" wäre für einen Namensgenerator prima Platz. *freu* Es fällt ja immer wieder Usern schwer, eine Tabelle zu anonymisieren.

[Daniel Albert]

Hallo an euch ALLE

DANKE

Ich habe mich für die 2te Variante entschieden da die Vorgaben aus mehreren Zellbereich zusammengesetzt werden. Daher habe ich jetzt kein gestückel mehr.Klappt wunderbar. Wollte noch eine Überschrift also eine Zeile einfügen aber dann haut er alles durcheinander. Ist aber nicht so wild.

Danke für die schnelle Unterstützung, hat mal wieder Super geklappt.

Gruß Daniel

[WillWissen]

Wollte noch eine Überschrift also eine Zeile einfügen aber dann haut er alles durcheinander. Ist aber nicht so wild.

Welchen Vorschlag genau hast du verwendet? Entsprechend musst du beim Einfügen einer Zeile die Formel anpassen.

[Daniel Albert]

Guten Morgen,

ich habe deinen letzten Vorschlag und den von Ralf durchgeführt. Beide würden passen aber ich kann bei beiden keine zusätzliche Zeile einfügen sonst passt das komplette System nicht mehr