Daten aus Liste in Kalender eintragen

[Thomas78]

Entschuldigung wenn ich nochmal nachfrage...

Ich habe nochmals eine andere Version angehängt.

Zum Verständnis würde ich in dieser Version gerne wissen wie ich die bisherige Formel umändern muss, damit es mir alle Werte aus der "Terminübersicht" die dem jeweiligen Monat entsprechen in die einzelnen Monat anzeigen kann.

Also z.B. 01.01.2017 Bäumel Führerschein und 01.01.2017 asdasd asdasd unter Januar (Spalte B) und 01.03.2017 asdasdsdasd ggggg und März in Spalte F 

Ich habe bereits versucht, das ganze mit MONAT auszulesen, komme hier aber nicht weiter.

Kann mit hier bitte nochmals jemand helfen mein Wissen zu erweitern?

Vielen Dank und schöne Grüße

Thomas

[neopa]

Hallo Thomas,

... ich hab mir jetzt nicht weiter die vorherigen Beiträge näher angeschaut.

Zu Deiner neuen Anfrage, in B5:

Code:

=WENNFEHLER(INDEX(TEXT($H$1:$H$999;"TTTT, TT.")&", "&$I$1:$I$999&", "&$J$1:$J$999;AGGREGAT(15;6;ZEILE($B$5:$H$999)/(TEXT($H$5:$H$999;"MM.JJ")=TEXT(B$3;"MM.JJ"));ZEILE(B1)));"")

Diese Formel nach unten kopieren und dann den Bereich nach rechts.

Da der Monat und das Jahr schon in den Überschriften steht, hab ich den Datumseintrag nur auf den Tag beschränkt. Kannst Du natürlich bei Bedarf noch erweitern.

[Thomas78]

Hallo Werner,

vielen Dank für deinen Beitrag.

Leider funktioniert die Formel bei mir nicht. Fehlermeldung wird keine angezeigt, aber es überträgt mir keine Daten in die einzelnen Monate.

Schöne Grüße

Thomas

[steve1da]

Hola,

bei mir schon. Hast du die Formel genauso in deine Tabelle in B5 eingefügt?

Gruß,
steve1da

[Thomas78]

Ohje ohje ich schäm mich so.... (es ist halt noch zu früh)

Ich hatte in meiner Datei immer den 01.07. als Beispiel drin. Nur in dieser hatte ich den 01.01. darum dachte ich es funktioniert nicht.

Natürlich funktioniert aber alles so wie es soll.

Vielen Dank !!!

[Rabe]

Hi,

Diese Formel nach unten kopieren und dann den Bereich nach rechts.

wie würde man denn bei Geburtstagen das Alter (, xx Jahre) auch noch in diese Formel am Ende einbauen?
Gesetzt den Fall, in Spalte K steht das Geburtsjahr.

Oder wäre es sinnvoller, den Eintrag solch wiederkehrender Termine ganz anders zu lösen?


Frage 2:
Warum ergibt
=DATUM(116;A1;1)
bei A1:= 18
den 01.06.2017?

[neopa]

Hallo Ralf,

in meine gestern eingestellte Formel kann man auch auf Basis einer Jahreszahl in Spalte K, die Ermittlung des Alter des jeweiligen Ereignisses einbauen und dann entsprechend auch ausgeben.
Der Einfachheit halber hab ich hier mal darauf verzichtet, dies auch noch als Matrixfunktion(alität)sformel umzubauen. Das nachfolgende genutzte WENN() ermöglichte die Grundstruktur der Formel beizubehalten, erfordert aber nun deswegen zwingend die Eingabe der Formel als klassische Matrixformel.

In B5: 

Code:

{=WENNFEHLER(INDEX(TEXT($H$1:$H$999;"TTTT, TT.")&", "&$I$1:$I$999&", "&$J$1:$J$999&WENN($K$1:$K$999;", "&JAHR($H$1:$H$999)-$K$1:$K$999&" Jahre";"");AGGREGAT(15;6;ZEILE($B$5:$H$999)/(TEXT($H$5:$H$999;"MM.JJ")=TEXT(B$3;"MM.JJ"));ZEILE(B1)));"")}

Und zu Deiner Zusatzfrage: Ob das eine sinnvolle Lösungsmöglichkeit ist oder nicht, hängt von vielen Faktoren ab. Und ob Du oder Thomas das so anwendest, ist natürlich Eure Entscheidung. Natürlich kann man einen Kalender auch noch anders aufbauen und ... aber Thomas hatte sich nun mal für diese Struktur entschieden.

Noch ein Hinweis an Thomas. Die 999 in der Formel kannst und solltest Du natürlich durch das max. erforderliche Zeilenende-Zahl ersetzen, z.B. 500 oder eben auch nur 99. Je weniger groß der auszuwertende Datenbereich ist, desto schneller ist die Auswertung.

[Thomas78]

Hallo Werner,

ich habe mich noch nicht entschieden wie ich den Kalender letztlich aufbaue. Momentan probiere ich verschiedene Varianten aus und setze mich mit den dazugehörenden Formeln auseinander.

Für mich ist das ein Lernprozess, da ich vielleicht eine Formel für einen Aufbau kenne aber die verschiedenen Möglichkeiten kennen will. Natürlich will ich dann auch die Formeln so weit verstehen, dass ich auch z.B. in einem Jahr noch Änderungen, Verbesserungen usw. daran vornehmen kann ohne gleich wieder auf eure Hilfe angewiesen zu sein.

An dieser Stelle möchte ich mich ausdrücklich bei allen bedanken die mir bisher geholfen haben!!!

Schöne Grüße Thomas

[Rabe]

Hi,

ich würde

1. als Erstes zwei neue Spalten nach L einfügen
   
2. die Spalte H in die Spalte K verschieben.
   
3. dann in Spalte H die Daten eingeben und
   
4. in Spalte K folgende Formel einsetzen: =WENN($H5="";"";DATUM(JAHR(HEUTE());MONAT($H5);TAG($H5)))
   
5. in Spalte L folgende Formel einsetzen: =WENN($J5="Geburtstag";JAHR($K5)-JAHR($H5);"")
   

Dadurch wird das richtige Datum verwendet für

• aktuelle Termine
  
• jährlich wiederkehrende Termine (hier wird in Spalte L das Alter errechnet)
  

Tabelle1

	F	G	H	I	J	K	L	M
3	Dezember		Terminübersicht
4
5	Sonntag, 31., Silvester, Geburtstag		01.01.2017	Bäumel	Führerschein	01.01.2017
6			01.01.2017	asdasd	asdasd	01.01.2017
7			01.03.2017	asdasdsdasd	ggggg	01.03.2017
8			31.12.1910	Silvester	Geburtstag	31.12.2017	107
9

verwendete Formeln
Zelle	Formel	Bereich	N/A
F3	=EDATUM(B3;2)
F5:F9	=WENNFEHLER(INDEX(TEXT($K$1:$K$99;"TTTT, TT.")&", "&$I$1:$I$99&", "&$J$1:$J$99;AGGREGAT(15;6;ZEILE($B$5:$K$99)/(TEXT($K$5:$K$99;"MM.JJ")=TEXT(F$3;"MM.JJ"));ZEILE(F1)));"")
K5:K9	=WENN(H5="";"";DATUM(JAHR(HEUTE());MONAT($H5);TAG($H5)))
L5:L9	=WENN(J5="Geburtstag";JAHR(K5)-JAHR(H5);"")

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.08 einschl. 64 Bit

Jetzt noch die Formel von Helmut anpassen, damit das Alter gegebenenfalls hinter den Text angefügt wird.
Und vielleicht noch die Terminsortierung in der Monatanzeige.

[neopa]

Hallo Ralf,

ich bin etwas verwundert bzw. auch irritiert über Dein Verhalten und Aussagen hier im thread. Von einem wie Dir, der bereits knapp 5000 Beiträge allein nur hier im Forum eingestellt  hat, hätte ich solches nicht erwartet.

Du hast gestern mich hier um einen ergänzenden Lösungsvorschlag nachgefragt. Diesen habe ich Dir aufgezeigt. Du hast darauf dann allerdings nicht geantwortet. Nun aber stellst Du heute "Vorschläge" ein, die mE nicht wirklich begründet sind. U.a. gibt es in vielen Kalendern noch andere wiederkehrende Termine als nur Geburtstage.  Und um solche zu berücksichtigen und formeltechnisch auch in der bisher vorgesehenen Art und Weise auszugeben, bedarf es keiner zwei zusätzlichen Eingabespalten sondern nur der einer, wie Du gestern vorgeschlagen hattest. 

Hinzu kommt Deine nicht nachvollziehbare abschließende Aussagen in Deinem Beitrag:

Jetzt noch die Formel von Helmut anpassen, damit das Alter gegebenenfalls hinter den Text angefügt wird.
Und vielleicht noch die Terminsortierung in der Monatanzeige.

Im thread hat bisher ein Helmut (?) keinen Beitrag geleistet und eine "Terminsortierung in der Monatsanzeige" könnte ich zwar auch formeltechnisch realisieren, diese ist aber nicht notwendig, wenn sinnvollerweise bereits in der Datenerfassung die Sortierung vorgenommen wird  (weil dazu nur ein Mausklick ausreichend ist),  also in der Spalte H der ursprünglichen Datenstruktur von Thomas.