Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Kopieren einer Zählenwenns-Funktion
#1
Hallo zusammen,

ich bin seit heute neu in diesem Forum und sage mal "Hallo!" ...

Ich habe eine Frage bzgl. meiner Excel-Datei bzw. einer Zählenwenns-Funktion. Ich möchte Zählen wie oft ein Wert innerhalb eines Zeitraums vorkommt und benutze dazu die folgende Formel:

=ZÄHLENWENNS(E1:E4;">=01/01/2016";E1:E4;"<=31/03/2016")

Beispiel:

E1 = 01.01.2016
E2 = 15.01.2016
E3 = 22.02.2016
E4 = 07.03.2016
E5 = 05.04.2016
....
E14 = 31.12.2016

Resultat: 4

Das funktioniert auch!

Aber meine Liste hat einen Zeitraum von 01.01.2013 - 31.12.2016 und ich will die einzelnen Monate auswerten, also =ZÄHLENWENNS(E1:E4;">=01/01/2013";E1:E4;"<=31/01/2013") ... ich möchte aber nicht 48 mal die gleiche Formel per Drag & Drop & Datum anpassen einfügen sondern einfach kopieren und Excel nimmt je Zeile jeweils den Folgemonat. Ich schaffe es aber nicht :(

Hat jemand von Euch eine Idee?

Herzliche Grüße
MyExcel
Antworten Top
#2
Hallo,

wei wäre es mit so einer Auswertung:


Arbeitsblatt mit dem Namen 'Tabelle1'
 FGHI
1JahreQuartaledatumAnzahl von datum
22016Qrtl1Jan2
3  Feb1
4  Mrz1
5 Qrtl2Apr2
6 Qrtl4Dez1
7Gesamtergebnis  7

ZelleFormatWert
H2TT.MM.JJJJJan
H3TT.MM.JJJJFeb
H4TT.MM.JJJJMrz
H5TT.MM.JJJJApr
H6TT.MM.JJJJDez
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Das geht ohne Formeln mit einer Pivottatbelle. Such mal hier im Forum in den Workshops nach Pivottabelle.

Sonst könnten die Formeln so aussehen, je nachdem ob Du die Formel in der Spalte oder Zeile weiterführen möchtest:

Arbeitsblatt mit dem Namen 'Tabelle1'
 CDEFGHI
1datum      
201.01.2016      
315.01.2016 21120
422.02.2016 2    
507.03.2016 1    
605.04.2016 1    
706.04.2016 2    
831.12.2016 0    
ZelleFormatWert
C2TT.MM.JJJJ01.01.2016
C3TT.MM.JJJJ15.01.2016
C4TT.MM.JJJJ22.02.2016
C5TT.MM.JJJJ07.03.2016
C6TT.MM.JJJJ05.04.2016
C7TT.MM.JJJJ06.04.2016
C8TT.MM.JJJJ31.12.2016
ZelleFormel
E3=ZÄHLENWENNS($C$2:$C$8;">=01/"&SPALTE(A1)&"/2016";$C$2:$C$8;"<="&DATUM(2016;SPALTE(B1);1)-1)
F3=ZÄHLENWENNS($C$2:$C$8;">=01/"&SPALTE(B1)&"/2016";$C$2:$C$8;"<="&DATUM(2016;SPALTE(C1);1)-1)
G3=ZÄHLENWENNS($C$2:$C$8;">=01/"&SPALTE(C1)&"/2016";$C$2:$C$8;"<="&DATUM(2016;SPALTE(D1);1)-1)
H3=ZÄHLENWENNS($C$2:$C$8;">=01/"&SPALTE(D1)&"/2016";$C$2:$C$8;"<="&DATUM(2016;SPALTE(E1);1)-1)
I3=ZÄHLENWENNS($C$2:$C$8;">=01/"&SPALTE(E1)&"/2016";$C$2:$C$8;"<="&DATUM(2016;SPALTE(F1);1)-1)
E4=ZÄHLENWENNS($C$2:$C$8;">=01/"&ZEILE(A1)&"/2016";$C$2:$C$8;"<="&DATUM(2016;ZEILE(A2);1)-1)
E5=ZÄHLENWENNS($C$2:$C$8;">=01/"&ZEILE(A2)&"/2016";$C$2:$C$8;"<="&DATUM(2016;ZEILE(A3);1)-1)
E6=ZÄHLENWENNS($C$2:$C$8;">=01/"&ZEILE(A3)&"/2016";$C$2:$C$8;"<="&DATUM(2016;ZEILE(A4);1)-1)
E7=ZÄHLENWENNS($C$2:$C$8;">=01/"&ZEILE(A4)&"/2016";$C$2:$C$8;"<="&DATUM(2016;ZEILE(A5);1)-1)
E8=ZÄHLENWENNS($C$2:$C$8;">=01/"&ZEILE(A5)&"/2016";$C$2:$C$8;"<="&DATUM(2016;ZEILE(A6);1)-1)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß Atilla
Antworten Top
#3
Hallo,

oder so:


=ZÄHLENWENNS($E$1:$E$4;">="&DATUM(2016+KÜRZEN((ZEILE(A1)-1)/12;);REST(ZEILE(A1)-1;12)+1;1);$E$1:$E$4;"<="&DATUM(2016+KÜRZEN((ZEILE(A1)-1)/12;);REST(ZEILE(A1)-1;12)+2;0))

nach unten ziehen. Zählt ab dem 1.1.16 monatsweise!
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#4
Sensationell !!!!

Antwort 1 hat irgendwie nicht funktioniert aber Antwort 2 nach Anpassung auf die Gesamtliste von 2.700 Zeilen prima ...

Vielen Dank ... you made my day
MyExcel
Antworten Top
#5
Etwas kürzer als Bosko für ein Jahr (2016) und auch vor xl2007 laufend ...

=SUMMENPRODUKT(--(TEXT($E$1:$E$4;"JMM")=TEXT(2016&-ZEILE(A1)&-1;"JMM")))

... wobei seine Lösung möglicherweise etwas schneller sein könnte.

Seine Lösung kann man aber auch kürzen für fortlaufende Monate in die Folgejahre hinein auf:

=ZÄHLENWENNS($E$1:$E$4;">"&DATUM(2016;ZEILE(A1););$E$1:$E$4;"<"&DATUM(2016;ZEILE(A1)+1;1)) oder
=SUMMENPRODUKT(--(TEXT($E$1:$E$4;"JMM")=TEXT(DATUM(2016;ZEILE(A1);1);"JMM")))
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste