Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Summieren wenn MONAT gleich
#1
Bug 
Hallo,

ich habe eine Tabelle erstellt wo in Spalte A ab Zeile 3 Datumwerte errechnet werden per Matrixformel.
In Spalte B ab Zeile 3 werden Summen Errechnet per SUMMEWENN Formel.

In Spalte D soll jetz immer nur 1 mal der Monat und das Jahr aus allen Datum der Spalte A angezeigt werden.
Wenn dort eben steht 4.1.2019 und 7.1.2019 und 11.1.2019 und 1.2.2019 soll in Spalte D Zeile 3 stehen Januar / 2019 und Zeile 4 dann Februar / 2019 usw....
Hierfür fehlt mir komplett der ansatz... 


In Spalte E ab Zeile 3 sollen dann alle Beträge aus Spalte B ab Zeile 3 passend summiert werden zum Monat in Spalte A ab Zeile 3.....
mit folgender Formal klappt es soweit aber nur wenn die Zellen einen Wert enthalten, sind die Zellen leer (enthalten sie nur die Formel ) bekomme ich einen Fehler.

Formel Spalte E ab Zeile 3 : =SUMMENPRODUKT(($A$3:$A$20<>"")*(MONAT($A$3:$A$20)=1)*$B$3:$B$20)

Wie muss ich die Formel abändern das ich $A$20 vergrößern kann ohne eine Fehlermeldung zu erhalten ?


Formel A3 :  =INDEX(TAB!C4:C5000;VERGLEICH(WAHR;TAB!C4:C5000<>"";0))
Formeln ab A4 : {=WENNFEHLER(INDEX(TAB!$C$4:$C$5000;VERGLEICH(1;(ZÄHLENWENN(A$3:A3;TAB!C$4:C$5000)=0)*(TAB!C$4:C$5000<>"");0));"")}
Formeln für Spalte B : =WENN(A3="";"";SUMMEWENN(TAB!C:C;A3;TAB!G:G))

ich hoffe das versteht jemand, wie ich es erkläre..... :19:
Antworten Top
#2
Hi,

Zitat:ich hoffe das versteht jemand, wie ich es erkläre...

mit einer Beispieltabelle und händisch eingetragenem Wunschergebnis wär's deutlicher.  https://www.clever-excel-forum.de/thread-326.html
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Antworten Top
#3
Hallo Psycor,

folgende Formel in D2 (oder auch weiter unterhalb, nur nicht in D1):

Code:
=WENNFEHLER(AGGREGAT(15;6;A$4:A$99/(TEXT(A$4:A$99;"MMMM / JJJJ")+0<>D1)/(A$4:A$99<>"");1);"")

Dieser Zelle das benutzerdefinierte Zahlenformat:
Code:
MMMM / JJJJ

zuweisen und danach Formel ziehend nach unten kopieren.

Deine Formel in Spalte A ließen sich übrigens auch mit AGGREGAT() ermitteln ohne, dass ein Matrixformelabschluß notwendig wird.

[Edit:]

Ich hatte vergessen, Dir die Formellösung für Deine anschließend gewünschte Summierung noch aufzuzeigen.

Wenn Du in D2 begonnen hast die Monate ermitteln zu lassen, dann in E2:

Code:
=WENN(D2="";"";SUMMEWENNS(B:B;A:A;">="&D2;A:A;"<="&MONATSENDE(D2;0)))

und diese nach unten kopieren.
Gruß Werner
.. , - ...
[-] Folgende(r) 1 Nutzer sagt Danke an neopa für diesen Beitrag:
  • Psycor
Antworten Top
#4
Hallo,

für dein erstes Problem mit Spalte D einfach in Zelle D3 schreiben  =A3 
Formeln runter ziehen 
Komplette Spalte markieren-> Rechtsklick -> Zellen formatieren -> Benutzerdefiniert -> bei Typ schreibst du rein "MMMM JJJJ" ohne die Gänsefüßchen ;) 

für dein zweites Problem ist eine Beispieltabelle von Vorteil. 

Gruß Gimpi
Antworten Top
#5
hallo Neopa,

die Summierung in spalte E passt soweit, wenn ich die Datum von Hand eintrage.
Aber das ermitteln der Monate funktioniert so nicht, ich bekomme nun in allen Zeilen den Januar angezeigt.

Die datei kann ich nicht hochladen leider nur ein screenshot, hoffe das reicht aus.

Unter den Datum und den Summen geht es immer mit Formeln weiter die Zellen sind also nicht leer.

vielen lieben Dank !!!


Angehängte Dateien Thumbnail(s)
   

.xlsx   Mappe1.xlsx (Größe: 63,95 KB / Downloads: 7)
Antworten Top
#6
Hallo Psyor,

hab nun die Formeln für Deine eingestellte Datei angepasst sowie auch erweitert für die automatisierte Ermittlung der Gesamtsumme.
Beide Formeln ziehend nach unten kopieren.

Diese Formeln hätte ich jedoch an Deiner Stelle mir erspart, weil eine Pivotauswertung viel einfacher und schneller erstellt ist und auch bei Massendaten schneller auswertet und flexibler in der Ergebnisdarstellung gehandhabt werden kann.

Arbeitsblatt mit dem Namen 'Tabelle1'
ABCDE
2ZahllauftagSummeMonatGesamt
304.01.201910.638,01 €Januar / 201931.640,46 €
407.01.201939,20 €Februar / 201948.823,15 €
511.01.20197.306,63 €März / 2019120.402,59 €
618.01.20193.214,94 €April / 201955.773,87 €
725.01.201910.441,68 €Gesamt256.640,07 €
801.02.201914.132,27 €
908.02.201910.211,34 €
1015.02.201911.227,37 €
1122.02.201913.222,17 €
1224.02.201930,00 €
1301.03.201917.581,71 €
1408.03.201914.256,10 €
1515.03.201940.083,28 €
1622.03.201926.514,31 €
1729.03.201921.967,19 €
1805.04.201926.432,03 €
1912.04.201913.326,64 €
2019.04.201915.452,33 €
2126.04.2019562,87 €
22

ZelleFormel
D3=WENNFEHLER(WENN(MAX(A:A)-TAG(MAX(A:A))=WENN(ZEILE()>3;D2-TAG(D2);9);"Gesamt";AGGREGAT(15;6;A$3:A$99/(TEXT(A$3:A$99;"MMMM / JJJJ")+0>WENN(D2="Monat";0;D2))/(A$3:A$99<>"");1));"")
E3=WAHL(1+(D3="Gesamt")+(D3="")*2;SUMMEWENNS(B:B;A:A;">="&D3;A:A;"<="&MONATSENDE(D3;0));SUMME(E$1:E2);"")
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg
Gruß Werner
.. , - ...
[-] Folgende(r) 1 Nutzer sagt Danke an neopa für diesen Beitrag:
  • Psycor
Antworten Top
#7
vielen DANK nochmals !!!!

Pivot hab ich komplett keine Ahnung !

Die Tabelle ist Dynamisch, das heißt es wird dort täglich neues hinzugefügt und ich weiß nicht ob sowas dann per pivot funktioniert !

so mit Formeln läuft alles automatisch und das finde ich super !

MfG

:05:
Antworten Top
#8
Hi,

Zitat:Die Tabelle ist Dynamisch, das heißt es wird dort täglich neues hinzugefügt und ich weiß nicht ob sowas dann per pivot funktioniert !
das ist ja gerade die Stärke einer Pivottabelle. Sobald die Quelldaten sich verändern, kannst du mit einem Mausklick (auf einen Aktualisieren-Button) die neuen Daten integrieren.
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Antworten Top
#9
Hallo, ich mache das mit Power Query. Bei Bedarf, poste ich gern (d)eine BeispielDatei. Ohne Formeln {na ja vielleicht mit einer....}. Dynamisch. Praktisch. Gut.
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Antworten Top
#10
@WillWissen

Pivot hört sich gut an aber ist eben nicht automatisch sondern ich muss einen Knopf drücken, das ist zu viel für unsere Büro-Leute.
Danke sehr


@Jockel

Power Quer hab ich noch nie gehört! Macht dir keine Mühe die Formel Version von @neopa funktioniert sehr gut !
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste