Hi,
Deine Formel wird so kein Ergebnis bringen!
André hat Dir doch geschrieben, daß das Suchkriterium kein Bereich sein kann!
Ok, geht doch, das ist aber ncht korrekt.
Eigentlich sollte die so aufgebaut sein:
=SVERWEIS(Kriterium;zu durchsuchender Bereich;Wert aus wievielter Spalte des Bereichs;0)
Und Kriterium ist immer nur
eine Zelle.
Also muß sie so lauten:
=SVERWEIS(Ausscannen!$A2;$V$2:$AA$50;SPALTE(B2);0)
Diese dann nach unten ziehen.
Damit wird nach dem Begriff aus Ausscannen!A2 in Spalte V des Bereichs V2:AA50 gesucht und der Inhalt der 2. Spalte des Bereichs (also Spalte W) zurückgegeben, wenn es eine genaue Übereinstimmung gibt.
Wenn der Begriff aus Zelle Ausscannen!A2 nicht in V vorkommt, dann wird als Ergebnis eben der Fehler #NV (= Nicht Vorhanden) angezeigt. Wenn das nicht so sein soll, dann mußt Du eine Fehlerbehandlung einbauen.
Und hier die Formel angepasst für Deine Tabelle "Formeln":
=WENNFEHLER(SVERWEIS(Ausscannen!A2;$V$2:$AA$50;SPALTE(B2);0);"")
Damit gibt es aber dann Lücken, wenn der Suchbegriff aus Ausscannen Spalte A nicht in Spalte V vorkommt.
| Arbeitsblatt mit dem Namen 'Formeln' |
| N | O | P | Q | R | S | T | U |
| 1 | Menge | Barcode 1 | Menge | Barcode 2 | Menge | Barcode 3 | Menge | Barcode 4 |
| 2 | | | 0 | #NV | 0 | #NV | 0 | #NV |
| 3 | | | 0 | #NV | 0 | #NV | 0 | #NV |
| 4 | 3 | M01BlackAW | 1 | CT01.3BlackSF | 0 | 0 | 0 | 0 |
| 5 | | | 0 | #NV | 0 | #NV | 0 | #NV |
| 6 | 1 | M01RotAW | 1 | CT01RotSF | 0 | 0 | 0 | 0 |
| 7 | | | 0 | #NV | 0 | #NV | 0 | #NV |
| 8 | 2 | M01GrauAW | 1 | CT01.2GrauSF | 0 | 0 | 0 | 0 |
| 9 | 3 | M01BlackAW | 1 | CT01.3BlackSF | 0 | 0 | 0 | 0 |
| 10 | | | 0 | #NV | 0 | #NV | 0 | #NV |
| Zelle | Formel |
| N2 | =WENNFEHLER(SVERWEIS(Ausscannen!$A2;$V$2:$AA$50;SPALTE(B2);0);"") |
| O2 | =WENNFEHLER(SVERWEIS(Ausscannen!$A2;$V$2:$AA$50;SPALTE(C2);0);"") |
| P2 | =ZÄHLENWENN($C$2:$C$2399;Q2) |
| Q2 | =SVERWEIS(Ausscannen!$A2;$V$2:$AA$50;SPALTE(D2);0) |
| R2 | =ZÄHLENWENN($C$2:$C$2399;S2) |
| S2 | =SVERWEIS(Ausscannen!$A2;$V$2:$AA$50;SPALTE(E2);0) |
| T2 | =ZÄHLENWENN($C$2:$C$2399;U3) |
| U2 | =SVERWEIS(Ausscannen!$A2;$V$2:$AA$50;SPALTE(F2);0) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
