Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Index/Vergleich mit unterschiedlichen Vergleichstypen
#1
Hallo liebe clever-excel Community,

ich stehe momentan vor folgender Herausforderung:

Mir liegt eine Tabelle mit Produkten inkl. Produkteigenschaften vor.


Ich habe nun zusätzlich die Felder: Material, Produktart, Gewicht und Abmessung über der Tabellle angelegt, in denen ich die Produkteigenschaften eines neuen Produtes (nicht in der Tabelle enthalten) eingeben kann.
Excel soll mir nun automatisch die Artikelnummer eines vergleichbaren Produktes aus der Tabelle heraussuchen. Material und Produktart müssen hierbei genau mit dem neuen Produkt übereinstimmen.
Gewicht und Abmessung können gleich oder größer sein.

Zur Vereinfachung habe ich Material und Produktart (genaue Übereinstimmung notwendig) bereits in einer Hilfsspalte (1) zusammengefasst.
Auch für Gewicht und Abmessung (soll gleich oder größer sein) habe ich eine Hilfsspalte (2) angelegt.

Meine Formel lautet:

=INDEX(Spalte Artikelnummer;VERGLEICH(Gesuchter Wert Hilfsspalte 1&Gesuchter Wert Hilfsspalte 2;Werte Hilfsspalte 1&Werte Hilfsspalte 2;0))

Problem hierbei ist, dass ich nur einen Vergleichstyp für beide Spalten auswählen kann. Ich würde aber gerne den Vergleichstyp 0 (genaue Übereinstimmung) auf die erste Hilfsspalte anwenden und den Vergleichstyp -1 (größer als) auf Hilfsspalte 2 anwenden. Ist das irgendwie möglich?

Noch besser wäre natürlich eine Formel, die mir alle Artikelnummern von Produkten anzeigt, die das gleiche Material und die gleiche Produktart haben, sowie größer-gleiches Gewicht/Abmessungen. Hier habe ich aber wenig Hoffnung...


Für eure Hilfe wäre ich sehr dankbar!

MfG Office123
Antworten Top
#2
Bitte lade eine Beispieldatei hoch!
Eine Menge reden, aber nichts sagen können viele...
Antworten Top
#3
Hallo Frogger,

anbei ein Beispiel.

Aufgrund der geringen Datenmenge funktioniert das hier auch scheinbar ganz gut.

Optimal wäre, wenn mir Excel über eine Formel direkt Nr. 3, 5, 7 und 9 anzeigen würde. (Hilfsspalte 1 identisch, Hilfsspalte 2 ≥).

Ist das möglich?

Gruß Office123


Angehängte Dateien
.xlsx   Beispiel excel.xlsx (Größe: 13,36 KB / Downloads: 18)
Antworten Top
#4
Hallo,

ohne Hilfsspalten:
Code:
=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE($A$7:$A$15)/(($B$7:$B$15=$B$3)*($C$7:$C$15=$C$3)*($D$7:$D$15>=$D$3)*($E$7:$E$15>=$E$3));ZEILE(A1)));"")
Diese Formel kannst Du herunterziehen und bekommst dann nacheinander die Produkte angezeigt, die den Kriterien entsprechen.
Gruß
Michael
[-] Folgende(r) 1 Nutzer sagt Danke an Der Steuerfuzzi für diesen Beitrag:
  •
Antworten Top
#5
Hallöchen,

mal eine Frage und etwas Theorie.
Bedeutet das, dass Du z.B. eine oder mehrere Produktarten hast und davon dann die eine "größere" haben willst?

INDEX kann Dir neben einem konkreten Wert auch einen Bereich zurückgeben.
Eventuell wäre hier eine Lösung mit einem geschachtelten INDEX möglich. Zum einen ermittelst Du den Bereich mit dem festen Kriterium, dann holst DU per Vergleich daraus die Zeilennummer mit dem nächstgrößeren Wert. Beachte aber die notwendige Sortierung in Abhängigkeit des Vergleichsparameters.
Schaue mal hier:

Arbeitsblatt mit dem Namen 'Tabelle1'
ABCDEF
11SuchwortSuchwertParameterErgebnis
12C3,5A2-12,25
13B2,50#NV
14A2,251#NV
15A1,5

ZelleFormel
F12=INDEX(INDEX($A$10:$B$20;($A$10:$A$20="A"););VERGLEICH($D$12;INDEX($A$10:$B$20;($A$10:$A$20="A");2);E12);2)
F13=INDEX(INDEX($A$10:$B$20;($A$10:$A$20="A"););VERGLEICH($D$12;INDEX($A$10:$B$20;($A$10:$A$20="A");2);E13);2)
F14=INDEX(INDEX($A$10:$B$20;($A$10:$A$20="A"););VERGLEICH($D$12;INDEX($A$10:$B$20;($A$10:$A$20="A");2);E14);2)
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg
.      \\\|///      Hoffe, geholfen zu haben.
       ( ô ô )      Grüße, André aus G in T  
  ooO-(_)-Ooo    (Excel 97-2019+365)
Antworten Top
#6
Hallo und entschuldigt die verspätete Antwort,

das hat super funktioniert!

Vielen Dank für die Hilfe.

MfG Office123
Antworten Top
#7
Guten Tag,
 
jetzt habe ich auch leider schon direkt das nächste Problem.
 
Ich habe eine weitere Spalte (F) hinzugefügt, in der ebenfalls ein vorgegebener Wert hinterlegt wird. Der Wert im „Datenpool“ soll identisch mit diesem Wert sein.
 
Die Formel habe ich dementsprechend einfach um F ergänzt: =WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE($A$7:$A$15)/(($B$7:$B$15=$B$3)*($C$7:$C$15=$C$3)*($D$7:$D$15>=$D$3)*($E$7:$E$15>=$E$3))*($F$7:$F$15=$F$3);ZEILE(A1)));"")
 
Leider scheint irgendwas mit der Formel jedoch noch nicht ganz zu stimmen, da Excel mir lediglich eine Fehlermeldung ausgibt… habt ihr hier eventuell eine Lösung für mich?
 
Mich würde außerdem interessieren ob es möglich ist die >= Anteile der Formel in irgendeiner Weise einzugrenzen (z.B. nur Werte anzeigen, die um 20% Größer sind als der Ausgangswert).
 
Vielen Dank im Voraus und noch einen schönen Tag!
Antworten Top
#8
Da ist Dir vermutlich eine Klammer "verrutscht":
Code:
=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE($A$7:$A$15)/(($B$7:$B$15=$B$3)*($C$7:$C$15=$C$3)*($D$7:$D$15>=$D$3)*($E$7:$E$15>=$E$3)*($F$7:$F$15=$F$3));ZEILE(A1)));"")
Gruß
Michael
[-] Folgende(r) 1 Nutzer sagt Danke an Der Steuerfuzzi für diesen Beitrag:
  •
Antworten Top
#9
(13.09.2018, 13:07)Office123 schrieb: Mich würde außerdem interessieren ob es möglich ist die >= Anteile der Formel in irgendeiner Weise einzugrenzen (z.B. nur Werte anzeigen, die um 20% Größer sind als der Ausgangswert).
Code:
($D$7:$D$15>=1,2*$D$3)
Gruß
Michael
[-] Folgende(r) 1 Nutzer sagt Danke an Der Steuerfuzzi für diesen Beitrag:
  •
Antworten Top
#10
Funktioniert einwandfrei!
 
Vielen Dank noch einmal.
 
Freundliche Grüße
 
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste