Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

tabellenspalte Geschäftsjahr
#1
Hey Leute,

ich habe eine Tabelle mit einer Spalte in der Termine stehen.
Nun möchte ich diese Termine in einer neuen Spalte dem richtigen Geschäftsjahr zuweisen.

Das GJ geht jeweils von 01.04. - 31.03.

Der Termin 15.04.2018 wäre somit GJ19.
Der Termin 29.03.2018 wäre noch GJ18.

In der neuen Spalte sollte dann beim 15.04.2018 GJ19 stehen.

Ich habe folgendes:
=WENN(JAHR([@Termin]<2007)+MONAT([@Termin]>3);"GJ07";WENN(JAHR([@Termin]<2008)+MONAT([@Termin]<4);"GJ07";WENN(JAHR([@Termin]<2008)+MONAT([@Termin]>3);"GJ08";WENN(JAHR([@Termin]<2009)+MONAT([@Termin]<4);"GJ08";WENN(JAHR([@Termin]<2009)+MONAT([@Termin]>3);"GJ09";WENN(JAHR([@Termin]<2010)+MONAT([@Termin]<4);"GJ09";WENN(JAHR([@Termin]<2010)+MONAT([@Termin]>3);"GJ10";WENN(JAHR([@Termin]<2011)+MONAT([@Termin]<4);"GJ10";""))))))))

Das wirft mir aber bei jedem X-beliebigen Termin "GJ07" aus.

Hat jemand eine elegante Lösung dafür?
Antworten Top
#2
Hallo, das geht bestimmt einfacher, aber quick & dirty..:


Code:
="GJ"&RECHTS(JAHR(B14)+(B14>--(4&-JAHR(B14)));2)
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
[-] Folgende(r) 1 Nutzer sagt Danke an Jockel für diesen Beitrag:
  • StrammerMax
Antworten Top
#3
Perfekt - vielen Dank :)

Da wäre ich in 100 Jahren nicht drauf gekommen.
Antworten Top
#4
Hi,

oder so:

Arbeitsblatt mit dem Namen 'Auswertung'
KL
1631.03.17GJ16
1701.04.17GJ17
1831.03.18GJ17
1901.04.18GJ18
2031.03.19GJ18
2101.04.19GJ19

ZelleFormel
L16="GJ"&RECHTS(JAHR(EDATUM(K16;-3));2)
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Es wäre auch mit einer WENN-Formel gegangen, aber Deine Formel war vom Aufbau her schon völlig falsch. Hier mal eine korrigierte Fassung, eine falsche und eine richtige:


Arbeitsblatt mit dem Namen 'Tabelle1'
KLMN
2TerminGJSpalte1Spalte2
331.03.07GJ06GJ07GJ06
401.04.07GJ07GJ08GJ07
531.03.08GJ07GJ08GJ07
601.04.08GJ08GJ09GJ08
731.03.09GJ08GJ09GJ08
801.04.09GJ09GJ10GJ09

ZelleFormel
L3="GJ"&RECHTS(JAHR(EDATUM(K3;-3));2)
M3=WENN((JAHR([@Termin])<2007)*(MONAT([@Termin])>3);"GJ07";WENN((JAHR([@Termin])<2008)*(MONAT([@Termin])<4);"GJ07";WENN((JAHR([@Termin])<2008)*(MONAT([@Termin])>3);"GJ08";WENN((JAHR([@Termin])<2009)*(MONAT([@Termin])<4);"GJ08";WENN((JAHR([@Termin])<2009)*(MONAT([@Termin])>3);"GJ09";WENN((JAHR([@Termin])<2010)*(MONAT([@Termin])<4);"GJ09";WENN((JAHR([@Termin])<2010)*(MONAT([@Termin])>3);"GJ10";WENN((JAHR([@Termin])<2011)*(MONAT([@Termin])<4);"GJ10";""))))))))
N3=WENN((JAHR([@Termin])=2007)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2008)*(MONAT([@Termin])<4);"GJ07";WENN((JAHR([@Termin])=2008)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2009)*(MONAT([@Termin])<4);"GJ08";WENN((JAHR([@Termin])=2009)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2010)*(MONAT([@Termin])<4);"GJ09";WENN((JAHR([@Termin])=2010)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2011)*(MONAT([@Termin])<4);"GJ10";"GJ06"))))
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Dieser Term enthält schon mehrere Fehler:

WENN(JAHR([@Termin]<2007)+MONAT([@Termin]>3)
Richtig wäre das:
WENN((JAHR([@Termin])=2007)&(MONAT([@Termin])>3)
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
[-] Folgende(r) 1 Nutzer sagt Danke an BoskoBiati für diesen Beitrag:
  • StrammerMax
Antworten Top
#5
Hallo, oder so..:


Code:
="GJ"&RECHTS(JAHR(B14)+(MONAT(B14)>3);2)
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
[-] Folgende(r) 1 Nutzer sagt Danke an Jockel für diesen Beitrag:
  • StrammerMax
Antworten Top
#6
hallo

beide Formeln haben Flüchtigkeitsfehler, Jockels Formel trifft den Übergang am 1.4 nicht 
="GJ" & RECHTS(JAHR(A1) + (A1 >--(4 & -JAHR(A1)));2)

und Boskos GJ hinkt ein Jahr hinterher
="GJ" & RECHTS(JAHR(EDATUM(A1;-3)) +1;2)

meine Formel ist etwas nachvollziehbarer, ich würde mich selbst aber für Bosko's Lösung entscheiden
="GJ" & RECHTS(JAHR(A1) + (MONAT(A1)>3);2)
Willie
Antworten Top
#7
Hallo Willie,


Zitat:und Boskos GJ hinkt ein Jahr hinterher

halte ich aber sehr für ein Gerücht!

Der 31.3.17 gehört zum Geschäftsjahr 2016!

Und noch eine Variante:

Arbeitsblatt mit dem Namen 'Tabelle1'
KL
2TerminGJ
331.03.07GJ06

ZelleFormatWert
L3"GJ"006

ZelleFormel
L3=RECHTS(JAHR(EDATUM(K3;-3));2)*1
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#8
(31.08.2018, 10:30)Willie017 schrieb: hallo

...
meine Formel ist etwas nachvollziehbarer...

Hallo, komisch ich sehe deine Formel gar nicht... ... ich hatte zwischen zeitlich "verschlimmbessert"... Der TE wird sich sicher selber entscheiden können...
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Antworten Top
#9
Hi,

Formel von Willie korrigiert:


Code:
="GJ" & RECHTS(JAHR(A2)-(MONAT(A2)<4);2)
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#10
(31.08.2018, 10:40)BoskoBiati schrieb: Der 31.3.17 gehört zum Geschäftsjahr 2016!
Das ist nicht falsch, aber Ansichtssache. Aus dem OP geht folgendes hervor:
Zitat:Der Termin 15.04.2018 wäre somit GJ19.
Der Termin 29.03.2018 wäre noch GJ18.
Damit hinkt Deine Formel tatsächlich hinterher.
Gruß
Michael
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste