Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Kalkulation - Schwierige Formel zu erstellen
#1
Hallo zusammen,

ich habe eine alte Kalkulationsliste im Unternehmen erhalten und muss dort eine bestimmte Formel eingeben, die ich beschreiben kann aber nicht umgesetzt bekomme. Ich versuche euch das mal kurz zu erklären und würde mich über Lösungsvorschläge freuen. 


Die Kalkulation besteht aus vielen Produkten in einem Arbeitsblatt. Die Produkte durchleben mehrere Kalkulationsschritte bis am Ende der Listenpreis rauskommt. 
Die Produkte gibt es in verschiedenen Ausführungen und dementsprechend mit mehreren Bezeichnungen.
Zeile 1A = Produktname 
Zeile 1B= Bezeichnung (2HB etc.)

Ich muss jetzt bei den Listenpreise (Endpreis der Kalkulation) folgende Formel einbauen: 

Alle Listenpreise mit der Bezeichnung 2F oder 3F müssen 95€ günstiger sein als die Listenpreise mit der Bezeichnung 2HB oder 3HB und dies gilt für jedes Produkt welches in Spalte A steht. 
Da aber alle Produkte in A stehen, kann man nicht einfach eine grundlegenden Formel anwenden weil jedes Produkt einen anderen "Basispreis" hat.

So sieht es vereinfacht aus  

Spalte A | Spalte B

Produkt A | 2F         180€
Produkt A | 2HB       250€

Produkt B | 2F         280€
Produkt B | 2HB       300€


Ich hoffe es ist einigermaßen verständlich und danke euch für die Hilfe im Vorfeld
Antworten Top
#2
Hi Kelmo,

erstell' mal bitte eine (realistische) Beispieldatei mit erfundenen Werten - etwa 15 Datensätze sind ausreichend. http://www.clever-excel-forum.de/Thread-...ng-stellen Trage dazu bitte händisch ein paar Wunschergebnisse ein.
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Antworten Top
#3
Hallöchen,

hier mal ein Ansatz für 2F und 2HB. Du kannst die Daten per Formel in eine zusätzliche Spalte übernehmen und anschließend mittels Kopieren und Inhalte Einfügen - Werte in die Spalte C und D dann löschen.

Arbeitsblatt mit dem Namen 'Tabelle1'
ABCD
1Produkt A2F180180
2Produkt A2HB85
3Produkt B3F
4Produkt B3HB

ZelleFormel
D1=WENN(B1="2HB";SUMMENPRODUKT(($A$1:$A$4=A1)*($B$1:$B$4="2F")*$C$1:$C$4)-95;C1)
D2=WENN(B2="2HB";SUMMENPRODUKT(($A$1:$A$4=A2)*($B$1:$B$4="2F")*$C$1:$C$4)-95;C2)
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg


Wäre das so ein gangbarer Weg? Natürlich dann anders herum, 2F soll ja kleiner sein Smile. Also z.B. so:
=WENN(RECHTS(B1;1)="F";SUMMENPRODUKT(($A$1:$A$4=A1)*(RECHTS($B$1:$B$4;2)="HB")*$C$1:$C$4)-95;C1)
.      \\\|///      Hoffe, geholfen zu haben.
       ( ô ô )      Grüße, André aus G in T  
  ooO-(_)-Ooo    (Excel 97-2019+365)
Antworten Top
#4
Hi,

bevor ich mir da Gedanken mache;

welcher Preis ist die Grundlage, F oder H?
Wenn die Differenz 95€ sein soll, was sollen denn Deine Zahlen?
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#5
Arbeitsblatt mit dem Namen 'Tabelle1'
ABCD
1Produkt A2F180155
2Produkt A2HB250250
3Produkt B3F280205
4Produkt B3HB300300

ZelleFormel
D1=WENN(RECHTS(B1;1)="F";SUMMENPRODUKT(($A$1:$A$4=A1)*(RECHTS($B$1:$B$4;2)="HB")*$C$1:$C$4)-95;C1)
D2=WENN(RECHTS(B2;1)="F";SUMMENPRODUKT(($A$1:$A$4=A2)*(RECHTS($B$1:$B$4;2)="HB")*$C$1:$C$4)-95;C2)
D3=WENN(RECHTS(B3;1)="F";SUMMENPRODUKT(($A$1:$A$4=A3)*(RECHTS($B$1:$B$4;2)="HB")*$C$1:$C$4)-95;C3)
D4=WENN(RECHTS(B4;1)="F";SUMMENPRODUKT(($A$1:$A$4=A4)*(RECHTS($B$1:$B$4;2)="HB")*$C$1:$C$4)-95;C4)
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg
.      \\\|///      Hoffe, geholfen zu haben.
       ( ô ô )      Grüße, André aus G in T  
  ooO-(_)-Ooo    (Excel 97-2019+365)
Antworten Top
#6
Hi,

da immer noch nicht feststeht, welcher Preis der Basispreis ist, hier mal zwei einfachere Varianten:

Arbeitsblatt mit dem Namen 'Tabelle1'
ABCDE
1Produkt A2F180180155
2Produkt A2HB250275250
3Produkt B3F280280205
4Produkt B3HB300375300

ZelleFormel
D1=WENN(RECHTS(B1;1)="F";C1;SVERWEIS(LINKS(B1;1)&"F*";B:C;2;0)+95)
E1=WENN(RECHTS(B1;2)="HB";C1;SVERWEIS(LINKS(B1;1)&"H*";B:C;2;0)-95)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#7
Moin Edgar,

die HB's sind die Basispreise, Zitat:
Alle Listenpreise mit der Bezeichnung 2F oder 3F müssen 95€ günstiger sein als die Listenpreise mit der Bezeichnung 2HB oder 3HB
Dass in der Frage bei den F's schon was drin steht ist eher irreführend Sad
.      \\\|///      Hoffe, geholfen zu haben.
       ( ô ô )      Grüße, André aus G in T  
  ooO-(_)-Ooo    (Excel 97-2019+365)
Antworten Top
#8
Hi,

bin gestern Abend nicht fertig geworden. Hier noch zwei Varianten:

Arbeitsblatt mit dem Namen 'Tabelle1'
ABCDE
1Produkt A2F180155155
2Produkt A2HB250250250
3Produkt B3F280205205
4Produkt B3HB300300300

ZelleFormel
D1=WENN(RECHTS(B1;1)="F";INDEX(C:C;AGGREGAT(15;6;ZEILE(A:A)/(A:A=A1)/(B:B=WECHSELN(B1;"F";"HB"));1))-95;C1)
E1=WENN(RECHTS(B1;1)="F";SUMMEWENNS(C:C;A:A;A1;B:B;"<>"&B1;B:B;LINKS(B1;1)&"*")-95;C1)
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste