SUMMENPRODUKT()-summieren nach Bedingungen / war:Gaaaanz kompliziert...

[goekeralf]

Hi Excel-Chefs,

folgende Herausforderung:

Tabelle 1:
In Spalte A stehen untereinander die Wochentage, d.h. A2: Montag, A3: Dienstag. In Zeile 1 stehen verschiedene Bezeichnungen, also B1: Blau, C1: Grün, D1: Gelb. Jetzt trage ich Montag unter Blau eine 3 ein, unter Grün eine 2 und unter Gelb eine 6.

Jetzt kommt's aber: Jede Farbe hat einen Wert, sagen wir Blau = 5€, Grün = 7€ und Gelb = 9€. Diese Werte stehen in Tabelle 2 als Matrix (Spalte A: Farben, Spalte B: Werte).

Wie summiere ich nun in Abhängigkeit der eingetragenen Anzahl die Tageswerte? Also die Summe z.B. in Zelle E2 unter Berücksichtigung der verschiedenen Preise für die Farben?

Mein Hirn ist schon weich...

Danke vorab für jegliche Hilfe!

Ralf

[steve1da]

Hola,

ein toller Betreff.

Erwartest du 83 als Ergebnis?

Gruß,
steve1da

[Frogger1986]

Schau die mal die Funktion Summewenn() an...

[goekeralf]

Hallo liebe Experten,

das mit dem Betreff geht auch besser, man sehe mir das nach...

Mit SUMMEWENN komme ich nicht zurecht, weil ich ja in der Spaltenüberschrift das Kriterium habe (die Farbe), in der anderen Tabelle aber die Zuordnung der Farbe zum Preis und die Summe ja in der zweiten Zeile ziehe...
Sorry wenn ich mich blöd anstelle, aber der Tag war lang....

Ralf

[schauan]

Hallöchen,

Wenn Du z.B. in B1 mal die Farbe wechselst, neue hinzukommen usw. ist als alternative Lösung sicher auch per SVERWEIS der richtige Multiplikator ermittelbar.
=B2*SVERWEIS($B$1;Tabelle2!$A$2:$B$10;2;FALSCH)+D2*…

Falls sich die Bezüge mit den Farben nicht ändern kannst Du auch ohne SUMMEWENN oder SVERWEIS rechnen.
z.B.
=B2*Tabelle2!$B$2+C2*Tabelle2!$B$3+D2*Tabelle2!$B$4
oder eben die SUMMEWENN von Frogger oder ...

[WillWissen]

Hallo Ralf,

Mit SUMMEWENN komme ich nicht zurecht,[...]

probier's mal so:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G
1	Tage	blau	rot	grün	gelb	Tagessumme	Tagessumme
2	Montag	3	3	1	4	89	89
3	Dienstag	5	7	5	7	196	196
4	Mittwoch	7	9	12	11	327	327
5	Donnerstag	9	6	4	2	145	145
6	Freitag	11	5	3	1	128	128
7	Samstag	13	1	2	3	123	123
8	Sonntag	15	1	3	5	164	164

Zelle	Format	Wert
B1	"blau"	5
C1	"rot"	7
D1	"grün"	9
E1	"gelb"	11

Zelle	Formel
F2	=SUMMENPRODUKT((B2:E2)*($B$1:$E$1))
G2	{=SUMME((B2:E2)*($B$1:$E$1))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Mit dieser Methode sparst du dir eine separate Tabelle. Achte auf die Formatierung!

[BoskoBiati]

Hi,


Geht auch so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	E	F	G	H	I	J	K
10	Montag		blau			rot	1
11	Dienstag		rot			blau	2
12	Montag		grün			grün	3
13			5

Zelle	Formel
G13	=SUMMENPRODUKT((E10:E12="Montag")*VERWEIS(G10:G12;{"rot";"blau";"grün"};{1;2;3}))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hola,
...
Erwartest du 83 als Ergebnis?

Gruß,
steve1da

Hallo, der TE hat ja nicht geantwortet... Ich käme auch auf 83. MMULT() sei dank... Es gibt ja eine eindeutige Vorgabe.

Arbeitsblatt mit dem Namen 'Blatt2'
	A	B
1	Farbe	Wert
2	Blau	5
3	Grün	7
4	Gelb	9

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Blatt1'
	A	B	C	D	E
1		Blau	Grün	Gelb	Erg.
2	Montag	3	2	6	83
3	Dienstag	6	5	4	101

Zelle	Formel
E2	=MMULT(B2:D2;Blatt2!$B$2:$B$4)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo Ralf,
probier's mal so:
...

Hallo Günter, wenn du INDEX() in Verbindung mit SUMME() verwendest, braucht's kein SUMMENPRODUKT() und kein CSE-Abschluss bei deiner SUMME()-Formel ...

[Jockel]

Hallo, habe meine Formel nochmal überdacht, da fehlte ja noch die Abhägigkeit zur Farbe.... Nun also..:

PHP-Code:

=SUMME(MMULT(($B$1:$D$1=Blatt2!$A$2:$A$4)*B2:D2;Blatt2!$B$2:$B$4))