Clever-Excel-Forum

Guten Abend,

ich möchte gerne Daten abgleichen, bin gerade aber ziemlich am verzweifeln. Ich erkläre meine Problematik mal an einen Beispiel. Mal angenommen man hat ein paar Artikel:

Apfel----01.01.2016
Apfel----15.01.2016
Birne----01.01.2016
Birne----03.03.2016

So nun soll Excel alle Artikel die den selben Namen aufweisen und im gleichen Monat liegen mit einer Zahl deklarieren. Hierbei soll erreicht das z.B beim Apfel eine 0 und eine 1 ausgeschrieben wird:

Apfel----01.01.2016---------0
Apfel----15.01.2016---------1
Birne----01.01.2016---------1
Birne----03.03.2016---------1


0 heißt in diesen Fall das der Artikel gleich ist und im selben Monat liegt. 1 bedeutet das der Artikel mit den nachfolgenden Artikel entweder nicht identisch ist oder der Monat sich in einen anderen Monat befindet.

Ich habe mich schon mal ein bisschen versucht, meine Problematik besteht darin erstmal die Artikel als identisch zu deklarieren ich habe es mit der Funktion "identisch" probiert, doch leider will das nicht so recht klappen. Des Weiteren habe ich versucht bei den Datumangaben Excel zusagen die Tage dürfen höchstens 30 Tage auseinander liegen. Doch eigtl. ist diese Definition ja Falsch ich möchte nur jeweils immer einen Monat betrachten, weil sonst packt er mir auch die Artikel zusammen die zwar nur 15 Tage auseinander liegen, sich aber in verschiedenen Monaten befinden.


[attachment=11148]


Mit freundlichen Grüßen
Morgän

Hallo,

reicht das so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1						Ziel
2	Apfel	01.01.2016	0			0	0
3	Apfel	15.01.2016	0			0	0
4	Apfel	18.01.2016	1			1	1
5	Birne	03.03.2016	1			0	0
6	Birne	27.03.2016	1			1	1
7	Birne	20.04.2016	1			1	1
8	Birne	27.11.2016	1			1	1

Zelle	Formel
G2	=ABS((A2=A3)*(MONAT(B2)=MONAT(B3))*(JAHR(B2)=JAHR(B3))-1)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Das ist unfair.

Apfel in A2 ist mit Apfel in A4 nicht identisch?


Um aber auf Dein Ergebnis zu kommen, habe ich sie identisch gemacht.

Hi,

so:

Tabelle1

	A	B	C	D	E	F
1						Ziel
2	Apfel	01.01.2016	0	0		0
3	Apfel	15.01.2016	1	0		0
4	Apfel	18.01.2016	1	1		1
5	Birne	03.03.2016	1	0		0
6	Birne	27.03.2016	1	1		1
7	Birne	20.04.2016	1	1		1
8	Birne	27.11.2016	1	1		1

Formeln der Tabelle

Zelle Formel D2 =UND(A2<>A3;MONAT(B2)<>MONAT(B3))*1

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

heje excelfreunde,

Morgän, siehe (deine) tabelle im anhang...

Vielen Dank für eure Lösungsvorschläge  :23:

@atilla: Zu deiner Frage: Apfel in A2 ist mit Apfel in A4 nicht identisch?

Ich ziele ein bisschen auf Bündelung ab, sprich die Mindestbestellung soll 1 lauten (anstatt 3 mal im Monat zu bestellen), sofern es im gleichen Monat vorkommt.

Mit freundlichen Grüßen
Morgän

Moin,

Zitat:@atilla: Zu deiner Frage: Apfel in A2 ist mit Apfel in A4 nicht identisch?

gib doch mal in B2 die Formel
ein und ziehe sie bis zum letzen Apfel. Wenn du die Ergebnisse siehst, weißt du bestimmt, was Atilla gemeint hat.  :32:

Hi,

hier noch ein paar Varianten, bei denen in Spalte C&D die Daten wild durcheinander vorkommen können! Die übrigen Varianten funktionieren nur bei sortierten Listen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H
1			letzter Treffer	letzter Treffer	1.Treffer	1.Treffer		Ziel
2	Apfel	01.01.2016	0	0	1	1	0	0
3	Apfel	15.01.2016	0	0	0	0	0	0
4	Apfel	18.01.2016	1	1	0	0	1	1
5	Birne	03.03.2016	0	0	1	1	0	0
6	Birne	27.03.2016	1	1	0	0	1	1
7	Birne	20.04.2016	1	1	1	1	1	1
8	Birne	27.11.2016	1	1	1	1	1	1

Zelle	Formel
C2	=(SUMMENPRODUKT(($A$2:A2=A2)*(MONAT($B$2:B2)=MONAT(B2)))=SUMMENPRODUKT(($A$2:$A$200=A2)*(MONAT($B$2:$B$200)=MONAT(B2))))*1
D2	=(ZÄHLENWENNS($A$2:A2;A2;$B$2:B2;">"&B2-TAG(B2);$B$2:B2;"<="&MONATSENDE(B2;0))=ZÄHLENWENNS($A$2:$A$200;A2;$B$2:$B$200;">"&B2-TAG(B2);$B$2:$B$200;"<="&MONATSENDE(B2;0)))*1
E2	=(SUMMENPRODUKT(($A$2:A2=A2)*(MONAT($B$2:B2)=MONAT(B2)))=1)*1
F2	=(ZÄHLENWENNS($A$2:A2;A2;$B$2:B2;">"&B2-TAG(B2);$B$2:B2;"<="&MONATSENDE(B2;0))=1)*1
G2	=(A2<>A3)*(MONAT(B2)<>MONAT(B3))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H
1			letzter Treffer	letzter Treffer	1.Treffer	1.Treffer		Ziel
2	Apfel	01.01.2016	0	0	1	1	0	0
3	Apfel	15.01.2016	0	0	0	0	0	0
4	Birne	16.01.2016	1	1	1	1	0	0
5	Apfel	18.01.2016	1	1	0	0	0	1
6	Apfel	03.03.2016	1	1	1	1	0	1
7	Birne	27.03.2016	1	1	1	1	0	0
8	Birne	29.03.2016	1	1	1	1	1	1
9	Birne	27.11.2016	1	1	1	1	1	1

Zelle	Formel
C2	=(SUMMENPRODUKT(($A$2:A2=A2)*(MONAT($B$2:B2)=MONAT(B2)))=SUMMENPRODUKT(($A$2:$A$201=A2)*(MONAT($B$2:$B$201)=MONAT(B2))))*1
D2	=(ZÄHLENWENNS($A$2:A2;A2;$B$2:B2;">"&B2-TAG(B2);$B$2:B2;"<="&MONATSENDE(B2;0))=ZÄHLENWENNS($A$2:$A$201;A2;$B$2:$B$201;">"&B2-TAG(B2);$B$2:$B$201;"<="&MONATSENDE(B2;0)))*1
E2	=(SUMMENPRODUKT(($A$2:A2=A2)*(MONAT($B$2:B2)=MONAT(B2)))=1)*1
F2	=(ZÄHLENWENNS($A$2:A2;A2;$B$2:B2;">"&B2-TAG(B2);$B$2:B2;"<="&MONATSENDE(B2;0))=1)*1
G2	=(A2<>A3)*(MONAT(B2)<>MONAT(B3))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg