Clever-Excel-Forum

Hallo und schönen Sonntag,

ich komme mit einer bestimmten SUMMEWENNS-Konstellation nicht klar. Aus einer Kontenkontrolle will ich offene Kartenzahlungen addieren. Dazu lese ich als Kriterium jeweils "Visa" oder "EC" mit Asterisken aus.

Tabelle2

	A	B	C	D	E
1	Text	Betrag	Buchungstag	Kartenz.
2	Überweisung A	100,00 €	01.04.2017	150,00 €	nur EC alle
3	Visa Rewe	50,00 €		80,00 €	EC offen
4	EC Edeka	70,00 €	03.04.2017
5	Überweisung B	200,00 €		0,00 €	beide Arten
6	Visa Markthalle	150,00 €		0,00 €	beide Arten offen
7	EC Aldi	80,00 €

Formeln der Tabelle

Zelle Formel D2 =SUMMEWENN(A:A;"*EC*";B:B) D3 =SUMMEWENNS(B:B;A:A;"*EC*";C:C;"") D5 =SUMMEWENNS(B:B;A:A;"*EC*";A:A;"*Visa*") D6 =SUMMEWENNS(B:B;A:A;"*EC*";A:A;"*Visa*";C:C;"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Sowohl die SUMMEWENN-Formal als auch die SUMMEWENNS-Formel für eine einzelne Kartenart funktionieren. Sobald ich beide Karten angebe, bekomme ich Ergebnis 0.

In mir keimt der Verdacht, dass SUMMEWENNS nicht mit zwei Asterisken klar kommt, gefunden habe ich bei der sonst so gesprächigen Tante Gugl allerdings nichts.

Hallo Günter,

SUMMEWENNS() kann mE nur UND-Beziehungen auswerten. Du suchst aber eine ODER-Beziehung.

Dazu nutze ich SUMMENPRODUKT(), z.B. so:

=SUMMENPRODUKT(B2:B99*(ISTZAHL(SUCHEN("EC";A2:A99))+ISTZAHL(SUCHEN("Visa";A2:A99)))*(C2:C99=""))

Hallo Werner,

vielen Dank für deine Erklärung. Damit ist mir klar, warum das so nicht funktionieren konnte. Mit deinem SUMMENPRODUKT-Vorschlag geht es natürlich einwandfrei; eine  andere Lösung wäre in dem Fall auch

Hallo

Natürlich geht das auch mit SUMMEWENNS().

=SUMME(SUMMEWENNS(B:B;A:A;{"*EC*";"*Visa*"};C:C;"")) oder flexibler
=SUMME(SUMMEWENNS(B:B;A:A;"*"&Liste&"*";C:C;"")) mit Liste als Bereich

(geht mit SUMMEWENN ohne S übrigens nicht, es sei denn, mein Excel hakt grad)

Hallo Detlef, hallo Lupo,

auch euch beiden herzlichen Dank.

Mir ist allerdings nicht 100%ig klar (trotz Formelauswertung und Auswertung mit F9), wie der Ausdruck mit der geschweiften Klammer arbeitet. Ich kann zwar sehen, dass durch die Umklammerung mit SUMME die dort zugehörigen Werte addiert werden - das Zusammenspiel mit SUMMEWENNS kann ich leider nicht erkennen.

@Lupo

Zitat:(geht mit SUMMEWENN ohne S übrigens nicht, es sei denn, mein Excel hakt grad)

dein XL hakt nicht :32:, sobald (wunschgemäß) nur die Werte der nichtgebuchten Datensätze addiert werden sollen. Es geht mit SUMMEWENN allerdings, wenn einfach alle Werte der Karten addiert werden ohne weitere Einschränkung. Übrigens, dein Vorschlag mit der Liste ist prima - ich benutze solche Listen gerne, wenn noch mehr Auswahlkriterien zur Verfügung stehen.

Hallo Günter, Detlef & lupo1,

natürlich ist hier SUMME(SUMMEWENNS()) eine intelligentere Lösung als mein Vorschlag mit SUMMENPRODUKT().
Mit etwas mehr Nachdenken, hätte ich diese wohl auch vorschlagen sollen.
Aber fixiert ist so oder so, dass SUMMEWENNS() ohne eine weitere Funktion keine ODER-Beziehung lösen kann.

(09.04.2017, 11:02)WillWissen schrieb: [ -> ]Mir ist allerdings nicht 100%ig klar (trotz Formelauswertung und Auswertung mit F9), wie der Ausdruck mit der geschweiften Klammer arbeitet. Ich kann zwar sehen, dass durch die Umklammerung mit SUMME die dort zugehörigen Werte addiert werden - das Zusammenspiel mit SUMMEWENNS kann ich leider nicht erkennen.

SUMMEWENNS() arbeitet hier mit den Kriterien als Array-Konstante oder alternativ als Zellbezug (siehe Lupo).
Damit ist es eine Array-Formel und Excel rechnet zwei SUMMEWENNS()-Formeln aus die dann mit SUMME() addiert werden.

Hi Detlef,

und wieder ist ein Stückchen Unklarheit beseitigt. Vielen Dank.