[attachment=10493]Hallo zusammen,
ich brauche dringend eure Hilfe.
Ich habe eine Kundenkartei angelegt, welche zu Zwecken der Archivierung dienen soll, um einmal den Ordner entsprechend zu finden, in dem die Unterlagen abgeheftet sind.
Nun habe ich das Problem, das beim SVerweis immer nur der erste Treffer angezeigt wird, ich habe jedoch einige Kunden mit gleichem Nachnamen
Wie könnte ich ein Dropdown o.ä. in den SVerweis einbauen, damit ich den Vornamen anwählen kann, der dann infrage käme (wie in meiner Beispieldatei.... bei Mustermann eben nur Max oder Brigitte zur Auswahl stehen)
Ich brüte nun schon seit Tagen und finde keine Lösung, da ich absoluter Anfänger bin.
Im Voraus vielen Dank und lieben Gruß
Tropea
Hallo,
da würde es Sinn machen mit eindeutigen systematischen Kundennummern zu arbeiten. Eine Kundennummer ist genau einem Kunden zugeordnet.
Das würde auch eventuelle spätere Auswertungen vereinfachen.
Die Kundennummer kann dann im Sverweis als Suchkriterium verwendet werden.
Gruß
sturmrm
Vielen Dank für den Vorschlag, das Problem ist nur, dass es schwierig wird wenn der Kunde anruft und ja nur seinen Namen kennt und nicht seine Kundennummer .
Wird mir aber nichts anderes übrig bleiben als dies zutun, dachte nur es gibt so eine Funktion, die das vereinfacht.
Hi,
was hältst du von diesem Vorschlag?
Tabelle1 | A | B | C | D | E | F | G | H |
5 | Name | Mustermann, Brigitte | | | | | | |
6 | Ordner | 4 | | | | | | |
7 | Projekt | Anbau | | | | | | |
8 | Ort | Musterwitz | | | | | | |
9 | | | | | | | | |
10 | | | | | | | | |
11 | Name | Vorname | Hilfsspalte | Ort | PLZ | Straße | Projekt | Ordner |
12 | Mustermann | Max | Mustermann, Max | Musterhausen | 10001 | Mustergasse 4 | Neubau | 7 |
13 | Mustermann | Brigitte | Mustermann, Brigitte | Musterwitz | 25003 | Musterstr. 10 | Anbau | 4 |
14 | Schulz | Henri | Schulz, Henri | Neuhofen | 81100 | Hoftal 5 | MFH | 3 |
15 | Müller | Hans | Müller, Hans | Neuss | 44001 | xgasse | EFH | 5 |
16 | Müller | Rudolf | Müller, Rudolf | Berlin | 11111 | ystr. | MFH | 8 |
Formeln der Tabelle |
Zelle | Formel | B6 | =SVERWEIS($B$5;$C$12:$H$207;6;0) | B7 | =SVERWEIS($B$5;$C$12:$H$207;5;0) | B8 | =SVERWEIS($B$5;$C$12:$H$207;2;0) | C12 | =A12&","&" "&B12 |
|
Datengültigkeit der Tabelle |
Zelle | Zulassen | Daten | Eingabe 1 | Eingabe 2 | B5 | Liste | | =$C$12:$C$16 | |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Die Hilfsspalte blendest du einfach aus.
Hallöchen,
so geht es auch nur mit den Vornamen. Ich habe dazu in Spalte I ein paar "Hilfszellen" genutzt, kannst Du auch anderswo unterbringen. Die Formel in I1 einfach eingeben und runterziehen, soweit wie nötig. Dann noch den benannten Bereich definieren und die Gültigkeit in B6 ...
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | I |
1 | | Kundenkartei | Max |
2 | | | Brigitte |
3 | | | |
4 | | | |
5 | Name | Mustermann | |
6 | Vorname | Brigitte | |
7 | Ordner | 7 | |
8 | Projekt | Neubau | |
9 | Ort | Musterhausen | |
Name | Bezug |
ListeVN | =BEREICH.VERSCHIEBEN(Tabelle1!$I$1;;;ZÄHLENWENN(Tabelle1!$I:$I;"?*")) |
Zelle | Formel |
I1 | {=WENNFEHLER(INDEX(B$1:B$99;KKLEINSTE(WENN((A$1:A$99=$B$5);ZEILE($1:$99));ZEILE(A1)));"")} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Zelle | Gültigkeitstyp | Operator | Wert1 | Wert2 |
B5 | Liste | | =$A$13:$A$17 | |
B6 | Liste | | =ListeVN | |
Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg |
Hi André,
da auch du mit Hilfszellen arbeitest, würde ich dann aber eher meine Lösung vorziehen als die höchst volatile BEREICH.VERSCHIEBEN-Fkt. und die ressourcenfressende Matrixformel. Mag zwar bei so einer kleinen Datei nicht ins Gewicht fallen; sollte der Fragesteller allerdings noch ein paar andere Mappen offen haben mit z.B. bedingter Formatierung, HEUTE() usw., kann das schon einiges ausmachen (da erzähle ich einem alten Fuchs, wie dir, nichts Neues).
Hallo zusammen,
ich hätte diesen Vorschlag:
das ist die Kundentabelle:
Arbeitsblatt mit dem Namen 'Kunden' |
| A | B | C | D | E | F | G |
1 | Name | Vorname | Ort | PLZ | Straße | Projekt | Ordner |
2 | Mustermann | Max | Musterhausen | 10001 | Mustergasse 4 | Neubau | 7 |
3 | Mustermann | Brigitte | Musterwitz | 25003 | Musterstr. 10 | Anbau | 4 |
4 | Schulz | Henri | Neuhofen | 81100 | Hoftal 5 | MFH | 3 |
5 | Müller | Hans | Neuss | 44001 | xgasse | EFH | 5 |
6 | Müller | Rudolf | Berlin | 11111 | ystr. | MFH | 8 |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Und das ist die Tabelle zum Suchen:
Arbeitsblatt mit dem Namen 'Suche' |
| A | B | C | D | E | F | G |
1 | | | | | | | |
2 | Name eingeben | Müller | <-Gelbe Zelle Eingabe für Namen | | | | |
3 | | | | | | | |
4 | Name | Vorname | Ort | PLZ | Straße | Projekt | Ordner |
5 | Müller | Hans | Neuss | 44001 | xgasse | EFH | 5 |
6 | Müller | Rudolf | Berlin | 11111 | ystr. | MFH | 8 |
7 | | | | | | | |
8 | | | | | | | |
9 | | | | | | | |
10 | | | | | | | |
Zelle | Formel |
A5 | {=WENNFEHLER(INDEX(Kunden!$A$1:$G$99;KKLEINSTE(WENN((Kunden!$A$1:$A$99=$B$2);ZEILE($1:$99));ZEILE($A1));SPALTE());"")} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Der Name muss aber exakt eingegeben werden.
Man könnte aus Andres Vorschlag statt der Namenseingabe auch Datengültigkeitsliste dort einbauen und dann aus der Liste einen Namen auswählen.
Aber statt BereichVerschieben würde ich Index(Vergleich()) nehmen.