Clever-Excel-Forum - (Wenn-)Formel dynamischer gestalten und evtl. kürzen

Hallo liebe Community,

bei meinem Problem geht es mir vor allem um die Möglichkeit, die bereits funktionierende Formel dynamischer zu gestalten und nach Möglichkeit auch verkürzt darzustellen. Im Anhang habe ich alle relevanten Teile angehängt. Grundsätzlich geht es darum, dass an jedem Ferientag im Register "Jahr", Spalte B (ab Zeile 6) das Kürzel "f" steht. Später möchte ich das auch noch mit dem gleichen Kürzel für die Feiertage einbauen.

Wie sich schnell erkennen lässt, sind zum Beispiel die Herbstferien nicht drin, da mir erst vor kurzem aufgefallen ist, dass ich die vergessen hatte. Daher ist der dynamische Teil unter anderem für mich interessant Smile

Hier ist die Formel um die es geht:

Code:
=WENN(ODER(UND([@Tage]>=Set!$Q$4;[@Tage]<Set!$R$4);UND([@Tage]>=Set!$Q$5;[@Tage]<Set!$R$5);UND([@Tage]>=Set!$Q$6;[@Tage]<Set!$R$6);UND([@Tage]>=Set!$Q$7;[@Tage]<Set!$R$7);UND([@Tage]>=Set!$Q$8;[@Tage]<Set!$R$8);UND([@Tage]>=Set!$Q$9;[@Tage]<Set!$R$9);UND([@Tage]>=Set!$Q$10;[@Tage]<Set!$R$10);UND([@Tage]>=Set!$Q$12;[@Tage]<Set!$R$12););"f";"")

Ich hoffe ich konnte mein Anliegen gut erklären und ihr könnt mir helfen!

Vielen Dank schon Mal und schöne Grüße,
loxer Smile

Hola,

Code:
=WENN(SUMMENPRODUKT((Set!$Q$4:$Q$12<=A6)*(Set!$R$4:$R$12>A6));"f";"")

Gruß,
steve1da

Hi,

(16.03.2017, 11:01)loxer schrieb: [ -> ]Ich hoffe ich konnte mein Anliegen gut erklären und ihr könnt mir helfen!

die Formel ist schon sehr lang und wird mit weiteren Ferien und den Feiertagen noch viiieeel länger.

Hier habe ich Dir einen Kalender mit Ferien und Feiertagen, der in Gemeinschaftsarbeit im Forum erzeugt wurde, schaue Dir mal an, wie das dort gemacht ist.
[attachment=10257]

Hi,

(16.03.2017, 11:06)steve1da schrieb: [ -> ]
Code:
=WENN(SUMMENPRODUKT((Set!$Q$4:$Q$12<=A6)*(Set!$R$4:$R$12>A6));"f";"")

und hier mit einer extra Spalte für die Feiertage:

Jahr

	A	B	C
5	Tage	Ferien	Feiertage
6	So, 01. Jan	F	F
7	Mo, 02. Jan	F
8	Di, 03. Jan	F
9	Mi, 04. Jan
10	Do, 05. Jan

verwendete Formeln
Zelle	Formel	Bereich	N/A
A6	=DATUM(Jahr;1;1)
A7:A10	=A6+1
B6:B10	=WENN(SUMMENPRODUKT((Set!$Q$4:$Q$12<=A6)*(Set!$R$4:$R$12>A6));"F";"")
C6:C10	=WENN(SUMMENPRODUKT((Tabelle6[Datum]=A6)*(Tabelle6[Datum]=A6));"F";"")

definierte Namen
Name	Bezieht sich auf	Tabelle	Z1S1-Formel
Jahr	=Set!$B$4		=Set!R4C2

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.08 einschl. 64 Bit

Vielen Dank steve1da!!! Das war die perfekte Lösung für meine Sache! Smile

Die Ferien und Feiertage wollte ich sogar in einer Spalte zusammenfassen, ich habe das nun wie folgt gelöst:

Code:
=WENN(ODER(SUMMENPRODUKT((Tabelle6[Datum]=$A6)*(Tabelle6[Datum]=$A6));SUMMENPRODUKT((Tabelle69[1. Tag der Ferien]<=$A6)*(Tabelle69[1. Schultag nach Ferien]>$A6)));"f";"")

@Rabe:
Danke auch für deinen Kalender! Allerdings benötige ich tatsächlich die oben genannte Form, da dieses Kürzel wichtig für meinen Dienstplan ist, denn es dient als Berechnungsgrundlage der Stunden der Mitarbeiter die in Ferien oder Feiertagen arbeiten Smile

Aber möglicherweise kann ich die Datei auch für andere Zwecke noch gut gebrauchen! Wink