Hallo zusammen,
also ich würde gerne folgendes machen:
Ich habe eine elend lange Spalte und ich möchte eine Funktion auf die ersten 400 Zeilen anwenden: Summe aller Elemente durch Anzahl (sprich also den Mittelwert bilden). Dann möchte ich wieder den Mittelwert der nächsten 400 Zeilen bilden usw. Bis zum Schluss.
Kann man das irgendwie realisieren?^^ Also ich habe absolut keine Idee. :s
Danke euch schonmal und noch einen schönen Tag. :)
Liebe Grüße
Wolfi
Hi,
ein Vorschlag, abgekupfert aus
http://www.supportnet.de/t/2266970
Tabelle1 | A | B | C |
| 1 | 1 | | 2,5 |
| 2 | 2 | | 6,5 |
| 3 | 3 | | 10,5 |
| 4 | 4 | 2,5 | 14,5 |
| 5 | 5 | | 18,5 |
| 6 | 6 | | 22,5 |
| 7 | 7 | | |
| 8 | 8 | 6,5 | |
| 9 | 9 | | |
| 10 | 10 | | |
| 11 | 11 | | |
| 12 | 12 | 10,5 | |
| 13 | 13 | | |
| 14 | 14 | | |
| 15 | 15 | | |
| 16 | 16 | 14,5 | |
| 17 | 17 | | |
| 18 | 18 | | |
| 19 | 19 | | |
| 20 | 20 | 18,5 | |
| 21 | 21 | | |
| 22 | 22 | | |
| 23 | 23 | | |
| 24 | 24 | 22,5 | |
| Formeln der Tabelle |
| Zelle | Formel | | B1 | =WENN(REST(ZEILE(A1);4)=0;MITTELWERT(BEREICH.VERSCHIEBEN(A1;;;-4;));"") | | C1 | =WENNFEHLER(MITTELWERT(BEREICH.VERSCHIEBEN(A$1;AUFRUNDEN(ZEILE()*4-4;0);;4;));"") |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
In Spalte B findest du Mittelwerte am jeweiligen Blockende; in Spalte C sind alle Blockwerte untereinander geschrieben. Zum Testen habe ich 4er-Blöcke verwendet - du musst sie halt auf 400er-Blöcke abändern.
Hi,
wo beginnen die Daten in A1 oder A2 wo soll das Ergebnis stehen?
hier mal was für in A1 beginnen schon die Daten, Auswertung ab Zeile 2
=MITTELWERT(INDEX(A:A;(ZEILE()-2)*400+1):INDEX(A:A;(ZEILE()-1)*400))
[
attachment=10223]
Hallo,
danke euch beiden, dass hat mir schon sehr geholfen. :)
Also die Ergebnisse sollen ab Zeile A2 stehen, genauso wie die Daten.
lg
Wolfi
Hi,
dann Formel in Zeile 2 danach kopieren
=MITTELWERT(INDEX(A:A;(ZEILE()-2)*400+2):INDEX(A:A;(ZEILE()-1)*400+1))
Genial, dass hat funktioniert auch wenn ich jetzt ne Weile dran saß, eh ichs verstanden hab. :17:
Danke euch!!
Wenn ich noch was fragen darf:
Wenn ich das selbe jetzt nochmal machen wollen würde, nur das ich aus den einzelnen Bereichen immer den größten und den kleinsten Wert haben mächte und dann max-min rechnen will. Wie würde das denn dann aussehen?
Zum Beispiel so?:
=KGRÖSSTE(INDEX(H:H;(ZEILE()-2)*400+2):INDEX(H:H;(ZEILE()-1)*400+1);1)-KKLEINSTE(INDEX(H:H;(ZEILE()-2)*400+2):INDEX(H:H;(ZEILE()-1)*400+1);1)
lg
Wolfi
Hallo Wolfi,
Sollte passen
es reicht auch ein
=MAX(INDEX(A:A;(ZEILE()-2)*400+2):INDEX(A:A;(ZEILE()-1)*400+1))-MIN(INDEX(A:A;(ZEILE()-2)*400+2):INDEX(A:A;(ZEILE()-1)*400+1))
Oder eben wie bei Dir Spalte H einsetzen statt A
Super danke dir! Das war eine sehr große Hilfe für mich. :19: