Hallo,
ich möchte gerne nach dem 4. Zeichen in einer Zelle einen Punkt einfügen. Mit einer Formel.
Bsp.:
jcdr1234567
kide345287907
jkpx587463454696
Ergebnis sollte sein
jcdr.1234567
kide.345287907
jkpx.587463454696
Danke schon einmal im Voraus.
Hallo, das geht z. B. so ..:
=ERSETZEN(A1;5;0;".")
Vielen Dank
funktioniert super für 4 Zeichen. Habe aber gerade gesehen das in meiner Tabelle auch 5 und 6 Buchstaben vorne sein können. Gibt es da auch eine Möglichkeit nach den Buchstaben den Punkt einzufügen?
Danke
Hallo,
angenommen, es kommen immer zuerst Buchstaben und dann die Zahl:
die Position der ersten Zahl:
Code:
for j = 1 to len(cells(i,"A")
if mid(cells(i,"A"), j,1) like "#" then exit for
next j
msgbox j
msg
(ungeprüft, i ist die Schleife über alle Zeilen)
Hallo, mt ner Formel ginge das z. B. so..:
=ERSETZEN(A1;VERGLEICH(WAHR;ISTZAHL(TEIL(A1;SPALTE(A1:IQ1);1)*1);0);0;".")
Achtung, Matrixformel !
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine
@ Jockel
Danke funktioniert super
(14.03.2017, 13:33)Jockel schrieb: [ -> ]Hallo, das geht z. B. so ..:
=ERSETZEN(A1;5;0;".")
Moin Jörg!
Mir sträuben sich die spärlichen Nackenhaare (Avatar stimmt nicht ;))!
Nicht wegen der super Formel,
sondern wegen der Tatsache, dass man eine Zeichenkette
mit der Länge Null "ersetzen" kann.
Muss ein gutes Zeug gewesen sein, was der Programmierer der Funktion geraucht hat. :21:
Gruß Ralf
(14.03.2017, 14:44)RPP63 schrieb: [ -> ]Moin Jörg!
...Avatar stimmt nicht ...!
Gruß Ralf
Moin Ralf, irgendwas stimmt mit Hasi nicht... ... aber was stimmt mit (meinem?) Avatar nicht?
Moin!
Nö, ich meinte meinen Avatar.
Die Lockenpracht ist eher Wunschdenken. ;)
Gruß Ralf
Hallo,
ginge auch so:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B |
1 | abcd923 | abcd.923 |
2 | abcde456 | abcde.456 |
Zelle | Formel |
B1 | =ERSETZEN(A1;AGGREGAT(15;6;SPALTE(1:1)/(CODE(TEIL(A1;SPALTE(1:1);1))>47)/(CODE(TEIL(A1;SPALTE(1:1);1))<58);1);0;".") |
B2 | =ERSETZEN(A2;AGGREGAT(15;6;SPALTE(2:2)/(CODE(TEIL(A2;SPALTE(2:2);1))>47)/(CODE(TEIL(A2;SPALTE(2:2);1))<58);1);0;".") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |