Moin aus Hamburg,
ich habe noch ein letztes Problem mit meinem Dienstplan. Gesetzt habe ich jetzt mehrere verschachtelte WENN Funktionen, dass er die Wochenenden erkennt und dort andere Arbeitsstunden nutzt. Funktioniert einwandfrei. Jetzt habe ich das Problem, dass ich ihm noch Feiertage sagen muss. Meine Idee:
=WENN(Datum(2017;01;01);...;...) Das funktioniert leider nur mit dem einen Datum. Muss ich jetzt für jedes Datum eine eigene WENN schreiben, oder kann ich auch einen bestimmten Bereich prüfen (in dem die Daten stehen). Das wäre sehr von Vorteil, da die Formel jetzt schon sooooooooo lang ist.
=SUMMENPRODUKT(WENN(L7="";"0";WENN(L3="Sa";SVERWEIS(L7;Martix!$M$2:$N$52;2;FALSCH);WENN(L3="So";SVERWEIS(L7;Martix!$P$2:$Q$52;2;FALSCH);WENN(L3="FT";SVERWEIS(L7;Martix!$P$2:$Q$52;2;FALSCH);SVERWEIS(L7;Martix!$G$2:$H$52;2;FALSCH)))))+(WENN(M7="";"0";WENN(L3="Sa";SVERWEIS(M7;Martix!$S$2:$T$52;2;FALSCH);WENN(L3="So";SVERWEIS(M7;Martix!$S$2:$T$52;2;FALSCH);WENN(L3="FT";SVERWEIS(M7;Martix!$S$2:$T$52;2;FALSCH);(SVERWEIS(M7;Martix!$J$2:$K$52;2;FALSCH))))))))
Hola,
Code:
=wenn(zählenwenn(Bereich_mit_den_Feiertagen;A1);.....)
Mehr kann man nicht dazu sagen weil außer dir niemand sieht wo was steht und was z.B. die Formel berechnet.
Gruß,
steve1dqa
Super, das versuch ich gleich mal! Danke!
Hallo
Ich glaube die Formel ist die eierlegende Wollmilchsau.
1x SUMMENPRODUKT(), 8x WENN(), 8x SVERWEIS().
Wofür das SUMMENPRODUKT() benötigt wird ist mir nicht klar, da alle Berechnungen innerhalb der äußeren WENN()-Formel ablaufen.
Hi,
und unbegreiflich, warum man die Bereiche für den SVERWEIS nicht zusammen und untereinander legen kann! Aber der ganze Dienstplan ist schon dubios aufgebaut!
Theoretisch sollte das reichen:
Code:
=SUMME(WENN(L7="";0;WENN(L3="sa";SVERWEIS(L7;Martix!$M$2:$N$52;2;0);WENN((L3="So")+(L3="FT");SVERWEIS(L7;Martix!$P$2:$Q$52;2;0);SVERWEIS(L7;Martix!$G$2:$H$52;2;0))));WENN(M7="";0;WENN((L3="sa")+(L3="so")+(L3="FT");SVERWEIS(M7;Martix!$S$2:$T$52;2;0);SVERWEIS(M7;Martix!$J$2:$K$52;2;0))))
Hallo
shift-del,
es ist richtig, dass es die eierlegende Wollmilchsau ist. Zur kurzen Erklärung am Beispiel (es ist ein Dienstplan):
[
attachment=10004]
In L3 steht der Wochentag, in L4 das Datum.
Die von mir oben eingefügte Formel steht in L6. In L7 wird eine Station eingefügt (Frühdienst) und in M7 ebenfalls eine Station (Spätdienst). In L6 werden jetzt, dank der Formel, die Arbeitsstunden angezeigt. (Darum auch Summenprodukt). Jede Station hat andere Arbeitsstunden, die er sich aus der Matrix ziehen soll. Dazu überprüft die Formel, ob in L3 Samstag oder Sonntag steht WENN(L3="Sa";SVERWEIS... bla bla bla. Nun soll er, als letzte Rafinesse, prüfen, ob der Datum in L4 ein Feiertag ist. Diese habe ich ebenfalls in eine Matrix zusammengefasst. (Es sind ja in Hamburg nicht so viele
) Im Grunde gibt L6 nur an (Stunden Frühdienst)+(Stunden Spätdienst) mit vielen Sachen, die beachtet werden müssen. (Die Arbeitsstunden am Wochenende sind die selben, wie die Sonntagsstunden.
Ich hoffe, dass ich es einigermaßen verdeutlichen konnte.
(03.03.2017, 13:39)BoskoBiati schrieb: [ -> ]Hi,
und unbegreiflich, warum man die Bereiche für den SVERWEIS nicht zusammen und untereinander legen kann! Aber der ganze Dienstplan ist schon dubios aufgebaut!
Moin BoskoBiati,
weil ich es nicht besser weiß und wir viele Informationen verarbeiten müssen. Ich bin froh, dass er soweit steht wie er steht!
SVERWEIS zusammen und untereinander legen habe ich auch leider noch nirgendwo gelesen. Sonst hätte ich das sicherlich versucht. Bin leider kein Fachmann (was man ja sieht), dafür verstehe ich etwas von dem, was wir hier machen.
Danke für eure Unterstützung und allen ein tolles Wochenende!
Hallo,
würdest Du mal die Tabelle vorstellen, könnte man Dir auch Tipps geben, was zu verbessern wäre, siehe allein die von mir geänderte Formel!
SUMMENPRODUKT ist hier überflüssig, weil dafür kein Bedarf ist, und zudem ein Ressourcenfresser!
Zitat:weil ich es nicht besser weiß
Foren helfen, das Wissen zu erweitern!
Deine Martix-Tabelle so aufgebaut:
| Arbeitsblatt mit dem Namen 'Martix' |
| | A | B | C | D | E | F |
| 1 | | F | | | S | |
| 2 | Station | W | Sa | So/FT | W | WE/FT |
| 3 | G10 | | | | | |
| 4 | L5A | | | | | |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Dann reicht diese Formel:
Code:
=WENN(L7="";0;SVERWEIS(L7;Martix!A:F;2+(L3="sa")+oder(L3={"so"."FT"})*2;0))+WENN(M7="";0;SVERWEIS(M7;Martix!A:F;5+oder(L3={"sa"."so"."FT"});0))
Ich versuche mal die Datei hochzuladen. Ich habe alle persönlichen und Firmendaten gelöscht, sodass ihr das mal sehen könnt. Auch ist sie, in der Anzahl der MA gekürzt, da wir 95 MA in dem Bereich haben.
"Datei gelöscht" siehe weitere Posts
Im Grunde ist es mein Ziel, in die jeweils untere Spalte die Station für evtl. Früh- oder Spätedienst eintragen, den Rest soll er alleine machen.
Meine Traumwelt!